同名块插入后被取代的问题

众山小

在明经论坛看见了这样的帖子，和我最近遇见问题一样，转的帖子如下：
不知道i大家有没有遇到这样的问题，给其他专业提供建筑最新图纸时，其他专业却反馈图纸并没有修改。最后的原因却是“同名图块”在作怪！原来其他专业图纸中存在与建筑新提图纸中的“同名图块”，这样新图块插入时被就原图块取代了，插入后自然看不出图纸变化。
这样最后结果是，建筑图纸和设备图纸不同，有时就匆忙出图了。
被这个问题纠结了好长一段时间。今天到网上一搜，不少网友和我存在同样的苦恼，但却并没有找到合适的解决方法。

众山小

这是明经G版的源码，很不错！但是还是没有完全达到我所希望的目的，因为只看得懂简单程序，所以希望大家帮忙！谢谢！

[pcode=lisp,true];;选择文件插入，同时更新本图的图块 By Gu_xl 2013.04.02
(defun c:ins (/                  DWGNAME     DBXDOC          ACVER
              DBXMODELSPACE              BLOCKS          DOC
              DBXBLOCKNAMES              OBJS
             )
  (setq DwgName (GETFILED "选择引入图块的DWG文件" "" "dwg" 4))
  (if
    (and
      DwgName
      (not
        (equal (strcase DwgName)
               (strcase (strcat (getvar "dwgprefix") (getvar "dwgname")))
        )
      )
    )
     (progn
       (setq
         DBXDOC        (vla-GetInterfaceObject
                  (vlax-get-acad-object)
                  (if (< (setq acVer (atoi (getvar "ACADVER"))) 16)
                    "ObjectDBX.AxDbDocument"
                    (strcat "ObjectDBX.AxDbDocument." (itoa acVer))
                  )
                )
       )
       (vla-open DBXDOC DWGNAME)
       (setq DBXModelSpace (vla-get-ModelSpace DBXDOC))
       (setq blocks (vla-get-blocks
                      (setq
                        doc (vla-get-ActiveDocument (vlax-get-acad-object))
                      )
                    )
       )
       (vlax-for blk (vla-get-blocks DBXDOC)
         (if (not (or (eq :vlax-true (vla-get-isXRef blk))
                      (eq :vlax-true (vla-get-isLayout blk))
                      (= "*U" (substr (vla-get-name blk) 1 2))
                      (= "*D" (substr (vla-get-name blk) 1 2))
                      (= "*T" (substr (vla-get-name blk) 1 2))
                  )
             )
           (setq dbxblocknames (cons (vla-get-name blk) dbxblocknames))
         )
       )
       (setq dbxblocknames
              (vl-remove-if-not
                '(lambda (x) (TBLSEARCH "BLOCK" x))
                dbxblocknames
              )
       )
       (if dbxblocknames
         (progn
           (foreach block dbxblocknames
             (vlax-for obj (vla-item blocks block) (vla-delete obj))
             (setq objs nil)
             (vlax-invoke
               dbxDoc
               'CopyObjects
               (vlax-for a (vla-item (vla-get-blocks DBXDOC) block)
                 (setq objs (cons a objs))
               )
               (vla-item blocks block)
             )
           )
           (vla-regen doc :vlax-true)
           (prompt
             (strcat "\n更新了" (itoa (length dbxblocknames)) "个图块！")
           )
         )
         (prompt "\n没有可更新的图块！")
       )
       (vlax-release-object DBXDOC)
       (command "insert" DwgName)
       (while (= 1 (logand (getvar 'cmdactive) 1)) (command pause))
     )
  )
  (princ)
)[/pcode]

众山小

这个程序有几方面能否在优化下：
1、程序能否增加个询问的步骤，“提示有几处同名块，是否替代”，有“取代，不取代”选项
2、程序能否增加另外一个询问的步骤，“是否圈出同名块区域”，有“圈出，不圈出”选项。（因为有时候图块太多，取代不一定准确，这样可以明确取代是否准确，尤其是相关专业图纸不明确时“
3、目前程序中，只取代了一个块，可程序反馈取代了5个块，不知道为什么？（替换插入时我已经pu过，且图面简单，不存在多的图块）

newer

众山小 发表于 2013-4-23 12:55

                               
登录/注册后可看大图

这个程序有几方面能否在优化下：
1、程序能否增加个询问的步骤，“提示有几处同名块，是否替代”，有“取代 ...

1、如果图中很多的重名块，难道你还要一个一个的确认？
2、还不如另外写个工具，选择两个区域，查找一个区域中和另外区域同名的块，这样更通用。
3、程序没看，有空看看程序在回复。

newer

其实，最关键的还是各专业有统一的图块命名规则，不要去影响到别人。

众山小

赞同！但是有时自己采用“在位编辑”修改了图块，然后传给设备专业，设备专业重新插入后，旧图块取代了新图块。

newer

众山小 发表于 2013-4-23 14:18

                               
登录/注册后可看大图

赞同！但是有时自己采用“在位编辑”修改了图块，然后传给设备专业，设备专业重新插入后，旧图块取代了新图 ...

这种情况，自己更新下图块就可以了。这句话不能说旧图块取代了新的，人家本来好好的在那里，是新的进来打搅人家了，而是应该说新的没有取代旧的。

既然你也有同样的问题，不妨说说你的要求，看看能不能有高手帮忙实现了。

炫翔

{:soso_e141:}没遇到过，在一个图档里面好像不准同名块的生成

429014673

我也经常遇到这样的情况

userzhl

遇到动态块会出问题。

casd

用设计中心可以解决，但要一个一个图块去点击。
我也希望可以有批量替换的方法。

userzhl

批量替换的话，ET里面就有现成的功能。

userzhl

选择个别图块进行替换的话，可以用下面的:
(setq ss (ssget (list (cons 0 "INSERT"))))
  (if ss
    (progn
      (setq i 0)
      (repeat (sslength ss)
(setq ents (entget (ssname ss i)))
(setq ents (subst (cons 2 BlkName) (assoc 2 ents) ents))
(entmod ents)
(setq i (1+ i))
      )
    )
  )