[求助]：如何让程序自动切换已打开的多个DWG文件？

兴趣人生

CAD打开多个文件时，如果要切换到下一页，让程序来做要如何实现呢？请教大虾们，谢谢

Underway

Ref info:  http://discussion.autodesk.com/thread.jspa?threadID=371476

(defun Go_Dn ()
   (SETQ DOCUMENT_NUMBER (NTH 3 (MEMBER (getvar 'dwgname) TEMP_INDEX)))
   (VLA-PUT-ACTIVEDOCUMENT ACADOBJECT (vla-item documentcollection DOCUMENT_NUMBER))
   (PRINC)
)


Ref info: http://www.menziengineering.ch/Downloads/Download.htm#52


VxScrollDocs - Scrolls the open docs in alphabetic order up or down


;
; -- Function VxScrollDocs
; Scrolls the open docs in alphabetic order up or down.
; Copyright:
;   ?004 MENZI ENGINEERING GmbH, Switzerland
; Arguments [Type]:
;   Dir = Direction "U" or "D" (Up or Down) [STR]
; Return [Type]:
;   > Null
; Notes:
;   - Load this function by AcadDoc.lsp to have it available in each
;     document
;
(defun VxScrollDocs (Dir / DocCol DocLst DocNum DocObj MaxPos MovDir)
(or Gb:AcO (setq Gb:AcO (vlax-get-acad-object)))
(setq DocCol (vlax-get Gb:AcO 'Documents))
(if (> (vla-get-Count DocCol) 1)
  (progn
   (vlax-for DocObj DocCol
    (setq DocLst (cons (cons (vla-get-Name DocObj) DocObj) DocLst))
   )
   (setq DocLst (vl-sort
                 DocLst
                 (function
                  (lambda (a b)
                   (< (strcase (car a)) (strcase (car b)))
                  )
                 )
                )
         MaxPos (1- (length DocLst))
         MovDir (eq (strcase Dir) "D")
         DocNum (vl-position (getvar 'DWGNAME) (mapcar 'car DocLst))
         DocNum (cond
                 ((and MovDir (< DocNum MaxPos)) (1+ DocNum))
                 ((and MovDir (= DocNum MaxPos)) 0)
                 ((> DocNum 0) (1- DocNum))
                 (MaxPos)
                )
   )
   (vlax-put Gb:AcO 'Activedocument (cdr (nth DocNum DocLst)))
  )
)
(princ)
)

兴趣人生

我的LISP很菜呀
请问二楼的大虾，那些代码是什么意思呢？
能不能帮我写个完整的代码呀？谢谢了

教父

老大，照顾一下我们新人啊，你给的东东怎么感觉这么深奥啊

cuiyi555

如果用纯lisp写 不知道可以么？没有试过 我想应该比较麻烦吧
你可以尝试用 arx去写 那样也许简单一点
上面给例程也是用object 写的吧

zxmmelly

有一个叫DocBar的插件就可以

buweida

我都是用“Ctrl+Tab”来切换的。而且我不太明白楼主的意思。