[求助]：cad中的数字消除尾零的问题

chen10jing · 发表于 2009-6-23 09:43:56

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

请教，在cad里面处理数据时，是否有办法消除数字的尾零，例如12.3500，变为12.35，120.30变为120.3等。数据量庞大，需要手改，十分麻烦，谢谢各位。

Underway · 发表于 2009-6-23 11:58:33

check DimZin 帮助

chen10jing · 发表于 2009-6-23 21:49:48

不懂，我说的是文本数字，不是标注数字，希望能程序实现。

Underway · 发表于 2009-6-24 12:08:41

Command: (setq a "12.3500")
"12.3500"

Command: (rtos (atof a))
"12.35000"

Command: dimzin
Enter new value for DIMZIN <0>: 8

Command: (rtos (atof a))
"12.35"

chen10jing · 发表于 2009-6-24 15:01:13

不懂这个是什么意思，如何使用？dimzin变量只能控制标注数字中的0，文本如何实现？

Underway · 发表于 2009-6-24 16:02:10

您注意到上例的结果上怎么样得出的吗?

chen10jing · 发表于 2009-6-24 20:22:11

我不懂这个程序，所以不清楚，请指点一下，非常感谢！

Underway · 发表于 2009-6-25 08:38:40

若您不懂程序且上传个图例文件(*.dwg)如何?
这样方便分析资料 ....

chen10jing · 发表于 2009-6-25 09:48:56

上传一个样图，请大家帮帮忙，万分感谢！

Underway · 发表于 2009-6-25 10:37:37

下载不了呢?
您自个儿试试能否下载?
ftp://p4.xdcad.net/591210_%D1%F9%CD%BC.rar
晓东常有这么样下载不了的情形....

gysjy · 发表于 2009-6-25 10:42:29

最初由 chen10jing 发布
[B]请教，在cad里面处理数据时，是否有办法消除数字的尾零，例如12.3500，变为12.35，120.30变为120.3等。数据量庞大，需要手改，十分麻烦，谢谢各位。 [/B]

[PHP](defun c:nn ( / e1 en l lop n nam ss str)
(princ "\n欢迎使用尾数清零程序！ gysjy.2009.6.25")
(setq ss (ssget '((0 . "TEXT"))) n 0 )
(repeat (sslength ss)
   (setq en (entget (ssname ss n)) n (1+ n)
         nam (cdr (assoc 1 en)) l (strlen nam)
         lop t
   )
   (while lop
   (setq  str (substr nam l))
   (if (= str "0")
      (setq nam (substr nam 1 (- l 1)) l (strlen nam))
      (setq lop nil)
   )
   )
   (princ nam) (princ " ")
   (setq e1 (subst (cons 1 nam) (assoc 1 en) en))
   (entmod e1)
)
(princ)
)[/PHP]

chen10jing · 发表于 2009-6-25 11:33:45

功能强大，见0就清，而且实现一次多选，非常好用。
但还有个问题，就是当是整数的时候，能清除小数点后的0，不能清除小数点，而且当整数没有小数点而且后面有0时，一并清掉了，例如500，最后给清成5了，能否实现把这二点过滤掉，这样就可以实现一次全部选取，不管是什么样的数字，都选上，由程序去默认清不清。

gysjy · 发表于 2009-6-25 15:49:37

最初由 chen10jing 发布
[B]
但还有个问题，就是当是整数的时候，能清除小数点后的0，不能清除小数点，而且当整数没有小数点而且后面有0时，一并清掉了，例如500，最后给清成5了，能否实现把这二点过滤掉.. [/B]

现将程序修改如下：
[PHP](defun c:nn ( / e1 en k l lop n nam ss str)
(princ "\n欢迎使用尾数清零程序！ gysjy.2009.6.25")
(setq ss (ssget '((0 . "TEXT"))) n 0 )
(repeat (sslength ss)
   (setq en (entget (ssname ss n)) n (1+ n)
         nam (cdr (assoc 1 en)) l (strlen nam)
         k 0 lop nil
   )
   (while (< k l)
   (setq k (1+ k) str (substr nam k 1))
   (if (= str ".")(setq lop t))
   )
   (while lop
   (setq  str (substr nam l))
   (if (= str "0")
      (setq nam (substr nam 1 (- l 1)) l (strlen nam))
      (setq lop nil)
   )
   )
   (if (= str ".")(setq nam (substr nam 1 (- l 1))))
   (princ nam) (princ " ")
   (setq e1 (subst (cons 1 nam) (assoc 1 en) en))
   (entmod e1)
)
(princ)
)[/PHP]

carrot1983 · 发表于 2009-6-25 17:31:11

最初由 Underway 发布
[B]Command: (setq a "12.3500")
"12.3500"

Command: (rtos (atof a))
"12.35000"

Command: dimzin
Enter new value for DIMZIN <0>: 8

Command: (rtos (atof a))
"12.35" [/B]

如果是纯数字，用这个方法就可以了。

Underway已经把思路给楼主了，楼主不能太懒啊。。。

(defun C:TT (/ DIMZIN E ELIST I SS)
(princ "\n纯数字消零 By carrot1983 6/25/09")
(setvar "CMDECHO" 0)
(command "._UNDO" "_END")
(command "._UNDO" "_BEGIN")
(setq DIMZIN (getvar "DIMZIN"))
(setvar "DIMZIN" 8)
(if (setq SS (ssget '((0 . "TEXT") (1 . "~*[~`--9]*"))))
(repeat (setq I (sslength SS))
(setq E (ssname SS (setq I (1- I))))
(setq ELIST (entget E))
(entmod
(subst (cons 1 (rtos (read (cdr (assoc 1 ELIST))) 2))
(assoc 1 ELIST)
ELIST
)
)
)
)
(setvar "DIMZIN" DIMZIN)
(command "._UNDO" "_END")
(princ)
)

zml84 · 发表于 2009-6-26 18:33:21

楼上代码较好，有两个亮点：
1. (ssget '((0 . "TEXT") (1 . "~*[~`--9]*"))) 选取纯数字
2.. 使用rtos 去消零。

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：cad中的数字消除尾零的问题

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

Re: [求助]：cad中的数字消除尾零的问题