[编程申请]：增加极坐标标注

msdg

请在晓东工具箱中增加一个“极坐标标注”。谢谢！

eachy

最初由 msdg 发布
[B]请在晓东工具箱中增加一个“极坐标标注”。谢谢！ [/B]

贴个图详细说说。

zhaoqiong555

是啊
我也要用啊
可是不会

wangxj2002

应该！极坐标标注经常要使用！！

自由的鱼

这个功能在什么时候用？很少用到！

xyp1964

位置以点（point）表示，文本形式如@5<30，请测试：
[php]
;|
jzb.lsp 极坐标
* C:jzb
-- XYP@bsedi.com
2004.12.17
|;
;;;加载jzb.lsp，运行jzb。
(prompt "\n\r      加载极坐标程序。")
(defun c:jzb ()
  (cmdla0)
  (command"ucs""W")
  (if (or (null @bl) (null @sc))
    (setbl1)
  )
  (while (setq pt1 (getpoint '(0 0)"\n标注点<退出> : "))
    (setq leng (distance '(0 0) pt1)
          ang  (angle '(0 0) pt1)
          ang  (* (/ 180 pi) ang)
          txt  (strcat "@" (rtos leng 2 2) "<" (rtos ang 2 2))
    )
    (jzhz)
    (command "point" pt1)
    (command "text" "J" "bc" pt1 (* @sc 300) "0" txt)
  )
  (cmdla1)
)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun CMDLA0 ()
  (setq cmdech (getvar "CMDECHO"))
  (setq oom (getvar "orthomode"))
  (setq osm (getvar "osmode"))
  (SETQ LA (getvar "clayer"))
  (setq rmode (getvar "regenmode"))
  (setq pw (getvar "plinewid"))
  (setvar "regenmode" 0)
  (setvar "CMDECHO" 0)
  (princ)
)
(defun CMDLA1 ()
  (setvar "CMDECHO" cmdech)
  (setvar "orthomode" oom)
  (setvar "osmode" osm)
  (setvar "clayer" LA)
  (setvar "regenmode" rmode)
  (setvar "plinewid" pw)
  (princ)
)
(defun ureal (bit kwd msg def / inp)
  (if def
    (setq msg (strcat "\n" msg "<" (rtos def 2) ">: ")
          bit (* 2 (fix (/ bit 2)))
    )
    (setq msg (strcat "\n" msg ": "))
  )
  (initget bit kwd)
  (setq inp (getreal msg))
  (if inp
    inp
    def
  )
)
(defun jzhz ()
  (setq chksty (tblsearch "style" "汉字"))
  (if (null chksty)
    (command "_style" "汉字" "宋体" "0" "0.7" "0" "" "")
  )
  (mkla "极坐标" 4)
  (setvar "textstyle" "汉字")
)
(defun mkla (name color)
  (If (= (Tblsearch "layer" name) nil)
    (Command "layer" "m" name "c" color name "")
    (Command "layer" "t" name "s" name "c" color name "")
  )
)
(defun setbl1 ()
  (setq @bl (ureal 1 "" "\n输入出图比例1 : " @bl))
  (setq @SC (/ @bl 100))
)
(DEFUN PXYP (TXT1)
  (SETQ        TXT1 (STRCAT "\n\r      程序命令: "
                     TXT1
                     "      -- xyp@bsedi.com"
             )
  )
  (PRINC TXT1)
  (Princ)
)
(pxyp "jzb      (极坐标)")
(princ)
;;;-------------------------------------------
;;;END
[/php]

xyp1964

程序示意：

jx2008

程序很好，就是标注的文字有点不太好。能不能改成距离，度分秒的格式，而且分成两行，就像坐标标注一样，上面的为度分秒，下面为距离数据。

zlzlzlzl

极坐标不是这个概念吧