apply、function、lambda、mapcar函数学习

QiaoCheng

apply、function、lambda、mapcar函数搞得头大了，俺收集了一小点

盼望高手们能添加一些以便学习

================================= apply 将参数表传给指定的函数==============================
(apply 'function list)
参数   'function 函数，可以是表示 defun 或 lambda 表达式的符号。
list   表。如果函数不接收参数，则该参数为 nil
返回值 函数调用的结果。
-------------------------------------
示例1
(apply '+ '(1 2 3))
返回:-> 6
-------------------------------------
示例2
(setq lst '((("GC200" . 2)) nil))
(apply '+ (mapcar 'cdr (car lst)))
返回:-> 2
-------------------------------------
示例3
(apply 'strcat '("a" "b" "c"))
返回:->  "abc"
------------------------------------------------------------
示例4
(apply 'append (reverse '((4 5 6) (1 2 3))))
返回:-> (1 2 3 4 5 6)
------------------------------------------------------------
示例5
(setq a '(1 2 3 4 5 6 7 8 9 0))
(apply 'mapcar (cons 'list (list a (cdr a))))
返回:-> ((1 2) (2 3) (3 4) (4 5) (5 6) (6 7) (7 8) (8 9) (9 0))
------------------------------------------------------------
示例6
(setq b '((0 1 2) (3 4 5) (6 7 8)))
(apply 'mapcar (cons 'list b))
返回:-> ((0 3 6) (1 4 7) (2 5 8))
----------------------------------------
示例7
(setq lst '((3 4 5) (0 1 2) (6 7 8)))
(apply 'mapcar (cons 'min lst)) ;或 (apply 'mapcar (cons 'max lst))
返回:-> (0 1 2)
=============== function 通知 Visual LISP 编译器将参数作为内置函数进行链接和优 ===============
(function symbol | lambda-expr)
function 函数与 quote 函数相同,但它将通知 Visual LISP 编译器将参数视为内部函数或用 defun 定义的
          函数,对其进行链接和优化.由 function 引用的经过编译的 lambda 表达式加载到 Visual LISP IDE 时，
          将包含调试信息
参数      symbol 命名函数的符号
          lambda-expr 如下格式的表达式：(lambda arguments {S-expression}* )
返回值    表达式的求值结果。
------------------------------------------------------------------------
示例1
(mapcar (function (lambda (x) (* x x))) '(1 2 3))
返回:-> (1 4 9)
------------------------------------------------------------------------
示例2
(setq lst '((3.33 4.44) (1.11 2.22) (5.55 6.66)))
(vl-sort lst (function (lambda (a b) (< (car a) (car b)))))
返回:-> ((1.11 2.22) (3.33 4.44) (5.55 6.66))
=================================== lambda 定义无名函数====================================
(lambda arguments expr...)
在经常使用某一表达式，而又觉得把它定义成一个新函数开销太大时可使用 lambda 函数。
lambda  将定义的函数放在要使用它的位置，还可以使程序员的意图表达得更清楚。
lambda  函数返回它最后一个 expr 的值。它常与 apply 和（或）mapcar 函数连用，以便对表中的元素执行某个操作。
参数    arguments传给表达式的参数。
expr    AutoLISP 表达式。
返回值  最后一个 expr 的值。
-----------------------------------------------------------------
示例1
(apply '(lambda (x y z) (* x (- y z))) '(5 20 14))
返回:-> 30
-----------------------------------------------------------------
示例2
(setq a 0)
(mapcar '(lambda (x) (setq a (1+ a)) (* x 5)) '(2 4 -6 10.2))
返回:-> (10 20 -30 51.0)
-----------------------------------------------------------------
示例4
(setq m '((1.0 0.0 0.0) (0.0 1.0 0.0) (0.0 0.0 1.0)))
(setq n '((0.5 0.0 0.0) (0.0 0.5 0.0) (0.0 0.0 0.5)))
((lambda (a) (mapcar '(lambda (r) (mxv a r)) m)) (trp n))
返回:-> ((0.25 0.0 0.0) (0.0 0.25 0.0) (0.0 0.0 0.25))
-----------------------------------------------------------------
示例5
(setq x "A" n 3 L '(0 1 2 3 4 5))
((lambda (i) (apply 'append (mapcar '(lambda (a) (if (= n (setq i (1+ i))) (list x a) (list a))) L))) -1)
返回:-> (0 1 2 "A" 3 4 5)
======================================== mapcar ==========================================
将作为本函数参数的一个或多个表的各个元素提供给指定函数进行求值，并将由求值结果构成的表返回
(mapcar function list1... listn)
参数   function
函数。 list1... listn 一个或多个表。表的数目必须与 function 参数中要求的参数个数相等。
返回值 表。
-----------------------------------------------------------------
示例1
(setq a 10 b 20 c 30)
(mapcar '1+ (list a b c))
返回:-> (11 21 31)
-----------------------------------------------------------------
示例2
(setq lst '((1.11 2.22) (3.33 4.44)))
(mapcar '(lambda (x) (cons 10 x)) lst)
返回:-> ((10 1.11 2.22) (10 3.33 4.44))
-----------------------------------------------------------------
示例3
(mapcar '(lambda (x) (+ x 3)) '(10 20 30))
返回:-> (13 23 33)
-----------------------------------------------------------------
示例4
(setq lst '((1.11 2.22) (3.33 4.44) (5.55 6.66)))
(mapcar '(lambda (x) (apply 'mapcar (cons x lst))) '(min max))
返回:-> ((1.11 2.22) (5.55 6.66))
-----------------------------------------------------------------
示例5
(setq ins '(710.623 295.614 88.313))
(setq ent (car (entsel))) ;<图元名: 7ef86d38>
(mapcar '+ (trans ins ent 1) '(1e-4 1e-4))
返回:-> (710.623 295.614)
-----------------------------------------------------------------
示例6
(setq m '((0.5 0.0 0.0) (0.0 0.5 0.0) (0.0 0.0 0.5)))
(setq v '(1.0 0.0 0.0))
(mapcar '(lambda (r) (apply '+ (mapcar '* r v))) m)
返回:-> (0.0 0.5 0.0)
-----------------------------------------------------------------
示例7
(setq lst '((2.22 2.22) (1.11 1.11) (4.44 4.44) (5.55 6.66) (7.77 8.88)))
(setq ins '(3.33 3.33))
(mapcar '(lambda (n) (nth n lst)) (vl-sort-i ins '>))
返回:-> ((1.11 1.11) (2.22 2.22))
-----------------------------------------------------------------
示例8
(setq a '(100 100))
(setq b '(200 200))
(mapcar (function (lambda (a b) (/ (+ a b) 2.0))) a b)
返回:-> (150.0 150.0)

laibinwu

炫翔 发表于 2013-6-3 08:29
将表中的第一个与第二个元素 用CONS组成

示例5
(setq a '(1 2 3 4 5 6 7 8 9 0))
(apply 'mapcar (cons 'list (list a (cdr a))))
返回:-> ((1 2) (2 3) (3 4) (4 5) (5 6) (6 7) (7 8) (8 9) (9 0))

这个详细过程是否可以这样理解：

_$ (setq a '(1 2 3 4 5 6 7 8 9 0))
_$ (list a (cdr a))
((1 2 3 4 5 6 7 8 9 0) (2 3 4 5 6 7 8 9 0))
_$ (cons 'list (list a (cdr a)))
(LIST (1 2 3 4 5 6 7 8 9 0) (2 3 4 5 6 7 8 9 0))
_$ (apply 'mapcar '(LIST (1 2 3 4 5 6 7 8 9 0) (2 3 4 5 6 7 8 9 0)))
((1 2) (2 3) (3 4) (4 5) (5 6) (6 7) (7 8) (8 9) (9 0))

XDSoft

总结的很好，很到位，希望朋友们补充。

炫翔

非常好，
示例不在于多，而在于经典！

pengfei2010

不错 不错 我也正在琢磨这几个函数，非常感谢楼主

xtdwynij

楼主师兄!今天看了你的收藏,自觉开了眼晴长了见识.只是有一个例子看不大懂.不知楼主师兄是否有空为小菜解答一下.例子如下:
(setq a '(1 2 3 4 5 6 7 8 9 0))
(apply 'mapcar (cons 'list (list a (cdr a))))
返回:-> ((1 2) (2 3) (3 4) (4 5) (5 6) (6 7) (7 8) (8 9) (9 0))

xtdwynij

xtdwynij 发表于 2013-5-31 12:19
楼主师兄!今天看了你的收藏,自觉开了眼晴长了见识.只是有一个例子看不大懂.不知楼主师兄是否有空为小菜解答 ...

(setq lst '(1 2 3 4 5 6 7 8 9 0))
(setq cc (mapcar 'list  lst (cdr lst))) 二个返回值是一个样的!

fkyourmather

炫翔 发表于 2013-5-28 18:26
非常好，
示例不在于多，而在于经典！

(setq a '(1 2 3 4 5 6 7 8 9 0))
(apply 'mapcar (cons 'list (list a (cdr a))))
返回:-> ((1 2) (2 3) (3 4) (4 5) (5 6) (6 7) (7 8) (8 9) (9 0))帮忙分析下

eachy

一个实例应用（50积分，10豆限制）
http://bbs.xdcad.net/thread-668580-1-1.html

炫翔

fkyourmather 发表于 2013-6-2 19:00
(setq a '(1 2 3 4 5 6 7 8 9 0))
(apply 'mapcar (cons 'list (list a (cdr a))))
返回:-> ((1 2) (2  ...

将表中的第一个与第二个元素 用CONS组成

newer

laibinwu 发表于 2013-6-9 22:39
示例5
(setq a '(1 2 3 4 5 6 7 8 9 0))
(apply 'mapcar (cons 'list (list a (cdr a))))

好像弄复杂了哎

(mapcar 'list a (cdr a)) 不是和你一样的结果？

lgttblue

新手表示强烈关注

crazylsp

(setq lst '((3 4 5) (0 1 2) (6 7 8)))
(apply 'mapcar (cons 'min lst)) 如何理解?   (cons (mapcar 'min lst)lst)?

st788796

crazylsp 发表于 2013-6-28 11:48
(setq lst '((3 4 5) (0 1 2) (6 7 8)))
(apply 'mapcar (cons 'min lst)) 如何理解?   (cons (mapcar 'mi ...

运行完了看看返回值是什么