[LISP函数]：COMMAND "COPY" 生成的实体如何才能选上啊

litss

用entlast只能选到新生成的一堆实体中的最后一个。用参数”p“又只能选到被拷贝的原对象。

如何是好啊？

caoyin

试试这个方法！
先执行(setq e (entlast))

再执行 copy

(lt:ss-entnext e)返回的选择集就是你要的
;;        〓 (lt:ss-entnext en) 〓
;;  [功能] 获取在图元 en 之后产生的图元的选择集
;;  [参数] en----图元名
;;  [返回] 选择集
;;  [测试]1.(setq ent (entlast))
;;          执行创建图元的命令，如 LINE,BOUNDARY
;;          (setq lst (lt:ss-entnext ent))
;;        2.(setq s (lt:ss-entnext (car(entsel))))
(defun lt:ss-entnext (en / ss)
  (setq ss (ssadd))
  (while en (setq en (entnext en)) (if en (ssadd en ss)))
  (if (zerop (sslength ss)) (setq ss nil))
  ss
)

litss

非常感谢！我马上试试

昨天在网上也找到一个类似的。但是不太好用：（。我把C：去掉了，改成内部函数，并让它返回选择集（删掉了princ）命令。结果在command命令中直接用（ss-selnew）时，还是出错。不明白为什么：（
[PHP]
;; SELNEW.LSP
;; Copyright (c) 2005 caddzone.com
;;
;; Distributed under fair use license: You are free
;; to use this software privately for any purpose, but
;; you may not publicly copy, distribute or publish it.
;;
;; Simple, safe, and stable way to select all objects
;; created by the most recently used command.
;;
;; After completion of a command that creates one or
;; more new objects, simply enter the SELNEW command,
;; to select those objects.
;;

(if (not *ssnew-cmd-reactor*)
(setq *ssnew-cmd-reactor*
(vlr-command-reactor nil
'((:vlr-commandWillStart . ssnew_command_willstart))
)
)
)

(defun ssnew_command_willstart (reactor args)
(setq *ssnew-entlast* (entlast))
(princ)
)

(defun C:SELNEW ( / e ss)
(if *ssnew-entlast*
(progn
(setq e *ssnew-entlast*)
(setq ss (ssadd))
(while (setq e (entnext e))
(ssadd e ss)
)
(if (not (zerop (sslength ss)))
(sssetfirst ss ss)
)
)
)
(princ)
)[/PHP]

caoyin

反应器的方法我也写过，但没有 entnext 简单

litss

：）已试过，非常合用。谢谢！

提前setq一个entlast，感觉有点象预设一个undo点，呵呵。

可惜一开始没想到这么做

carrot1983

我的相法是。。。可以用论坛里有关于。。选择集的交差并集的贴子。
然后再进行编排就可。