[求助]：框选延长的程序

chen10jing

既然能做一个框选剪切，可否做一个框选延长的程序，以框选的第二点的ｘ坐标或ｙ坐标为准作为延长边界，有些延长本来就不需要很准确的，还要画一条线作为延长边界，然后还要删除，很麻烦。

zxq0220

[php]
;晓东 zxq0220 框选延长 2007.10.7
(DEFUN C:TT ()
(SETVAR "CMDECHO" 0)
(SETQ OLDOS (GETVAR "OSMODE"))
(IF (AND (SETQ P1 (GETPOINT "\nNear Line Point 近线一点 :"))
          (SETQ P2 (GETCORNER P1 "\nNext Point  下一点 :"))) (PROGN
  (SETVAR "OSMODE" 0)
  (COMMAND "LENGTHEN" "DY" P1 P2 "")
  (SETVAR "OSMODE" OLDOS)
))
(SETVAR "CMDECHO" 1)
(PRINC)
)
[/php]

黄河之水

(defun C:DDED()  (command "_lengthen" "dy"))
这样行不？不过只能单选一根线，该不会几根线一起延长吧！

露水2

修改修改可多选

chen10jing

程序非常好,可是有局限性,二个程序都只能每次延长一根,而且先选定直线的端点,否则无法延长,可否改为先框选一下,构成一个虚拟的边界,然后选择要延长的线,将选择的线延长到以框选的虚拟边界的结束点的X坐标或Y坐标为准的虚拟边界线上.

caiqs

www.shixiong2.ys168.com

chen10jing

不知是我没有找到还是没有，我没有找到能达到目的的程序呀，请楼主帮忙发一个，非常感谢！

zml84

[php]
;;;功能：矩形边界内对象的延伸
(vl-load-com)
(defun C:TT (/ PT1 PT2 SS I EN PT)
    (setvar "CMDECHO" 0)
    (if        (and (setq PT1 (getpoint "\n指定第一个角点: "))
             (setq PT2 (getcorner PT1 ">>对角点: "))
             (setq SS (ssget "w" PT1 PT2))
        )
        (progn
            ;;
            (command "_.rectang" "non" PT1 "non" PT2)
            ;;
            (command "_.EXTEND" (entlast) "")
            (setq I 0)
            (repeat (sslength SS)
                (setq EN (ssname SS I))
                (if (setq PT (vlax-curve-getstartpoint EN))
                    (command (list EN PT))
                )
                (if (setq PT (vlax-curve-getendpoint EN))
                    (command (list EN PT))
                )
                (setq I (1+ I))
            )
            (command "")
        )
    )
    (setvar "CMDECHO" 1)
    (princ)
) ;_结束 defun
[/php]
http://www.acad.net.cn/viewthrea ... &extra=page%3D1

zxq0220

这样试试
[php]
;晓东 zxq0220 框选延长 2007.10.9
(DEFUN C:TT ()
(SETVAR "CMDECHO" 0)
(SETQ OLDOS (GETVAR "OSMODE"))
(IF (AND (SETQ P1 (GETPOINT "\nFirst Point 第一点 :"))
          (SETQ P2 (GETCORNER P1 "\nNext Point  下一点 :"))
                  (SETQ SS (SSGET "c" P1 P2))) (PROGN
  (SETVAR "OSMODE" 0)
  (COMMAND "_.RECTANG" P1 P2)
  (SETQ S1 (ENTLAST))
  (COMMAND "_.EXTEND" S1 "")
  (REDRAW S1 3)
  (IF (> (CAR P1) (CAR P2))
   (SETQ XMIN (CAR P2) XMAX (CAR P1))
   (SETQ XMIN (CAR P1) XMAX (CAR P2))
  )
  (IF (> (CADR P1) (CADR P2))
   (SETQ YMIN (CADR P2) YMAX (CADR P1))
   (SETQ YMIN (CADR P1) YMAX (CADR P2))
  )
  (SETQ I -1)
  (REPEAT (SSLENGTH SS)
   (SETQ EN (SSNAME SS (SETQ I (1+ I)))
         PT1 (CDR (ASSOC 10 (ENTGET EN)))
                 PT2 (CDR (ASSOC 11 (ENTGET EN))))
   (IF (< XMIN (CAR PT1) XMAX) (COMMAND (LIST EN PT1))
    (IF (< XMIN (CAR PT2) XMAX) (COMMAND (LIST EN PT2))
     (IF (< YMIN (CADR PT1) YMAX) (COMMAND (LIST EN PT1))
      (IF (< YMIN (CADR PT2) YMAX) (COMMAND (LIST EN PT2)))
         )
    )
   )
  )
  (COMMAND "")
  (COMMAND "ERASE" S1 "")
  (SETVAR "OSMODE" OLDOS)
))
(SETVAR "CMDECHO" 1)
(PRINC)
)
[/php]

chen10jing

程序还需要改进,都只能框选着实体才可延长,这样的话在整幅图面上,大量的实体的情况下,要延长其中的极小部分,根本无法选择,所以没法用.需要做成先框选一个虚拟边界,然后点选或框选需要延长的实体,这样才有用.此程序的目的只是避免延长时去先画并不严格要求的边界,然后延长.再删除边界线,省点功夫,如此程序则一点功夫也没有省.

zml84

[php]
;;;以横竖相交的xline为边界
(defun C:TT3 (/ PT1 S0 S1 S2)
    (setvar "CMDECHO" 0)
    (if        (setq PT1 (getpoint "\n指定点位: "))
        (progn
            ;;
            (command "_.xline" "h" "non" PT1 "")
            (setq S0 (entlast))
            (command "_.xline" "v" "non" PT1 "")
            (setq S1 (entlast))
            ;;
            (command "_.EXTEND" S0 S1 "")
            (while (setq S2 (entsel "\n点取对象: "))
                (command S2)
            )
            (command "")
            (command "_erase" S0 S1 "")
        )
    )
    (setvar "CMDECHO" 1)
    (princ)
) ;_结束 defun
[/php]

zml84

[php]
;;;以横竖相交的xline为边界
(defun C:TT3 (/ PT1 S0 S1 S2)
    (setvar "CMDECHO" 0)
    (if        (setq PT1 (getpoint "\n指定点位: "))
        (progn
            ;;
            (command "_.xline" "h" "non" PT1 "")
            (setq S0 (entlast))
            (command "_.xline" "v" "non" PT1 "")
            (setq S1 (entlast))
            ;;
            (command "_.EXTEND" S0 S1 "")
            (while (setq S2 (entsel "\n点取对象: "))
                (command S2)
            )
            (command "")
            (command "_erase" S0 S1 "")
        )
    )
    (setvar "CMDECHO" 1)
    (princ)
) ;_结束 defun
[/php]

chen10jing

我所提到的问题任未得到解决，一是对实体的选择不方便，第二是选点后中途退出时的边界会保留，希望解决这二个问题。




提了好几些天了，很好的程序，每次都只是搞到一半就不管了，不管求助人的需要，弄的不知道用好还是不用好，还是要对程序负责到底才是好程序呀。

xdcad9819

收藏收藏好好好好好