[求助]：找出最长与最短线段

ap0307227

求一个能在众多线段中，找出最长与最短线段的LISP，谢谢~~

zml84

获取每一个的长度，然后 min  max

ap0307227

谢谢zml84 的回答，但我刚学，不会写，能否帮我写一下呢？谢谢 ~

zml84

[php]
(defun C:TT (/ SS LST_LEN I EN ENT PT0 PT1 LEN A B)
    (if        (setq SS (ssget '((0 . "LINE"))))
        (progn
            ;;获取全部长度
            (setq LST_LEN '()
                  I 0
            )
            (repeat (sslength SS)
                (setq EN  (ssname SS I)
                      ENT (entget EN)
                      PT0 (cdr (assoc 10 ENT))
                      PT1 (cdr (assoc 11 ENT))
                )
                (setq LEN     (distance PT0 PT1)
                      LST_LEN (cons LEN LST_LEN)
                )
                (setq I (1+ I))
            )
            ;;找最大最小
            (setq A (apply 'max LST_LEN)
                  B (apply 'min LST_LEN)
            )
            ;;显示输出
            (princ "\n最长: ")
            (princ A)
            (princ "\n最短: ")
            (princ B)
        )
    )
    (princ)
)
[/php]

ap0307227

实在万分感谢zml84，嘻，能否加个要求，把最长与最短用颜色区分一下呢？我也试一下，呵！

zml84

[php]
(defun C:TT (/ SS LST I ENT ENT0 ENT1)
    (if        (and (setq SS (ssget '((0 . "LINE"))))
             (>= (sslength SS) 2)
        )
        (progn
            ;;获取全部对象组码
            (setq LST '()
                  I   0
            )
            (repeat (sslength SS)
                (setq ENT (entget (ssname SS I))
                      LST
                          (cons ENT LST)
                )
                (setq I (1+ I))
            )
            ;;按照长度排序
            (setq LST (vl-sort LST
                               '(lambda        (ENT0 ENT1)
                                    (< (distance (cdr (assoc 10 ENT0))
                                                 (cdr (assoc 11 ENT0))
                                       )
                                       (distance (cdr (assoc 10 ENT1))
                                                 (cdr (assoc 11 ENT1))
                                       )
                                    )
                                )
                      )
            )
            ;;挑出最大最小
            (setq ENT0 (car LST)
                  ENT1 (last LST)
            )
            ;;变色
            (if        (assoc 62 ENT0)
                (setq ENT0 (subst (cons 62 1) (assoc 62 ENT0) ENT0))
                (setq ENT0 (cons (cons 62 1) ENT0))
            )
            (entmod ENT0)
            (if        (assoc 62 ENT1)
                (setq ENT1 (subst (cons 62 2) (assoc 62 ENT1) ENT1))
                (setq ENT1 (cons (cons 62 2) ENT1))
            )
            (entmod ENT1)
            ;;显示输出
            (princ "\n最短: ")
            (princ (distance (cdr (assoc 10 ENT0))
                             (cdr (assoc 11 ENT0))
                   )
            )
            (princ "\n最长: ")
            (princ (distance (cdr (assoc 10 ENT1))
                             (cdr (assoc 11 ENT1))
                   )
            )
        )
    )
    (princ)
)
[/php]

ap0307227

哇，实在强~~原以为加一点点，谁知加这么多，实在佩服，万万分感谢！

xyp1964

2. [FONT=courier new];; 最长最短线变色
   
3. (defun c:test778 ()
   
4.   (CMDLA0)
   
5.   (if (setq ss (ssget '((0 . "LINE"))))
   
6.     (progn
   
7.       (setq slst (xyp-SS2List ss)
   
8.             slst (vl-sort slst
   
9.                           '(lambda (s1 s2)
   
10.                              (< (xyp-get-CurveLength s1) (xyp-get-CurveLength s2))
    
11.                            )
    
12.                  )
    
13.       )
    
14.       (xyp-put "color" (car slst) 1)
    
15.       (xyp-put "color" (last slst) 2)
    
16.     )
    
17.   )
    
18.   (CMDLA1)
    
19. )[/FONT]

[FONT=courier new];; 最长最短线变色<br /> (defun c:test778 ()<br />   (CMDLA0)<br />   (if (setq ss (ssget '((0 . "LINE"))))<br />     (progn<br />       (setq slst (xyp-SS2List ss)<br />             slst (vl-sort slst<br />                           '(lambda (s1 s2)<br />                              (< (xyp-get-CurveLength s1) (xyp-get-CurveLength s2))<br />                            )<br />                  )<br />       )<br />       (xyp-put "color" (car slst) 1)<br />       (xyp-put "color" (last slst) 2)<br />     )<br />   )<br />   (CMDLA1)<br /> )[/FONT]