[编程申请]：求倒角标注lisp

sqqr

求倒角标注lisp

标注45°倒角。


选择待标注的倒角: 拾取待标注的45°倒角线


倒角尺寸<20.4>: （注：程序自动测出倒角尺寸做为缺省值并提示，无需输入45°角度值，程序会自动加上“×45°”字样）

woshiwo99

期待ing……

zxq0220

程序使用尺寸变量参数。
[php]
;倒角标注====晓东 zxq0220
(DEFUN C:DIMCHAMFER ()
(SETVAR "CMDECHO" 0)
(SETQ OLDOS (GETVAR "OSMODE"))
(SETQ OLDZIN (GETVAR "DIMZIN"))
(SETVAR "DIMZIN" 8)
(SETVAR "OSMODE" 0)
(SETQ DL (ENTGET (CAR (ENTSEL "\nPlease Select a Line 请选择一条直线 :"))))
(WHILE (/= (CDR (ASSOC 0 DL)) "LINE")
  (PRINC "\nError!")
  (SETQ DL (ENTGET (CAR (ENTSEL "\nPlease Select a Line 请选择一条直线 :"))))
)
(SETQ P1 (CDR (ASSOC 10 DL))
       P2 (CDR (ASSOC 11 DL))
       X (ABS (- (CAR P1) (CAR P2)))
       Y (ABS (- (CADR P1) (CADR P2))))
(IF (EQUAL X Y 1E-4) (PROGN
   (SETQ TT (STRCAT (RTOS X 2 3) "x45%%d")
         OLDASC (GETVAR "DIMASC")
         P4 (POLAR P1 (ANGLE P1 P2) (* (DISTANCE P1 P2) 0.5)))
  (SETVAR "DIMASZ" 0)
  (SETQ ANG (/ PI 4))
  (SETVAR "SNAPANG" ANG)
  (IF (SETQ P3 (GETPOINT P4 "\nText Point 文字点? ")) (PROGN
   (SETQ P4 (IF (> (DISTANCE P3 P1) (DISTANCE P3 P2)) P2 P1)
         P5 (POLAR P3 (/ PI 2) (* (GETVAR "DIMGAP") 2)))
   (COMMAND "LEADER" P4 P5 "" TT "")
  ))
  (SETVAR "SNAPANG" 0)
  (SETVAR "DIMASZ" OLDASZ)
))
(SETVAR "DIMZIN" OLDZIN)
(SETVAR "OSMODE" OLDOS)
(SETVAR "CMDECHO" 1)
(PRINC)
)
[/php]

li809

程序可用，谢谢

woshiwo99

老大！如果倒角的引线能自动按倒角的延伸方向引出就好了。

vinsam

做出的标注为什么引线没有箭头呢

zxq0220

最初由 woshiwo99 发布
[B]老大！如果倒角的引线能自动按倒角的延伸方向引出就好了。 [/B]

程序就是按倒角的延伸方向引出的。

最初由 vinsam 发布
[B]做出的标注为什么引线没有箭头呢
[/B]

国家制图标准中倒角就是没有箭头呀，所以将引线的箭头关掉了。

zxcvbnm-cad

只能对45°斜线有用
能不能修改成任意角度的斜线

woshiwo99

老大，我标注的总是不能沿倒角的延伸方向！还有，用完了之后，对象捕捉就给清空了。很不方便啊。请老大检查一下。

zxq0220

最初由 zxcvbnm-cad 发布
[B]只能对45°斜线有用
能不能修改成任意角度的斜线 [/B]

更改后的程序：
[php]
(DEFUN C:DIMCHAMFER ()
(SETVAR "CMDECHO" 0)
(SETQ OLDOS (GETVAR "OSMODE"))
(SETQ OLDZIN (GETVAR "DIMZIN"))
(SETQ ORTHO (GETVAR "ORTHOMODE"))
(SETQ OLDTAD (GETVAR "DIMTAD"))
(SETVAR "DIMZIN" 8)
(SETVAR "OSMODE" 0)
(SETVAR "DIMTAD" 1)
(SETQ DL (ENTGET (CAR (ENTSEL "\nPlease Select a Line 请选择一条直线 :"))))
(WHILE (/= (CDR (ASSOC 0 DL)) "LINE")
  (PRINC "\nError!")
  (SETQ DL (ENTGET (CAR (ENTSEL "\nPlease Select a Line 请选择一条直线 :"))))
)
(SETQ P1 (CDR (ASSOC 10 DL))
       P2 (CDR (ASSOC 11 DL))
       X (ABS (- (CAR P1) (CAR P2)))
       Y (ABS (- (CADR P1) (CADR P2))))
(IF (EQUAL X Y 1E-4)
  (SETQ TT (STRCAT (RTOS X 2 3) "x45%%d"))
(PROGN
  (SETQ CT (/ (DISTANCE P1 P2) (SQRT 2.0)))
  (PRINC "\n倒角尺寸<") (PRINC (RTOS CT 2 3))
  (SETQ TT (GETSTRING "> :")
        TT (STRCAT (IF (= TT "") (RTOS CT 2 3) TT) "x45%%d"))
))
(IF (/= TT "") (PROGN
  (SETQ OLDASZ (GETVAR "DIMASZ")
        P4 (POLAR P1 (ANGLE P1 P2) (* (DISTANCE P1 P2) 0.5)))
  (SETVAR "DIMASZ" 0)
  (SETVAR "SNAPANG" (ANGLE P1 P2))
  (SETVAR "ORTHOMODE" 1)
  (IF (SETQ P3 (GETPOINT P4 "\nText Point 文字点? ")) (PROGN
   (SETQ P4 (IF (> (DISTANCE P3 P1) (DISTANCE P3 P2)) P2 P1)
         P5 (POLAR P3 (/ PI 2) (* (GETVAR "DIMGAP") 1)))
   (COMMAND "LEADER" P4 P5 "" TT "")
  ))
  (SETVAR "SNAPANG" 0)
  (SETVAR "ORTHOMODE" ORTHO)
  (SETVAR "DIMASZ" OLDASZ)
))
(SETVAR "DIMZIN" OLDZIN)
(SETVAR "OSMODE" OLDOS)
(SETVAR "CMDECHO" 1)
(PRINC)
)
[/php]

最初由 woshiwo99 发布
[B]老大，我标注的总是不能沿倒角的延伸方向！还有，用完了之后，对象捕捉就给清空了。很不方便啊。请老大检查一下。[/B]

延伸方向已更正。如果正常结束程序就能恢复对象捕捉。

zxcvbnm-cad

好象还是只能对45°的斜线有用

zxq0220

最初由 zxcvbnm-cad 发布
[B]好象还是只能对45°的斜线有用 [/B]

一楼楼主要的就是45°的标注呀！

zxcvbnm-cad

请zxq0220大侠再编个任意角度的
谢谢