[LISP函数-基本]：修改指定系统变量并返回其先前值

eachy · 发表于 2005-9-4 02:31:19

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

;;;ChangeVars
;;;修改指定系统变量并返回其先前值
;;;参数
;;;一个包含要更改的系统变量和他们的新值的点对列表
;;;示例
;;;(setq ret (changevars '(("filedia" . 0)("cmdecho" . 0)("osmode" . 512))))
;;;注意
;;;CHANGEVARS 返回一个包含所有指定的系统变量和他们先前值的列表。要恢复他们，
;;;可简单地将该返回的列表提供给CHANGEVARS 函数。
(defun xd-changevars (lst)
(mapcar '(lambda (x / tmp var)
(setq tmp (cons (car x)
(if (= (type (setq var (getvar (car x)))) 'list)
(list var)
var
)
)
) ;_ end of setq
(setvar (car x)
(if (= (type (cdr x)) 'list)
(cadr x)
(cdr x)
)
)
tmp
) ;_ end of lambda
lst
) ;_ end of mapcar
) ;_ end of defun

;;;ChangeVars 
;;;修改指定系统变量并返回其先前值 
;;;参数 
;;;一个包含要更改的系统变量和他们的新值的点对列表 
;;;示例 
;;;(setq ret (changevars '(("filedia" . 0)("cmdecho" . 0)("osmode" . 512)))) 
;;;注意 
;;;CHANGEVARS 返回一个包含所有指定的系统变量和他们先前值的列表。要恢复他们， 
;;;可简单地将该返回的列表提供给CHANGEVARS 函数。 
(defun xd-changevars (lst) 
  (mapcar '(lambda (x / tmp var) 
             (setq tmp (cons (car x) 
                             (if (= (type (setq var (getvar (car x)))) 'list) 
                               (list var) 
                               var 
                             ) 
                       ) 
             ) ;_ end of setq 
             (setvar (car x) 
                     (if (= (type (cdr x)) 'list) 
                       (cadr x) 
                       (cdr x) 
                     ) 
             ) 
             tmp 
           ) ;_ end of lambda 
          lst 
  ) ;_ end of mapcar 
) ;_ end of defun

eachy · 发表于 2005-9-23 12:34:11

再看看CAD定义的

;;cad内部定义函数 From acad.mnl
;;; --- ai_sysvar ------------------------------------------
;;; Change system variable settings and save current settings
;;; (Note: used by *merr* to restore system settings on error.)
;;;
;;; The <vars> argument is used to...
;;; restore previous settings (ai_sysvar NIL)
;;; set a single sys'var (ai_sysvar '("cmdecho" . 0))
;;; set multiple sys'vars (ai_sysvar '(("cmdecho" . 0)("gridmode" . 0)))
;;;
;;; defun-q is needed by Visual Lisp for functions which redefine themselves.
;;; it is aliased to defun for seamless use with AutoLISP.
(defun-q ai_sysvar
(vars / savevar pair varname varvalue varlist)
(setq varlist nil)
;; place holder for varlist
(defun savevar (varname varvalue / pair)
(cond
;; if new value is NIL, save current setting
((not varvalue)
(setq varlist
(cons
(cons varname (getvar varname))
varlist
)
)
)
;; change sys'var only if it's different
((/= (getvar varname) varvalue)
;; add current setting to varlist, change setting
(setq varlist
(cons
(cons varname (getvar varname))
varlist
)
)
(setvar varname varvalue)
)
(T nil)
)
)
(cond ;_reset all values
((not vars)
(foreach pair varlist
(setq varname (car pair)
varvalue (cdr pair)
)
(setvar varname varvalue)
)
(setq varlist nil)
)
((not (eq 'LIST (type vars)))
(princ "\nAI_SYSVAR: 参数类型错。\n")
)
;; set a single system variable
((eq 'STR (type (car vars)))
(savevar (car vars) (cdr vars))
)
;; set multiple system variables
((and
(eq 'LIST (type (car vars)))
(eq 'STR (type (caar vars)))
)
(foreach pair vars
(setq varname (car pair)
varvalue (cdr pair)
)
(if (not (eq 'STR (type varname)))
(princ "\nAI_SYSVAR: 参数类型错。\n")
(savevar varname varvalue)
)
)
)
(T (princ "\nAI_SYSVAR: 第一个参数有错。\n"))
) ;cond
;; redefine ai_sysvar function to contain the value of varlist
(setq ai_sysvar
(cons (car ai_sysvar)
(cons (list 'setq 'varlist (list 'quote varlist))
(cddr ai_sysvar)
)
)
)
varlist
;; return the list
) ;_sysvar

;;cad内部定义函数 From acad.mnl 
;;; --- ai_sysvar ------------------------------------------ 
;;; Change system variable settings and save current settings 
;;; (Note: used by *merr* to restore system settings on error.) 
;;; 
;;; The <vars> argument is used to... 
;;;   restore previous settings (ai_sysvar NIL) 
;;;   set a single sys'var (ai_sysvar  '("cmdecho" . 0)) 
;;;   set multiple sys'vars (ai_sysvar '(("cmdecho" . 0)("gridmode" . 0))) 
;;; 
;;; defun-q is needed by Visual Lisp for functions which redefine themselves. 
;;; it is aliased to defun for seamless use with AutoLISP. 
(defun-q ai_sysvar 
         (vars / savevar pair varname varvalue varlist) 
         (setq varlist nil) 
         ;; place holder for varlist 
         (defun        savevar        (varname varvalue / pair) 
           (cond 
             ;; if new value is NIL, save current setting 
             ((not varvalue) 
              (setq varlist 
                     (cons 
                       (cons varname (getvar varname)) 
                       varlist 
                     ) 
              ) 
             ) 
             ;; change sys'var only if it's different 
             ((/= (getvar varname) varvalue) 
              ;; add current setting to varlist, change setting 
              (setq varlist 
                     (cons 
                       (cons varname (getvar varname)) 
                       varlist 
                     ) 
              ) 
              (setvar varname varvalue) 
             ) 
             (T nil) 
           ) 
         ) 
         (cond ;_reset all values 
           ((not vars) 
            (foreach pair varlist 
              (setq varname  (car pair) 
                    varvalue (cdr pair) 
              ) 
              (setvar varname varvalue) 
            ) 
            (setq varlist nil) 
           ) 
           ((not (eq 'LIST (type vars))) 
            (princ "\nAI_SYSVAR: 参数类型错。\n") 
           ) 
           ;; set a single system variable 
           ((eq 'STR (type (car vars))) 
            (savevar (car vars) (cdr vars)) 
           ) 
           ;; set multiple system variables 
           ((and 
              (eq 'LIST (type (car vars))) 
              (eq 'STR (type (caar vars))) 
            ) 
            (foreach pair vars 
              (setq varname  (car pair) 
                    varvalue (cdr pair) 
              ) 
              (if (not (eq 'STR (type varname))) 
                (princ "\nAI_SYSVAR: 参数类型错。\n") 
                (savevar varname varvalue) 
              ) 
            ) 
           ) 
           (T (princ "\nAI_SYSVAR: 第一个参数有错。\n")) 
         )                                ;cond 
         ;; redefine ai_sysvar function to contain the value of varlist 
         (setq ai_sysvar 
                (cons (car ai_sysvar) 
                      (cons (list 'setq 'varlist (list 'quote varlist)) 
                            (cddr ai_sysvar) 
                      ) 
                ) 
         ) 
         varlist 
         ;; return the list 
) ;_sysvar

账号		自动登录	找回密码
密码			立即注册

[LISP函数-基本]：修改指定系统变量并返回其先前值

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子