[已解决]：如何把一组字符串折散为一个以单独字符构成的表?

Wildcat

请问 如何把一组字符串折散为一个以单独字符构成的表(需要支持中文字符)?

我只能想出字符串中仅有英文字符的解决方法

2. 
   
3.   [FONT=courier new]
   
4. 
   
5. (defun R_sub (string)
   
6.   (setq R_sub_n 1
   
7.         R_sub_list nil)
   
8.   (repeat (strlen string)
   
9.     (setq R_sub_list (cons (substr string R_sub_n 1) R_sub_list)
   
10.           R_sub_n (1+ R_sub_n)
    
11.     )
    
12.   )
    
13.   (reverse R_sub_list)
    
14. )
    
15. 
    
16.   [/FONT]
    

<br />   [FONT=courier new]<br /> <br /> (defun R_sub (string)<br />   (setq R_sub_n 1<br />         R_sub_list nil)<br />   (repeat (strlen string)<br />     (setq R_sub_list (cons (substr string R_sub_n 1) R_sub_list)<br />           R_sub_n (1+ R_sub_n)<br />     )<br />   )<br />   (reverse R_sub_list)<br /> )<br /> <br />   [/FONT]<br />

例如:

(setq a "L0124")

(R_sub a)

则得到 ("L" "0" "1" "2" "4")

但如果a中含有中文字符,则结果异常。
曾想用ascii和chr这对函数，判断独立的字符是中文还是英文，但行不通。

请问如何可以使其支持中文字符？

雨箭风刀

方法1
vl-string->list 根据数据是否大于159
方法2.
用vb对字的判断（自动将汉字判断为一个“字”）。 引申：用vba，vbscript均可。

zml84

按照2楼方法1，代码如下：
[php]
(vl-load-com)
;;;功能：字符拆分
(defun TEST (STR / LST LST2 N lst3)
    (setq LST (vl-string->list STR))
    (setq LST2 '())
    (while LST
        (setq N (car LST))
        (if (> N 159)
            (setq LST3 (list N (cadr LST))
                  LST  (cdr LST)
            )
            (setq LST3 (list N))
        )
        (setq LST2 (cons (vl-list->string LST3) LST2)
              LST  (cdr LST)
        )
    )
    (reverse LST2)
)
[/php]

leeyuan

经验证，3楼的代码可行

xshrimp

;仅仅支持英文.
[php]
(defun txt-str2lst (str)
(mapcar  'chr  (vl-string->list str)  )
)
[/php]

支持中文
[php]
(defun gps->str-2lst (string / i lst tmp_str)
  (setq i 1 lst nil)
  (while (/= ""  (setq tmp_str (substr string i 1)))  
  (if (> (ascii tmp_str) 159)
       ;中文字符
       (setq tmp_str (substr string i 2) i (+ i 2))               
       ;非中文
       (setq tmp_str (substr string i 1) i (+ i 1))
      )  
  (setq lst (append lst (list tmp_str)))
  )  
)
[/php]
命令: (gps->str-2lst "a b  cd 中文支持ABCD*&^%1234") ("a" " " "b" " " " " "c"
"d" " " "中" "文" "支" "持" "A" "B" "C" "D" "*" "&" "^" "%" "1" "2" "3" "4")

Wildcat

谢谢大家的帮忙，问题已解决。

Wildcat

谢谢大家的帮忙，问题已解决。

雨箭风刀

凑个热闹，用正则表达式。
[php]
;|实例：
(xxexp "."  "setqL0124少1 ,至.2∑μ1数" )
->返回： ("s" "e" "t" "q" "L" "0" "1" "2" "4" "少" "1" " " "," "至" "." "2" "∑" "μ" "1" "数")
|;

;|正则表达式分断字符串---by lxx|;
(defun xxexp (pat str / end)
  (vl-load-com)
  (setq *xxvbsexp (vlax-get-or-create-object "VBScript.RegExp"))
  (vlax-put *xxvbsexp 'Pattern pat)
  (vlax-put *xxvbsexp 'Global -1)
  (setq matches (vlax-invoke *xxvbsexp 'Execute str))
  (vlax-for x matches (setq end (cons (vla-get-value x) end)))
  (reverse end)
)
[/php]

它山之石

屠文刀
嘿嘿