[求助]：请问如何在CAD中求封闭面积?

空空空空空空

我是初学者,我想请问各位如何在CAD中用快速的方法求封闭面积?

旮旯酋酋长

方法一：
1、点击面域－选定要求面积的线，创建面域；
2、点击面域/质量特性－选择刚才所建面域，右击就OK了；
3、若是不同等高线要求平面上投影面积，选定所有等高线，点击特性，设Z值为同一数值。再按上1、2所述步骤就可。
方法二：
求直线所围图形面积：点击工具－查询－面积－点选各直线端点就可。

saint12

关键是如何寻找“闭合”的区域阿？通常一张总图要算面积的时候，圈“闭合区域”的时间已经占了大部分了。因为有许多区域是不能用BOUNDARY命令的。只能自己用PLINE命令重新画一个闭合区域出来的。

有什么好办法阿？？？

taner

[PHP](defun c:aream (/ olderr oldcmdecho errexit undox restore ss1 nr en tot_area)
  (defun errexit (s)
    (restore)
  )
  (defun undox ()
    (command "._undo" "_E")
    (setvar "cmdecho" oldcmdecho)
    (setq *error* olderr)
    (princ)
  )
  (setq olderr *error*
        restore undox
        *error* errexit
  )
  (setq oldcmdecho (getvar "cmdecho"))
  (setvar "cmdecho" 0)
  (command "._UNDO" "_BE")
  (if (setq ss1 (ssget '((-4 . "<OR") (0 . "POLYLINE")
                        (0 . "LWPOLYLINE")
                        (0 . "CIRCLE")
                        (0 . "ELLIPSE")
                        (0 . "SPLINE")
                        (0 . "REGION")
                        (-4 . "OR>")
                       )
                )
      )
    (progn
      (setq nr 0)
      (setq tot_area 0.0)
      (setq en (ssname ss1 nr))
      (while en
        (command "._area" "_O" en)
        (setq tot_area (+ tot_area (getvar "area")))
        (setq nr (1+ nr))
        (setq en (ssname ss1 nr))
      )
      (princ "\nTotal Area = ")
      (princ tot_area)
    )
  )
  (restore)
)[/PHP]

[PHP](defun c:mj (/ pt)
  (while (setq pt (getpoint "点击区域..."))
    (command "_.boundary" "a" "o" "p" "" pt "")
    (command "_.area" "o" (entlast))
    (entdel (entlast))
    (prompt "\n")
    (prompt (rtos (getvar "area")))
  )
  (princ)
)[/PHP]

yh01811

还需要用到查询功能

ephoenixzh

直接用reg不就OK了

taner

http://www.xdcad.net/forum/showthread.php?s=&threadid=507794