[求助]：如何获取矩形的长宽和中心坐标？

kevinchan

如何获取矩形的长宽和中心坐标？

Underway

(defun c:test ()
   (cond
    ((not (setq ss (ssget ":S" '((0 . "LWPolyline"))))))
    (T
     (setq ee (ssname ss 0))
     (setq pts (acet-geom-extents ee)
           Pur (cadr pts)
           Pll (car pts)
           Px9 (car Pur)
           Px0 (car Pll)
           Py9 (cadr Pur)
           Py0 (cadr Pll)
           pt5 (list (/ (+ Px9 Px0) 2) (/ (+ Py9 Py0) 2))
           Dxx (- Px9 Px0)
           Dyy (- Py9 Py0)
      )
      (princ "\nLength: ") (princ Dxx)
      (princ "\n Width: ") (princ Dyy)
      (princ "\n中间点: ") (princ pt5)
    ))
    (princ)
)

ljpnb

程序不完全正确，我估计程序中用到了vla-GetBoundingBox ，当矩形倾斜时，得到的长宽就不正确了。

kevinchan

非常谢谢！

ljpnb

改了一下
[php]
(defun c:test (/ ent obj lst p1 p2 p3 a b cen-point)
  (princ "\n本程序功能:求矩形的长宽和中心坐标!")
  (if (setq ent (car (entsel "\n选择一个矩形:")))
    (progn
      (setq obj (vlax-ename->vla-object ent))
      (setq lst (vlax-get obj 'Coordinates))
      (setq p1 (list (nth 0 lst) (nth 1 lst))
            p2 (list (nth 2 lst) (nth 3 lst))
            p3 (list (nth 4 lst) (nth 5 lst))
      )
      (setq a (distance p1 p2)
            b (distance p2 p3)
      )
      (setq cen-point (mapcar '(lambda (x y) (/ (+ x y) 2.0)) p1 p3))
      (princ "\n矩形长度=")
      (princ a)
      (princ "\n矩形宽度=")
      (princ b)
      (princ "\n中心点坐标为:")
      (princ cen-point)
      
    )
  )
  (princ)
)

[/php]

kevinchan

如果反过来，把N个矩形获取的数据存为TXT文件，
a  b  cen-pointx cen-pointy
10 20 -10 15.25
15 25 -60 100.5
....
再根据TXT文件生成矩形，如何做？

(defun c:test        ()
  (setvar "osmode" 0)
  (setvar "pdmode" 34)
  (setq ffn (getfiled "选取文件" "" "txt" 2))
  (setq ff (open ffn "r"))
  (read-line ff)
  (while (setq data (read-line ff))
    (setq data (read (strcat "(" data ")")))
    (command "_.rectang" .......)   ;;;这一步该怎么写？
  )
  (close ff)
  (princ)
  (command "zoom" "Extents")
)

ljpnb

修改了一下：
[php]
(defun c:test (/ os ffn ff data a b cen-point p1 p2)
  (setq os (getvar "osmode"))
  (setvar "osmode" 0)
  ;;(setvar "pdmode" 34)
  (setq ffn (getfiled "选取文件" "" "txt" 2))
  (setq ff (open ffn "r"))
  (read-line ff)
  (while (setq data (read-line ff))
    (setq data (read (strcat "(" data ")")))
    (setq a            (nth 0 data)
          b            (nth 1 data)
          cen-point (list (nth 2 data) (nth 3 data))
    )
    (setq p1 (list (- (car cen-point) (* a 0.5))
                   (- (cadr cen-point) (* b 0.5))
             )
          p2 (list (+ (car cen-point) (* a 0.5))
                   (+ (cadr cen-point) (* b 0.5))
             )
    )
    (command "_.rectang" p1 p2)
;;;这一步该怎么写？
  )
  (close ff)
  (setvar "osmode" os)
  (command "zoom" "Extents")
  (princ)
)[/php]

kevinchan

学习中，非常谢谢ljpnb~~