wowan1314,讨论下尺寸避让的算法吧。

XDSoft · 发表于 2013-7-7 13:16:21

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

wowowan,你和大家讲讲尺寸避让的算法吧，虽然不是你写的，但是你用的最熟，和大家讲讲需要注意的地方。

wowan1314 · 发表于 2013-7-7 13:37:23

{:soso_e149:}不好意思，您高估我了。我只会用。

对于标注我都没怎么学习过。因为工作中标注用的不多。

算法思路还是大家直接来看YAD的源码或许更好些。

;;尺寸文字避让函数---------BY YAD
(defun yad_dimad1 (SS / yad-dxf yad-perpt yad-chgent ss n m ent en ang w h l_dat l_mov oldang mov s pt pt1 pt2 l_adj en l_en disang disw dish item item1)
(defun yad-dxf(en n)
(if (not (listp en)) (setq en (entget en)))
(cdr (assoc n en))
)
(defun yad-perpt(pt pt1 pt2)
(inters pt1 pt2 pt (polar pt (+ (angle pt1 pt2) (/ pi 2)) 1200) nil)
)
(defun yad-chgent(en n / m val)
(if (not (listp en)) (setq en (entget en)))
(foreach itm n
(setq m (car itm) val (cadr itm))
(if (assoc m en)
(setq en (subst (cons m val) (assoc m en) en))
(setq en (append en (list (cons m val))))
)
)
(entmod en)
)
;(prompt "\n选择需要自动调整文字位置的一组标注尺寸：")
(if SS
(progn
; (vl-cmdf "_undo" "_be")
(vl-cmdf "_.dimedit" "_h" ss "")
(setq n -1 m 0)
(repeat (sslength ss)
(setq ent (ssname ss (setq n (1+ n))))
(setq en (yad-dxf (tblsearch "block" (yad-dxf ent 2)) -2))
(while (/= (yad-dxf (setq en (entnext en)) 0) "MTEXT"))
(setq ang (yad-dxf en 50) h (yad-dxf en 43) w (+ (/ (yad-dxf en 42) 2) (* 0.2 h)) h (* 0.6 h))
(setq l_dat (cons (list ent ang w h) l_dat))
(if (< (/ (yad-dxf ent 42) 2) w)
(if (= (rem (setq m (1+ m)) 2) 0)
(setq l_mov (cons (list ent ang w h) l_mov))
(setq l_mov (append l_mov (list (list ent ang w h))))
)
)
)
(foreach itm l_mov
(setq ent (car itm) ang (cadr itm) w (caddr itm) h (cadddr itm) pt (yad-dxf ent 11) oldang (angle pt (yad-perpt pt (setq pt1 (yad-dxf ent 10)) (polar pt1 ang 1200))) mov T)
(while (and mov (setq s (ssget "_f" (list (setq pt1 (polar (polar pt ang w) (+ ang (/ pi 2)) h)) (setq pt2 (polar pt1 (+ ang pi) (* 2 w))) (setq pt2 (polar pt2 (- ang (/ pi 2)) (* 2 h))) (polar pt2 ang (* 2 w)) pt1)
'((0 . "dimension")(-4 . "<or")(70 . 0)(70 . 1)(70 . 32)(70 . 33)(70 . 128)(70 . 129)(70 . 160)(70 . 161)(-4 . "or>"))
)))
(setq n -1 l_adj nil)
(repeat (sslength s)
(setq en (ssname s (setq n (1+ n))))
(if (and (ssmemb en ss) (not (equal en ent)) (setq l_en (yad-dxf l_dat en)) (equal ang (car l_en) 0.01))
(progn
(setq pt1 (yad-perpt (yad-dxf en 11) pt (polar pt ang 1200))
disang (angle pt1 pt)
disw (- (+ w (cadr l_en)) (distance pt pt1))
dish (- (+ h (caddr l_en)) (distance pt (yad-perpt (yad-dxf en 11) pt (polar pt (+ ang (/ pi 2)) 1200))))
)
(if (and (> dish 0) (not (equal dish 0 1)))
(if (setq item (vl-member-if '(lambda(e) (equal (car e) disang 0.01)) l_adj))
(setq item (car item) l_adj (subst (list disang (max disw (cadr item)) (max dish (caddr item))) item l_adj))
(setq l_adj (cons (list disang disw dish) l_adj))
)
)
)
)
)
(cond
((not l_adj) (setq mov nil))
((and (= (length l_adj) 1) (setq item (car l_adj)) (> (setq disw (cadr item)) 0) (not (equal disw 0 1)) (> (caddr item) 0))
(if (> (yad-dxf ent 70) 128)
(progn
(setq pt1 (yad-perpt pt (setq pt2 (yad-dxf ent 10)) (polar pt2 ang 1200)))
(yad-chgent ent (list (list 11 (setq pt (polar pt (setq disang (angle pt pt1)) (* 2 (+ (distance pt pt1) (if (equal disang oldang 0.01) 0 h)))))) (list 70 (+ 128 (rem (yad-dxf ent 70) 128)))))
)
(progn
(setq mov nil)
(yad-chgent ent (list (list 11 (polar pt (car item) disw)) (list 70 (+ 128 (rem (yad-dxf ent 70) 128)))))
)
)
)
((and (= (length l_adj) 2) (setq item (car l_adj) item1 (cadr l_adj))
(or (and (> (setq disw (cadr item)) 0) (not (equal disw 0 1)) (> (caddr item) 0))
(and (> (setq disw (cadr item1)) 0) (not (equal disw 0 1)) (> (caddr item1) 0))
))
(if (or (> (yad-dxf ent 70) 128) (and (> (caddr item) 0) (> (caddr item1) 0) (> (setq disw (+ (cadr item) (cadr item1))) 0) (not (equal disw 0 1))))
(progn
(setq pt1 (yad-perpt pt (setq pt2 (yad-dxf ent 10)) (polar pt2 ang 1200)))
(if (equal pt pt1 1) (setq disang (- ang (/ pi 2))) (setq disang (angle pt pt1)))
(yad-chgent ent (list (list 11 (setq pt (polar pt disang (* 2 (+ (distance pt pt1) (if (equal disang oldang 0.01) 0 h)))))) (list 70 (+ 128 (rem (yad-dxf ent 70) 128)))))
)
(progn
(setq mov nil)
(if (or (< (caddr item) 0) (and (< (setq disw (cadr item)) 0) (not (equal disw 0 1))))
(setq item item1)
)
(yad-chgent ent (list (list 11 (polar pt (car item) (cadr item))) (list 70 (+ 128 (rem (yad-dxf ent 70) 128)))))
)
)
)
(T (setq mov nil))
)
)
)
;(prompt "\n自动调整完毕！")
; (vl-cmdf "_undo" "_e")
)
)
(princ)
)

;;尺寸文字避让函数---------BY YAD 
(defun yad_dimad1 (SS / yad-dxf yad-perpt yad-chgent ss n m ent en ang w h l_dat l_mov oldang mov s pt pt1 pt2 l_adj en l_en disang disw dish item item1) 
  (defun yad-dxf(en n) 
    (if (not (listp en)) (setq en (entget en))) 
    (cdr (assoc n en)) 
  ) 
  (defun yad-perpt(pt pt1 pt2) 
    (inters pt1 pt2 pt (polar pt (+ (angle pt1 pt2) (/ pi 2)) 1200) nil) 
  ) 
  (defun yad-chgent(en n / m val) 
    (if (not (listp en)) (setq en (entget en))) 
    (foreach itm n 
      (setq m (car itm) val (cadr itm)) 
      (if (assoc m en) 
        (setq en (subst (cons m val) (assoc m en) en)) 
        (setq en (append en (list (cons m val)))) 
      ) 
    ) 
    (entmod en) 
  ) 
  ;(prompt "\n选择需要自动调整文字位置的一组标注尺寸：") 
  (if SS 
    (progn 
     ; (vl-cmdf "_undo" "_be") 
      (vl-cmdf "_.dimedit" "_h" ss "") 
      (setq n -1 m 0) 
      (repeat (sslength ss) 
        (setq ent (ssname ss (setq n (1+ n)))) 
        (setq en (yad-dxf (tblsearch "block" (yad-dxf ent 2)) -2)) 
        (while (/= (yad-dxf (setq en (entnext en)) 0) "MTEXT")) 
        (setq ang (yad-dxf en 50) h (yad-dxf en 43) w (+ (/ (yad-dxf en 42) 2) (* 0.2 h)) h (* 0.6 h)) 
        (setq l_dat (cons (list ent ang w h) l_dat)) 
        (if (< (/ (yad-dxf ent 42) 2) w) 
          (if (= (rem (setq m (1+ m)) 2) 0) 
            (setq l_mov (cons (list ent ang w h) l_mov)) 
            (setq l_mov (append l_mov (list (list ent ang w h)))) 
          ) 
        ) 
      ) 
      (foreach itm l_mov 
        (setq ent (car itm) ang (cadr itm) w (caddr itm) h (cadddr itm) pt (yad-dxf ent 11) oldang (angle pt (yad-perpt pt (setq pt1 (yad-dxf ent 10)) (polar pt1 ang 1200))) mov T) 
        (while (and mov (setq s (ssget "_f" (list (setq pt1 (polar (polar pt ang w) (+ ang (/ pi 2)) h)) (setq pt2 (polar pt1 (+ ang pi) (* 2 w))) (setq pt2 (polar pt2 (- ang (/ pi 2)) (* 2 h))) (polar pt2 ang (* 2 w)) pt1) 
                                           '((0 . "dimension")(-4 . "<or")(70 . 0)(70 . 1)(70 . 32)(70 . 33)(70 . 128)(70 . 129)(70 . 160)(70 . 161)(-4 . "or>")) 
                                ))) 
          (setq n -1 l_adj nil) 
          (repeat (sslength s) 
            (setq en (ssname s (setq n (1+ n)))) 
            (if (and (ssmemb en ss) (not (equal en ent)) (setq l_en (yad-dxf l_dat en)) (equal ang (car l_en) 0.01)) 
              (progn 
                (setq pt1 (yad-perpt (yad-dxf en 11) pt (polar pt ang 1200)) 
                      disang (angle pt1 pt) 
                      disw (- (+ w (cadr l_en)) (distance pt pt1)) 
                      dish (- (+ h (caddr l_en)) (distance pt (yad-perpt (yad-dxf en 11) pt (polar pt (+ ang (/ pi 2)) 1200)))) 
                ) 
                (if (and (> dish 0) (not (equal dish 0 1))) 
                  (if (setq item (vl-member-if '(lambda(e) (equal (car e) disang 0.01)) l_adj)) 
                    (setq item (car item) l_adj (subst (list disang (max disw (cadr item)) (max dish (caddr item))) item l_adj)) 
                    (setq l_adj (cons (list disang disw dish) l_adj)) 
                  ) 
                ) 
              ) 
            ) 
          ) 
          (cond 
            ((not l_adj) (setq mov nil)) 
            ((and (= (length l_adj) 1) (setq item (car l_adj)) (> (setq disw (cadr item)) 0) (not (equal disw 0 1)) (> (caddr item) 0)) 
              (if (> (yad-dxf ent 70) 128) 
                (progn 
                  (setq pt1 (yad-perpt pt (setq pt2 (yad-dxf ent 10)) (polar pt2 ang 1200))) 
                  (yad-chgent ent (list (list 11 (setq pt (polar pt (setq disang (angle pt pt1)) (* 2 (+ (distance pt pt1) (if (equal disang oldang 0.01) 0 h)))))) (list 70 (+ 128 (rem (yad-dxf ent 70) 128))))) 
                ) 
                (progn 
                  (setq mov nil) 
                  (yad-chgent ent (list (list 11 (polar pt (car item) disw)) (list 70 (+ 128 (rem (yad-dxf ent 70) 128))))) 
                ) 
              ) 
            ) 
            ((and (= (length l_adj) 2) (setq item (car l_adj) item1 (cadr l_adj)) 
                  (or (and (> (setq disw (cadr item)) 0) (not (equal disw 0 1)) (> (caddr item) 0)) 
                      (and (> (setq disw (cadr item1)) 0) (not (equal disw 0 1)) (> (caddr item1) 0)) 
                  )) 
              (if (or (> (yad-dxf ent 70) 128) (and (> (caddr item) 0) (> (caddr item1) 0) (> (setq disw (+ (cadr item) (cadr item1))) 0) (not (equal disw 0 1)))) 
                (progn 
                  (setq pt1 (yad-perpt pt (setq pt2 (yad-dxf ent 10)) (polar pt2 ang 1200))) 
                  (if (equal pt pt1 1) (setq disang (- ang (/ pi 2))) (setq disang (angle pt pt1))) 
                  (yad-chgent ent (list (list 11 (setq pt (polar pt disang (* 2 (+ (distance pt pt1) (if (equal disang oldang 0.01) 0 h)))))) (list 70 (+ 128 (rem (yad-dxf ent 70) 128))))) 
                ) 
                (progn 
                  (setq mov nil) 
                  (if (or (< (caddr item) 0) (and (< (setq disw (cadr item)) 0) (not (equal disw 0 1)))) 
                    (setq item item1) 
                  ) 
                  (yad-chgent ent (list (list 11 (polar pt (car item) (cadr item))) (list 70 (+ 128 (rem (yad-dxf ent 70) 128))))) 
                ) 
              ) 
            ) 
            (T (setq mov nil)) 
          ) 
        ) 
      ) 
      ;(prompt "\n自动调整完毕！") 
     ; (vl-cmdf "_undo" "_e") 
    ) 
  ) 
  (princ) 
)

GTJ116600 · 发表于 2013-7-7 16:59:05

wowan1314 发表于 2013-7-7 13:37
不好意思，您高估我了。我只会用。

对于标注我都没怎么学习过。因为工作中标注用的不 ...

这个工作中确实非常有用，支持老大。{:soso_e113:}

/db_自贡黄明儒_ · 发表于 2013-7-7 19:56:57

本帖最后由 /db_自贡黄明儒_ 于 2013-7-7 20:02 编辑

好像这个避让不怎么管用。
我有一个想法,就是把刚标注的尺寸炸开，然后得到MText(or)text的包围框，搜索包围框内有没有尺寸。

newer · 发表于 2013-7-7 20:52:57

/db_自贡黄明儒_ 发表于 2013-7-7 19:56
好像这个避让不怎么管用。
我有一个想法,就是把刚标注的尺寸炸开，然后得到MText(or)text的包围框，搜索包 ...

如果找到重合的了，你的算法想怎么移动文字呢，什么时候上，什么时候下，什么时候左，什么时候右？

ayl1004 · 发表于 2013-7-7 21:15:14

感觉标注还是不要搞程序了，简单的图形倒可以用程序，复杂点的，非手工不可。

/db_自贡黄明儒_ · 发表于 2013-7-7 21:18:34

newer 发表于 2013-7-7 20:52
如果找到重合的了，你的算法想怎么移动文字呢，什么时候上，什么时候下，什么时候左，什么时候右？

既然炸开了，那么就可以获取mtext下面的那条线，根据mtext与线的关系，决定尺寸怎么移动

wowan1314 · 发表于 2013-7-7 21:53:15

/db_自贡黄明儒_ 发表于 2013-7-7 21:18
既然炸开了，那么就可以获取mtext下面的那条线，根据mtext与线的关系，决定尺寸怎么移动

怎么会不管用呢？不知道你的标注是什么样子的。对于对齐标注。这个函数是表现很好的。

另外对于标注里的文字不需要砸开就可以找到。对标注不感兴趣，所以我也没仔细的学习这个函数。

gdslqs · 发表于 2013-7-8 09:17:33

我用过yad的尺寸避让，还是觉得tssd的尺寸避让好用，高手们研究下tssd的吧

newer · 发表于 2013-7-8 10:03:54

gdslqs 发表于 2013-7-8 09:17
我用过yad的尺寸避让，还是觉得tssd的尺寸避让好用，高手们研究下tssd的吧

TSSD的尺寸避让哪里好，和大家说说啊。

gdslqs · 发表于 2013-7-8 11:17:32

newer 发表于 2013-7-8 10:03
TSSD的尺寸避让哪里好，和大家说说啊。

就是感觉避让合理一些，比如避让开了不重叠，又不是拉得很远，刚合适

newer · 发表于 2013-7-8 12:19:40

gdslqs 发表于 2013-7-8 11:17
就是感觉避让合理一些，比如避让开了不重叠，又不是拉得很远，刚合适

可否截取个图片贴论坛来？或者做个动画的演示，看看。

zhangq_cai1 · 发表于 2013-7-11 08:26:18

发一个tssd的源码看看~~~~~~~~~~~~~~~~~~~~~~~~~~~~~·

hnfsf · 发表于 2014-5-7 23:36:45

所有标注尺寸文字避让里面，tssd最好用，可以框选一大片，都能很好避让

账号		自动登录	找回密码
密码			立即注册

[研讨] wowan1314,讨论下尺寸避让的算法吧。

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

点评

评分

点评

点评

点评

点评

点评

点评

点评