哪位大大来解释下这个函数为什么是这样的写法？

wowan1314

1. (defun LM:acdoc nil
   
2.   (eval (list 'defun
   
3.        'LM:acdoc
   
4.        'nil
   
5.        (vla-get-activedocument (vlax-get-acad-object))
   
6. )
   
7.   )
   
8.   (LM:acdoc)
   
9. )

(defun LM:acdoc nil<br />   (eval (list 'defun<br />        'LM:acdoc<br />        'nil<br />        (vla-get-activedocument (vlax-get-acad-object))<br /> )<br />   )<br />   (LM:acdoc)<br /> )

这样写的好处是：第一次调用时，函数会执行(vla-get-activedocument (vlax-get-acad-object))这句代码。


但是以后再执行这个函数，就不会再执行(vla-get-activedocument (vlax-get-acad-object))这个代码.而直接返回 其代表的值。相当于设置一个全局变量一样。

不知道为什么会这么神奇？  这个代码是怎么运行的？ 下次调用怎么会直接返回值而不再去执行相应的代码？

wowan1314

我谈下我的理解，因为我想的比较简单。也许不正确。
1、这个函数第一次运行后，以后再运行就是执行 EVAL 里面重新定义的函数了
    这一点大家都知道了。
2、那么关键就是EVAL里的重新定义。这个list  里面共四个元素。前三个有'号。最后一个没有。
    所以最后一句在第一次执行时候是被运行了的。

重新定义后的函数其实是这样的！

2. (defun LM:acdoc nil
   
3.    #<VLA-OBJECT IAcadDocument 0114d320>
   
4. )

(defun LM:acdoc nil<br />    #<VLA-OBJECT IAcadDocument 0114d320><br /> )

里面已经没有代码了。只有值了。

wowan1314

2. ;; Multiple Nested Copy  -  Lee Mac
   
3. ;; Copies all components of a selected block reference to the active space.
   
4. 
   
5. (defun c:ncopym ( / ent lst mat obj )
   
6.     (while
   
7.         (progn (setvar 'errno 0) (setq ent (car (entsel "\nSelect Block Reference: ")))
   
8.             (cond
   
9.                 (   (= 7 (getvar 'errno))
   
10.                     (princ "\nMissed, try again.")
    
11.                 )
    
12.                 (   (= 'ename (type ent))
    
13.                     (setq obj (vlax-ename->vla-object ent))
    
14.                     (cond
    
15.                         (   (/= "AcDbBlockReference" (vla-get-objectname obj))
    
16.                             (princ "\nSelected object is not a block reference.")
    
17.                         )
    
18.                         (   (= :vlax-true (vla-get-hasattributes obj))
    
19.                             (princ "\nSelected block must not be attributed.")
    
20.                         )
    
21.                         (   (= :vlax-true (vla-get-isdynamicblock obj))
    
22.                             (princ "\nSelected block must not be dynamic.")
    
23.                         )
    
24.                         (   (not
    
25.                                 (and
    
26.                                     (equal (vla-get-xscalefactor obj) (vla-get-yscalefactor obj) 1e-8)
    
27.                                     (equal (vla-get-xscalefactor obj) (vla-get-zscalefactor obj) 1e-8)
    
28.                                 )
    
29.                             )
    
30.                             (princ "\nSelected block must be uniformly scaled.")
    
31.                         )                                    
    
32.                         (   t
    
33.                             (setq mat
    
34.                                 (vlax-tmatrix
    
35.                                     (apply
    
36.                                         (function
    
37.                                             (lambda ( mat vec )
    
38.                                                 (append (mapcar 'append mat (mapcar 'list vec))
    
39.                                                    '((0.0 0.0 0.0 1.0))
    
40.                                                 )
    
41.                                             )
    
42.                                         )
    
43.                                         (refgeom ent)
    
44.                                     )
    
45.                                 )
    
46.                             )
    
47.                             (vlax-for obj (vla-item (vla-get-blocks (LM:acdoc)) (vla-get-name obj))
    
48.                                 (setq lst (cons obj lst))
    
49.                             )
    
50.                             (foreach obj
    
51.                                 (vlax-invoke (LM:acdoc) 'copyobjects (reverse lst)
    
52.                                     (vlax-ename->vla-object (cdr (assoc 330 (entget ent))))
    
53.                                 )
    
54.                                 (vla-transformby obj mat)
    
55.                             )
    
56.                         )
    
57.                     )
    
58.                 )
    
59.             )
    
60.         )
    
61.     )
    
62.     (princ)
    
63. )
    
64. 
    
65. ;; RefGeom (gile)
    
66. ;; Returns a list whose first item is a 3x3 transformation matrix and
    
67. ;; second item the object insertion point in its parent (xref, block or space)
    
68. 
    
69. (defun refgeom ( ent / ang enx mat ocs )
    
70.     (setq enx (entget ent)
    
71.           ang (cdr (assoc 050 enx))
    
72.           ocs (cdr (assoc 210 enx))
    
73.     )
    
74.     (list
    
75.         (setq mat
    
76.             (mxm
    
77.                 (mapcar '(lambda ( v ) (trans v 0 ocs t))
    
78.                    '(
    
79.                         (1.0 0.0 0.0)
    
80.                         (0.0 1.0 0.0)
    
81.                         (0.0 0.0 1.0)
    
82.                     )
    
83.                 )
    
84.                 (mxm
    
85.                     (list
    
86.                         (list (cos ang) (- (sin ang)) 0.0)
    
87.                         (list (sin ang) (cos ang)     0.0)
    
88.                        '(0.0 0.0 1.0)
    
89.                     )
    
90.                     (list
    
91.                         (list (cdr (assoc 41 enx)) 0.0 0.0)
    
92.                         (list 0.0 (cdr (assoc 42 enx)) 0.0)
    
93.                         (list 0.0 0.0 (cdr (assoc 43 enx)))
    
94.                     )
    
95.                 )
    
96.             )
    
97.         )
    
98.         (mapcar '- (trans (cdr (assoc 10 enx)) ocs 0)
    
99.             (mxv mat (cdr (assoc 10 (tblsearch "block" (cdr (assoc 2 enx))))))
    
100.         )
     
101.     )
     
102. )
     
103. 
     
104. ;; Matrix Transpose  -  Doug Wilson
     
105. ;; Args: m - nxn matrix
     
106. 
     
107. (defun trp ( m )
     
108.     (apply 'mapcar (cons 'list m))
     
109. )
     
110. 
     
111. ;; Matrix x Matrix  -  Vladimir Nesterovsky
     
112. ;; Args: m,n - nxn matrices
     
113. 
     
114. (defun mxm ( m n )
     
115.     ((lambda ( a ) (mapcar '(lambda ( r ) (mxv a r)) m)) (trp n))
     
116. )
     
117. 
     
118. ;; Matrix x Vector  -  Vladimir Nesterovsky
     
119. ;; Args: m - nxn matrix, v - vector in R^n
     
120. 
     
121. (defun mxv ( m v )
     
122.     (mapcar '(lambda ( r ) (apply '+ (mapcar '* r v))) m)
     
123. )
     
124. 
     
125. ;; Active Document  -  Lee Mac
     
126. ;; Returns the VLA Active Document Object
     
127. 
     
128. (defun LM:acdoc nil
     
129.     (eval (list 'defun 'LM:acdoc 'nil (vla-get-activedocument (vlax-get-acad-object))))
     
130.     (LM:acdoc)
     
131. )
     
132. 
     
133. (vl-load-com) (princ)

;; Multiple Nested Copy  -  Lee Mac<br /> ;; Copies all components of a selected block reference to the active space.<br /> <br /> (defun c:ncopym ( / ent lst mat obj )<br />     (while<br />         (progn (setvar 'errno 0) (setq ent (car (entsel "\nSelect Block Reference: ")))<br />             (cond<br />                 (   (= 7 (getvar 'errno))<br />                     (princ "\nMissed, try again.")<br />                 )<br />                 (   (= 'ename (type ent))<br />                     (setq obj (vlax-ename->vla-object ent))<br />                     (cond<br />                         (   (/= "AcDbBlockReference" (vla-get-objectname obj))<br />                             (princ "\nSelected object is not a block reference.")<br />                         )<br />                         (   (= :vlax-true (vla-get-hasattributes obj))<br />                             (princ "\nSelected block must not be attributed.")<br />                         )<br />                         (   (= :vlax-true (vla-get-isdynamicblock obj))<br />                             (princ "\nSelected block must not be dynamic.")<br />                         )<br />                         (   (not<br />                                 (and<br />                                     (equal (vla-get-xscalefactor obj) (vla-get-yscalefactor obj) 1e-8)<br />                                     (equal (vla-get-xscalefactor obj) (vla-get-zscalefactor obj) 1e-8)<br />                                 )<br />                             )<br />                             (princ "\nSelected block must be uniformly scaled.")<br />                         )                                    <br />                         (   t<br />                             (setq mat<br />                                 (vlax-tmatrix<br />                                     (apply<br />                                         (function<br />                                             (lambda ( mat vec )<br />                                                 (append (mapcar 'append mat (mapcar 'list vec))<br />                                                    '((0.0 0.0 0.0 1.0))<br />                                                 )<br />                                             )<br />                                         )<br />                                         (refgeom ent)<br />                                     )<br />                                 )<br />                             )<br />                             (vlax-for obj (vla-item (vla-get-blocks (LM:acdoc)) (vla-get-name obj))<br />                                 (setq lst (cons obj lst))<br />                             )<br />                             (foreach obj<br />                                 (vlax-invoke (LM:acdoc) 'copyobjects (reverse lst)<br />                                     (vlax-ename->vla-object (cdr (assoc 330 (entget ent))))<br />                                 )<br />                                 (vla-transformby obj mat)<br />                             )<br />                         )<br />                     )<br />                 )<br />             )<br />         )<br />     )<br />     (princ)<br /> )<br /> <br /> ;; RefGeom (gile)<br /> ;; Returns a list whose first item is a 3x3 transformation matrix and<br /> ;; second item the object insertion point in its parent (xref, block or space)<br /> <br /> (defun refgeom ( ent / ang enx mat ocs )<br />     (setq enx (entget ent)<br />           ang (cdr (assoc 050 enx))<br />           ocs (cdr (assoc 210 enx))<br />     )<br />     (list<br />         (setq mat<br />             (mxm<br />                 (mapcar '(lambda ( v ) (trans v 0 ocs t))<br />                    '(<br />                         (1.0 0.0 0.0)<br />                         (0.0 1.0 0.0)<br />                         (0.0 0.0 1.0)<br />                     )<br />                 )<br />                 (mxm<br />                     (list<br />                         (list (cos ang) (- (sin ang)) 0.0)<br />                         (list (sin ang) (cos ang)     0.0)<br />                        '(0.0 0.0 1.0)<br />                     )<br />                     (list<br />                         (list (cdr (assoc 41 enx)) 0.0 0.0)<br />                         (list 0.0 (cdr (assoc 42 enx)) 0.0)<br />                         (list 0.0 0.0 (cdr (assoc 43 enx)))<br />                     )<br />                 )<br />             )<br />         )<br />         (mapcar '- (trans (cdr (assoc 10 enx)) ocs 0)<br />             (mxv mat (cdr (assoc 10 (tblsearch "block" (cdr (assoc 2 enx))))))<br />         )<br />     )<br /> )<br /> <br /> ;; Matrix Transpose  -  Doug Wilson<br /> ;; Args: m - nxn matrix<br /> <br /> (defun trp ( m )<br />     (apply 'mapcar (cons 'list m))<br /> )<br /> <br /> ;; Matrix x Matrix  -  Vladimir Nesterovsky<br /> ;; Args: m,n - nxn matrices<br /> <br /> (defun mxm ( m n )<br />     ((lambda ( a ) (mapcar '(lambda ( r ) (mxv a r)) m)) (trp n))<br /> )<br /> <br /> ;; Matrix x Vector  -  Vladimir Nesterovsky<br /> ;; Args: m - nxn matrix, v - vector in R^n<br /> <br /> (defun mxv ( m v )<br />     (mapcar '(lambda ( r ) (apply '+ (mapcar '* r v))) m)<br /> )<br /> <br /> ;; Active Document  -  Lee Mac<br /> ;; Returns the VLA Active Document Object<br /> <br /> (defun LM:acdoc nil<br />     (eval (list 'defun 'LM:acdoc 'nil (vla-get-activedocument (vlax-get-acad-object))))<br />     (LM:acdoc)<br /> )<br /> <br /> (vl-load-com) (princ)

wowan1314

汉字是多么亲切的一种语言啊。。 怎么那么地方用英语？！


The use of defun-q will help to explain the difference:

Consider the following functions:

2. (defun-q f1 nil
   
3.     (vla-get-activedocument (vlax-get-acad-object))
   
4. )

(defun-q f1 nil<br />     (vla-get-activedocument (vlax-get-acad-object))<br /> )

2. (defun-q f2 nil
   
3.     (eval (list 'defun-q 'f2 'nil (vla-get-activedocument (vlax-get-acad-object))))
   
4.     (f2)
   
5. )

(defun-q f2 nil<br />     (eval (list 'defun-q 'f2 'nil (vla-get-activedocument (vlax-get-acad-object))))<br />     (f2)<br /> )

Before function evaluation, the respective function definitions are as follows:

1. _$ f1
   
2. (nil (vla-get-ActiveDocument (vlax-get-acad-object)))
   
3. _$ f2
   
4. (nil (EVAL (LIST (QUOTE DEFUN-Q) (QUOTE F2) (QUOTE nil) (vla-get-ActiveDocument (vlax-get-acad-object)))) (F2))

复制代码

When evaluated, both functions will return the Active Document object:

1. _$ (f1)
   
2. #<VLA-OBJECT IAcadDocument 0ceb5b6c>
   
3. _$ (f2)
   
4. #<VLA-OBJECT IAcadDocument 0ceb5b6c>

复制代码

However, observe the respective function definitions following function evaluation:

1. _$ f1
   
2. (nil (vla-get-ActiveDocument (vlax-get-acad-object)))
   
3. _$ f2
   
4. (nil #<VLA-OBJECT IAcadDocument 0ceb5b6c>)

复制代码

Note that function f2 now no longer retrieves the Application Object (vlax-get-acad-object) before retrieving the Active Document Property (vla-get-activedocument), but simply returns the Active Document object directly. The method is similar to setting a global variable pointing to the Active Document Object.

Of course, for this program, I could have equivalently used a local variable assigned with the Active Document Object, however, such local variable would then be re-assigned this value for every use of the program.
&#171; Last Edit: June 04, 2013, 07:53:20 am by Lee Mac &#187;

newer

一楼的帖子，对里面的符号用EVAL求值，就把函数DEFUN了。

wowan1314

newer 发表于 2013-8-2 08:05
一楼的帖子，对里面的符号用EVAL求值，就把函数DEFUN了。

我是问这个函数为什么这样写？？  
这样写有什么好处？
为什么会有这种好处？

newer

wowan1314 发表于 2013-8-2 10:29
我是问这个函数为什么这样写？？  
这样写有什么好处？
为什么会有这种好处？

你这么说，我才又看了次程序，外面定义的名字 和里面 EVAL定义的一样，我看到他在函数里面又递归调用了自己。我们知道LISP求值是从最内部的括号求完再到外面的括号，看作者的代码，是想在里面执行函数的时候要保证这个函数安全的定义了（通过上面的EVAL，注意EVAL里面的同名函数并没递归调用的语句，作者是想通过这样的写法，在函数第一个执行的时候不递归调用，第二次后才开始递归）。

我不知道我上面说的是不是作者的想法，毕竟他选择这样写的，我也不知道我上面说的，你是不是能明白我要表达的意思。

ayl1004

newer 发表于 2013-8-2 10:48
你这么说，我才又看了次程序，外面定义的名字 和里面 EVAL定义的一样，我看到他在函数里面又递归调用了自 ...

这没有用递归吧，应该不算递归，里面的定义覆盖了原函数。有什么好处就不清楚了。

wowan1314

ayl1004 发表于 2013-8-2 11:11
这没有用递归吧，应该不算递归，里面的定义覆盖了原函数。有什么好处就不清楚了。

好处是：第一次调用时，函数会执行(vla-get-activedocument (vlax-get-acad-object))这句代码。


但是以后再执行这个函数，就不会再执行(vla-get-activedocument (vlax-get-acad-object))这个代码.而直接返回 其代表的值。相当于设置一个全局变量一样。


不知道为什么会这么神奇？  这个代码是怎么运行的？ 下次调用怎么会直接返回值而不再去执行相应的代码？

st788796

道可道，非常道

/db_自贡黄明儒_

确实很奇怪,搞不明白，帮你顶一下{:soso_e181:}。

newer

wowan1314 发表于 2013-8-2 11:17
好处是：第一次调用时，函数会执行(vla-get-activedocument (vlax-get-acad-object))这句代码。

葛老，你弄明白了吗？

st788796

nil <=> ()
这个 nil 有时让人迷惑

MoremoreGold

Lisp里面"符号"既可以储存变量也可以储存函数
也可以说不仅defun用来定义函数，setq 也可以
这个程序第一次执行完eval函数后再执行(f2)等于是(setq f2 (vla...))
好处就是,这是一个coding理念:尽量减少全局变量的使用。coders相信在五千行以上规模的程序中，全局变量绝对是灾难之源。
我相信能参与到这种代码规模的人一定不少，但是更多人写的程序不会超过200行。

newer

MoremoreGold 发表于 2013-8-15 20:03
Lisp里面"符号"既可以储存变量也可以储存函数
也可以说不仅defun用来定义函数，setq 也可以
这个程序第一 ...

能举一些全局变量时灾难之源的例子吗？

MoremoreGold

我不是coders，我写的小东西100行都嫌多
减少全局变量的使用是程序员的理念