How to combine a .Net Jig and MessageFilter to catch user input

eachy · 发表于 2013-5-27 22:07:03

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

How to combine a .Net Jig and MessageFilter to catch user input such as Right Click?                                                       By Philippe Leefsma
  Here is a common question developers were asking to ADN support:
  I use a EntityJig derived class to let the user place a block reference in the dwg, it works fine but I would like to let the user get a null angle just giving a right click when prompted for the angle. Using "UserInputControls.NullResponseAccepted" doesn't seem to work as expected.
  Do you have a solution to handle that request?

  Solution
  Here is a complete VB.Net sample that illustrates ho to handle a MessageFilter within a Jig. The sample could be extended to monitor more user actions if needed.

Imports Autodesk.AutoCAD.ApplicationServices
Imports Autodesk.AutoCAD.DatabaseServices
Imports Autodesk.AutoCAD.EditorInput
Imports Autodesk.AutoCAD.Geometry
Imports Autodesk.AutoCAD.Runtime
Imports System.Runtime.InteropServices
'////////////////////////////////////////////////////////////////////
'// Use: Jig a newly created block reference
'// Author: Philippe Leefsma, September 2011
'////////////////////////////////////////////////////////////////////
Public Class JigMsgFilter
Inherits EntityJig
Private _position As Point3d
Private _filter As JigFilter
Public Sub New(ByVal btrId As ObjectId)
MyBase.New(New BlockReference(Point3d.Origin, btrId))
_position = Point3d.Origin
_filter = New JigFilter
System.Windows.Forms.Application.AddMessageFilter(_filter)
End Sub
Public Overloads ReadOnly Property Entity() As BlockReference
Get
Return MyBase.Entity
End Get
End Property
Protected Overloads Overrides Function Update() As Boolean
Entity.Position = _position
Return True
End Function
Protected Overloads Overrides Function Sampler( _
ByVal prompts As JigPrompts) _
As SamplerStatus
Dim jigOpts As JigPromptPointOptions = _
New JigPromptPointOptions(vbCrLf + "Specify position: "))
jigOpts.UserInputControls = _
UserInputControls.NullResponseAccepted
Dim res As PromptPointResult = prompts.AcquirePoint(
jigOpts)
If (res.Status <> PromptStatus.OK) Then
Return SamplerStatus.Cancel
End If
If (_position = res.Value) Then
Return SamplerStatus.NoChange
End If
_position = res.Value
Return SamplerStatus.OK
End Function
Public Function Run() As PromptStatus
Dim promptResult As PromptResult = _
Application.DocumentManager.MdiActiveDocument.Editor.Drag(Me)
Return promptResult.Status
End Function
'////////////////////////////////////////////////////////////
'// Use: Start Jig command
'//
'////////////////////////////////////////////////////////////
Public Shared Sub JigMsgFilter()
Dim doc As Document = _
Application.DocumentManager.MdiActiveDocument
Dim db As Database = doc.Database
Dim ed As Editor = doc.Editor
Dim res As PromptResult = _
ed.GetString(vbCrLf + "Enter block name to insert: ")
If res.Status <> PromptStatus.OK Then
Exit Sub
End If
Using Tx As Transaction = _
db.TransactionManager.StartTransaction()
Dim bT As BlockTable = Tx.GetObject( _
db.BlockTableId, _
OpenMode.ForRead)
If (Not bT.Has(res.StringResult)) Then
ed.WriteMessage(vbCrLf + "Block do not exist :(")
Exit Sub
End If
Dim btrId As ObjectId = bT(res.StringResult)
Dim jig As New JigMsgFilter(btrId)
If (jig.Run() <> PromptStatus.OK) Then
jig.Entity.Dispose()
Exit Sub
End If
Dim model As BlockTableRecord = Tx.GetObject( _
bT(BlockTableRecord.ModelSpace), _
OpenMode.ForWrite)
model.AppendEntity(jig.Entity)
Tx.AddNewlyCreatedDBObject(jig.Entity, True)
Tx.Commit()
End Using
End Sub
'////////////////////////////////////////////////////////////
'// Use: Implementation of message filter
'//
'////////////////////////////////////////////////////////////
Private Class JigFilter
Implements System.Windows.Forms.IMessageFilter
Private WM_RIGHTCLICK As Integer = &H204
Public Function PreFilterMessage( _
ByRef m As System.Windows.Forms.Message) _
As Boolean _
Implements _
System.Windows.Forms.IMessageFilter.PreFilterMessage
If m.Msg = WM_RIGHTCLICK Then
Dim doc As Document = _
Application.DocumentManager.MdiActiveDocument
Dim ed As Editor = doc.Editor()
ed.WriteMessage(vbCrLf + "Right Button pressed!!")
'Block message for AutoCAD
Return True
End If
Return False
End Function
End Class
End Class

Imports Autodesk.AutoCAD.ApplicationServices 
Imports Autodesk.AutoCAD.DatabaseServices 
Imports Autodesk.AutoCAD.EditorInput 
Imports Autodesk.AutoCAD.Geometry 
Imports Autodesk.AutoCAD.Runtime 
Imports System.Runtime.InteropServices 
 
'//////////////////////////////////////////////////////////////////// 
'// Use: Jig a newly created block reference 
'// Author: Philippe Leefsma, September 2011 
'//////////////////////////////////////////////////////////////////// 
 
Public Class JigMsgFilter 
    Inherits EntityJig 
    Private _position As Point3d 
    Private _filter As JigFilter 
 
    Public Sub New(ByVal btrId As ObjectId) 
        MyBase.New(New BlockReference(Point3d.Origin, btrId)) 
        _position = Point3d.Origin 
        _filter = New JigFilter 
        System.Windows.Forms.Application.AddMessageFilter(_filter) 
    End Sub 
 
    Public Overloads ReadOnly Property Entity() As BlockReference 
        Get 
            Return MyBase.Entity 
        End Get 
    End Property 
 
    Protected Overloads Overrides Function Update() As Boolean 
        Entity.Position = _position 
        Return True 
    End Function 
 
    Protected Overloads Overrides Function Sampler( _ 
        ByVal prompts As JigPrompts) _ 
            As SamplerStatus 
 
        Dim jigOpts As JigPromptPointOptions = _ 
          New JigPromptPointOptions(vbCrLf + "Specify position: ")) 
        jigOpts.UserInputControls = _ 
            UserInputControls.NullResponseAccepted 
 
        Dim res As PromptPointResult = prompts.AcquirePoint( 
            jigOpts) 
        If (res.Status <> PromptStatus.OK) Then 
            Return SamplerStatus.Cancel 
        End If 
        If (_position = res.Value) Then 
            Return SamplerStatus.NoChange 
        End If 
 
        _position = res.Value 
        Return SamplerStatus.OK 
 
    End Function 
 
 
    Public Function Run() As PromptStatus 
        Dim promptResult As PromptResult = _ 
        Application.DocumentManager.MdiActiveDocument.Editor.Drag(Me) 
        Return promptResult.Status 
    End Function 
 
    '//////////////////////////////////////////////////////////// 
    '// Use: Start Jig command 
    '// 
    '//////////////////////////////////////////////////////////// 
 
    Public Shared Sub JigMsgFilter() 
        Dim doc As Document = _ 
            Application.DocumentManager.MdiActiveDocument 
        Dim db As Database = doc.Database 
        Dim ed As Editor = doc.Editor 
        Dim res As PromptResult = _ 
            ed.GetString(vbCrLf + "Enter block name to insert: ") 
        If res.Status <> PromptStatus.OK Then 
            Exit Sub 
        End If 
 
        Using Tx As Transaction = _ 
            db.TransactionManager.StartTransaction() 
            Dim bT As BlockTable = Tx.GetObject( _ 
                db.BlockTableId, _ 
                OpenMode.ForRead) 
 
            If (Not bT.Has(res.StringResult)) Then 
                ed.WriteMessage(vbCrLf + "Block do not exist :(") 
                Exit Sub 
            End If 
 
            Dim btrId As ObjectId = bT(res.StringResult) 
            Dim jig As New JigMsgFilter(btrId) 
            If (jig.Run() <> PromptStatus.OK) Then 
                jig.Entity.Dispose() 
                Exit Sub 
            End If 
            Dim model As BlockTableRecord = Tx.GetObject( _ 
                bT(BlockTableRecord.ModelSpace), _ 
                OpenMode.ForWrite) 
            model.AppendEntity(jig.Entity) 
            Tx.AddNewlyCreatedDBObject(jig.Entity, True) 
            Tx.Commit() 
        End Using 
    End Sub 
 
    '//////////////////////////////////////////////////////////// 
    '// Use: Implementation of message filter 
    '// 
    '//////////////////////////////////////////////////////////// 
 
    Private Class JigFilter 
        Implements System.Windows.Forms.IMessageFilter 
        Private WM_RIGHTCLICK As Integer = &H204 
        Public Function PreFilterMessage( _ 
            ByRef m As System.Windows.Forms.Message) _ 
                As Boolean _ 
            Implements _ 
                System.Windows.Forms.IMessageFilter.PreFilterMessage 
            If m.Msg = WM_RIGHTCLICK Then 
                Dim doc As Document = _ 
                    Application.DocumentManager.MdiActiveDocument 
                Dim ed As Editor = doc.Editor() 
                ed.WriteMessage(vbCrLf + "Right Button pressed!!") 
 
                'Block message for AutoCAD 
 
                Return True 
            End If 
            Return False 
        End Function 
    End Class 
End Class

ScmTools · 发表于 2013-6-2 21:00:54

好久没有用VB了，看着代码有点吃力{:soso_e140:}

账号		自动登录	找回密码
密码			立即注册

[分享] How to combine a .Net Jig and MessageFilter to catch user input

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。