[求助]：如何实现NO1,NO2,NO3......数值自动变化？？？

cat516

求助各位：近日画一建筑施工图，有数百个桩，需要给每个桩编号NO1,NO2,NO3......,如果每个桩的编号都要手动一个个更改很麻烦，而且很容易出错，AUTOCAD(我用的是AUTOCAD2006)有没有方法实现给第一个桩标示NO1后，其他的用连续复制NO1,数值会自动变成NO2,NO3,NO4......,是不是可以做一个动态块实现此功能？？？本人对CAD了解不是很精深，烦劳各位高手帮帮忙，想想办法，本人现在郁闷透了，任务很紧，20号之前要交任务，所以请大家想想办法

yi.gao

ET

超级北极熊

楼上的，ET？

这个问题我也很想知道怎么解决。

我对ET不了解，ET要另外安装咯？

lzws03

将以下文字复制到一个文本文档中，做成一个　LSP　文件，加载后运行　NU　即可使单行文字拷贝时自动增加了。


--------------------------------------------------------------------------------------------------------------------

;;; 拷贝数字 数字自动增加程序
(defun c:nu (/ origent origentdata origtext numtext prefixlen prefix num
           cmd addn pt1 pt2 newdata txt
        )
  (setq copyincolderrorfunc *error*)
  (setq *error* copyincerrorfunc)
  (command "_.undo" "_Group")
  (setq cmd (getvar "cmdecho"))
  (setvar "cmdecho" 0)
  (while (= origent nil)
    (setq origent (entsel "\n选择文本: "))
  )
  (setq txt (car origent))
  (setq origentdata (cdr (entget (car origent))))
  (if (/= (cdr (assoc 0 origentdata)) "TEXT")
    (princ "未选择文本.")
    (progn
      (setq origtext (cdr (assoc 1 origentdata)))
      (setq numtext (getsuffixdigits origtext))
      (if (= numtext "")
    (princ "此文本不是以数字结尾")
    (progn
      (setq prefixlen (- (strlen origtext) (strlen numtext)))
      (if (= prefixlen 0)
        (setq prefix "")
        (setq prefix (substr origtext 1 prefixlen))
      )
      (setq num (atoi numtext))
      (setq addn (getint "\n请输入增值(默认为1): "))
      (if (= addn nil)
        (setq addn 1)
      )
      (setq pt1 (getpoint "\n基准点:"))
      (setq pt2 0)
      (while (progn
           (initget 128)
           (setq pt2 (getpoint pt1 "\n拷贝至 (点回车键退出): "))
         )
        (if (/= pt2 nil)
          (progn
        (setq num (+ num addn))
        (setq num (itoa num))
        (setq newdata (strcat prefix num))
        (command "copy" txt "" pt1 pt2)
        (command "change" (entlast) "" "" "" "" "" "" newdata)
        (setq num (atoi num))
          )
        )
      )
    )
      )
    )
  )
  (setq *error* copyincolderrorfunc)
  (princ)
  (setvar "cmdecho" cmd)
  (command "_.undo" "_end")
)
(defun getsuffixdigits (origstr / digits prefixlen char)
  (setq digits "")
  (setq prefixlen (strlen origstr))
  (while (> prefixlen 0)
    (setq char (substr origstr prefixlen 1))
    (if (wcmatch char "#")
      (progn
    (setq digits (strcat char digits))
    (setq prefixlen (1- prefixlen))
      )
      (setq prefixlen 0)
    )
  )
  (setq digits digits)
)
(setq copyincolderrorfunc nil)
(defun copyincerrorfunc (msg)
  (if (= msg "function cancelled")
    (princ " ")
    (if (= msg "quit / exit abort")
      (princ " ")
      (princ (strcat "\nerror: " msg))
    )
  )
  (setq *error* copyincolderrorfunc)
  (princ)
)


--------------------------------------------------------------------------------------------------------------------

想在附件中上传此小程序，但怕不能下载，所以帖出了源码。　详细的加载及使用方法不多说了，不会的在本论坛中查找或者去问 yi.gao 。

yi.gao

你倒真会给我安排工作，我能拒绝吗？

wayi2002

我经常输入1号楼、2号楼、3号楼。。。。。。，如1楼主所说能实现，就太方便了。

yi.gao

耶，真的哦

yi.gao

耶，真的哦

782150yhm

假的哦。

yi.gao

真假难辨哦

lzws03

呵呵，单行文字，数字在末尾的时候拷贝会自动增加，但有时候也不能用，不知道为什么。　一般新建一张图保证就能用此命令，具体与哪里冲突就不知道了。　哪位知道指点一下。

多行文字就别试了，我试过，不能用。

yi.gao

有时候能用就行

yi.gao

就是这样的

wayi2002

数字在前面怎么用呢？谢谢

yi.gao

ET