[求助]：求和的程序中加一内容

yaya-54

(defun c:sum ()
  (command "_.undo" "begin")
  (princ "\n选择被加数字对象:")
  (setq        ss  (ssget '((0 . "TEXT")))
        i   0
        sum 0
  )
  (cond
    ((> (setq n (sslength ss)) 0)
     (repeat n
       (setq sum (+ sum (atof (cdr (assoc 1 (entget (ssname ss i))))))
             i         (1+ i)
       )
     ) ;_repeat
     (entmod
       (subst
         (cons 1 (rtos sum 2 0))
         (assoc        1
                (setq ent (entget (car (entsel "\n选择要更新的结果"))))
         )
         ent
       )
     )
    ) ;_cond 1
    (t (princ "\n没有选中单行文字对象!")) ;_cond 2
  ) ;_cond
  (command "_.undo" "end")
  (princ)
) ;_enddefun
这个求和计算当没有选择要更新的结果时，计算结果就是参数类型错误: lentityp nil，如何让它变成就算没有选择要更新的结果时，计算结果也会显示在命令行中。

cy956

(defun        c:sum ()
   (command "_.undo" "begin")
   (princ "\n选择被加数字对象:")
   (setq ss  (ssget '((0 . "TEXT")))
         i   0
         sum 0
   )
   (cond
     ((> (setq n (sslength ss)) 0)
      (repeat n
        (setq sum (+ sum (atof (cdr (assoc 1 (entget (ssname ss i))))))
              i          (1+ i)
        )
      ) ;_repeat
      (setq e1(entsel "\n选择要更新的结果"))
      (if e1(progn
        (setq ent(entget (car e1)))      
        (entmod        (subst (cons 1 (rtos sum 2 0))(assoc 1 ent) ent))
        )
        (princ (strcat "\n合计为:" (rtos sum 2 0)))
        )
     ) ;_cond 1
     (t (princ "\n没有选中单行文字对象!")) ;_cond 2
   ) ;_cond
   (command "_.undo" "end")
   (princ)
) ;_enddefun


没校验,你自己测试

yaya-54

可以用。谢谢!：)