[编程申请]：梁配筋与面积---文字关联的程序

xingbaoquan99

如图，3根20和面积9关联，如果将20改成18或者小于20的数，自动计算面积和9比较，如果小于9，字体颜色自动变成红色，希望论坛里的大侠能编一下，或者给出思路，越详细越好。谢谢。

xingbaoquan99

最初由 carrot1983 发布
[B]好想法。
第一反应就是用到反应器。

问题是：也是第一步

如何实现一一对应。

让图形中的3根20与9对应，4根25与19对应。。。等等

一个一个选择吗？

楼主，有思路的话，应该就可以写出程序来 [/B]

反应器还不会，只知道应该用到反应器，但是没有反应器的教程。

carrot1983

好想法。
第一反应就是用到反应器。

问题是：也是第一步

如何实现一一对应。

让图形中的3根20与9对应，4根25与19对应。。。等等

一个一个选择吗？

楼主，有思路的话，应该就可以写出程序来

carrot1983

参考了： http://www.xdcad.net/forum/showthread.php?s=&threadid=658253

写出了这个代码：但是有不足，不能改颜色。
;;如果使用(vla-put-color NOTIFIER-OBJECT 1);改成红色 会出现提示 ; 错误: AutoCAD.Application: 对象正在通知

[php]
(vl-load-com)
                                        ;(vlr-remove-all)
;;梁配筋与面积---文字关联的程序  By carrot1983 2009-03-24
(defun C:TT (/ A D DATA_LIST E E1 I N PAT V1 VLA_OWN_LIST)
  (setq E1 (car (entsel "\n选择satwe计算值: ")))
  (setq E (car (entsel "\n选择平法梁配筋文字: ")))

  (setq DATA_LIST (list (cdr (assoc 5 (entget E1))))) ;_句柄表，它们将是反应器的关联数据

  (setq VLA_OWN_LIST (list (vlax-ename->vla-object E))) ;_vla对象表，它们将是反应器的所有者

  ;;反应器链接到<平法梁配筋文字 E>，<satwe计算值 E1>为关联数据，当修改<平法梁配筋文字 E>时，调用函数@CJW-BEAM-AREA
  ;;永久反应器
  (vlr-pers
    (vlr-object-reactor
      VLA_OWN_LIST
      DATA_LIST
      '((:vlr-modified . @CJW-BEAM-AREA))
    )
  )
  (princ)
)

(defun @CJW-BEAM-AREA (NOTIFIER-OBJECT               REACTOR-OBJECT
                       PARAMETER-LIST               /           AREA
                       D           DATA_LIST   E1           I
                       N           PAT               TXT           V1
                      )
  ;;反应器的所有者 <平法梁配筋文字>的文字内容
  (setq TXT (vla-get-textstring NOTIFIER-OBJECT))
  
  (setq DATA_LIST (vlr-data REACTOR-OBJECT)) ;_获取反应器的关联数据: 句柄表
  (setq E1 (handent (car DATA_LIST))) ;_取得<satwe计算值 E1>图元名

  ;;反应器的关联数据<satwe计算值>的文字内容
  (setq V1 (CJW-DXF 1 (entget E1)))

  ;;计算平法梁配筋文字面积 AREA
  (cond        ((vl-string-search "%%130" TXT)
         (setq PAT "%%130")
        )
        ((vl-string-search "%%131" TXT)
         (setq PAT "%%131")
        )
        ((vl-string-search "%%132" TXT)
         (setq PAT "%%132")
        )
  )
  (setq I (vl-string-search PAT TXT))
  (setq N (atoi (substr TXT 1 I)))
  (setq D (atoi (substr TXT (+ 1 5 I) (strlen TXT))))
  (setq AREA (* 0.01 (* N pi (expt D 2) 0.25))) ;_梁筋面积

  (if (< AREA (read V1)) ;_配筋值小于计算值时提示
    ;;如果使用(vla-put-color NOTIFIER-OBJECT 1);改成红色 会出现提示 ; 错误: AutoCAD.Application: 对象正在通知
    (alert "\n配筋值小了。。")
  )
  (princ)
)
[/php]

baolanjun

期待后面的内容,包括程序的思路

xingchao1350

好创意，支持