字符串分割--------------集中营

/db_自贡黄明儒_

;;85.1 [功能] 字符串分割
;;http://www.mjtd.com/function/info-129-216.html,有修改 黄明儒 2013年8月9日
;;(setq str   "100,,23456.876,345.456," delim ",")
(defun parse1 (str delim / LST POS)
  (while (setq pos (vl-string-search delim str))
    (setq lst (cons (substr str 1 pos) lst)
          str (substr str (+ pos 2))
    )
  )
  (if (> (strlen str) 0)
    (setq lst (cons str lst))
  )
  (reverse lst)
)
;;85.2 [功能] 字符串分割
;;http://www.mjtd.com/function/info-129-444.html，修改xl:read->biao  黄明儒 2013年8月9日
(defun parse2 (str delim / LST POS)
  (while (setq pos (vl-string-search delim str))
    (setq lst (append lst (list (substr str 1 pos))))
    (setq str (substr str (+ 2 pos)))
  )
  (if (> (strlen str) 0)
    (append lst (list str))
    lst
  )
)

游客，如果您要查看本帖隐藏内容请回复

;;85.4 [功能] 字符串分割
;;这是一个很牛的分割法(基本同parse8)，容易理解
;;delim是一个字符串集合，其中的每一个字符都会被当作是分割符号 by qjchen@gmail.com
;;如 (parse4 "符号25 35 45 ; 55, 66 " " ;")=> ("25" "35" "45" "55," "66")
;;(parse4 "aa ,10 b.10x20,.2" ",.")("aa " "10 b" "10x20" "2")
(defun parse4 (str delim / L1 L2)
  (setq        str   (vl-string->list str)
        delim (vl-string->list delim)
  )
  (while str
    (if        (not (member (car str) delim))
      (setq l1 (cons (car str) l1))
      (if l1
        (setq l2 (cons (vl-list->string (reverse l1)) l2)
              l1 nil
        )
      )
    )
    (setq str (cdr str))
  )
  (if l1
    (setq l2 (cons (vl-list->string (reverse l1)) l2))
  )
  (reverse l2)
)
;;85.5 [功能] 字符串分割(这highflybird回答我的求助,简洁)
;;(parse5 "aa 10 b10x20.2" "")返回("AA" "10" "B10X20")
;;(parse5 "aa 10 b10x20.2" ".")返回("AA" "10" "B10X20" "2")
(defun parse5 (String Delimiter / str lst)
  ;;替换成空格，为后面转化作准备，问题是如果字符中原来就有空格
  (setq str (VL-STRING-TRANSLATE Delimiter " " String))
  (setq str (strcat "(" str ")"))                  ;加括号
  (setq lst (read str))                                  ;读
  (mapcar 'VL-PRINC-TO-STRING lst)                  ;转化
)
;;85.6 [功能] 用分隔符解释字符串成表 ;by fsxm
;;空格" "，不能用"" ，一个空格就转成一个字符
;;(parse6 "aa   10 b10x20.2" " ")返回("aa" "" "" "10" "b10x20.2")
;;(parse6 "aa   10 b10x20.2" "")死循环
(defun parse6 (string strkey / PO STRLST XLEN)
  (setq xlen (1+ (strlen strkey)))
  (while (setq po (vl-string-search strkey string))
    (setq strlst (cons (substr string 1 po) strlst))
    (setq string (substr string (+ po xlen)))
  )
  (reverse (cons string strlst))
)
;;85.7 [功能] 字符串分割 黄明儒 2013年8月9日
;;改自梁雄啸str2lst1;同parse5,也parse6一样，空格不能有""替代
;;(parse7 "aa   10 b10x20.2" " ");("aa" "" "" "10" "b10x20.2")
;;(parse7 "aa   10 b10x20.2" "")死循环
;;(parse7 "aa 10 b10x20.2" " ")("aa" "10" "b10x20.2")与parse5不同，不会去掉.2
;;(parse7 "aa 10 b10x20.2" "x")("aa 10 b10" "20.2")
(defun parse7 (str delim / I)
  (while (setq i (vl-string-search
                   delim
                   str
                   (if i
                     (+ 2 i)
                     0
                   )
                 )
         )
    (setq str (vl-string-subst "\"\"" delim str i))
  )
  (read (strcat "(\"" str "\")"))
)
;;85.8 [功能] 字符串分割(基本同parse4)
;;改自梁雄啸str2lst2 黄明儒 2013年8月9日
;;(parse8 "aa ,10 b.10x20,.2" ",.")("aa " "10 b" "10x20" "" "2")
;;(vl-list->string '(40));"("
;;(vl-list->string '(34)),"\""
;;(vl-list->string '(32))," "
(defun parse8 (str delim / DELIM X)
  (setq delim (vl-string->list delim))
  (read
    (vl-list->string
      (apply
        'append
        (mapcar        '(lambda (x)
                   (if (member x delim)
                     (list 34 32 34)                  
                     (list x)
                   )
                 )
                (append (list 40 34) (vl-string->list str) (list 34 41))
        )
      )
    )
  )
)
;;85.9  [功能] 字符串分割 (纯lisp法)
;;改自梁雄啸str2lst3 黄明儒 2013年8月9日
;;(parse9 "aa   10 b10x20.2" " ");("aa" "" "" "10" "b10x20.2")
;;(parse9 "aa   10 b10x20.2" ""),没作用，但不进入死循环
(defun parse9 (str delim / I S STR1 STRLST)
  (setq        i 0
        str1 ""
  )
  (while (/= "" (setq s (substr str (setq i (1+ i)) 1)))
    (cond ((/= delim s) (setq str1 (strcat str1 s)))
          (T
           (setq strlst        (append strlst (list str1))
                 str1        ""
           )
          )
    )
  )
  (if (/= str1 "")
    (append strlst (list str1))
    strlst
  )
)
;;85.10 [功能] 字符串分割(纯lisp法)
;;改自梁雄啸str2lst 黄明儒 2013年8月9日
;;(parse10 "aa   10 b10x20.2" " ");("aa" "" "" "10" "b10x20.2")
;;(parse10 "aa   10 b10x20.2" ""),没作用，但不进入死循环
(defun parse10 (str delim / I S STR1)
  (setq        i 0
        str1 ""
  )
  (while (/= "" (setq s (substr str (setq i (1+ i)) 1)))
    (setq str1 (strcat str1
                       (if (= delim s)
                         "\" \""
                         s
                       )
               )
    )
  )
  (read (strcat "(\"" str1 "\")"))
)
;;85.11 [功能] 字符串分割 By wowan1314
;;(parse11 "aa   10 b10x20.2" " ");("aa" "" "" "10" "b10x20.2")
;;(parse11 "aa   10 b10x20.2" ""),死循环
(defun parse11 (str del / LST POS)
  (while
    (setq pos (vl-string-search del str))
     (setq lst (cons (substr str 1 pos) lst)
    str (substr str
         (+ 1 pos (strlen del))
        )
     )
  )
  (reverse (cons str lst))
)

rq28

有个实例就好了
这么多的如何是好啊

newer

楼主，试试，这些应该都可以用正则表达式改写下。

st788796

一直用这个,可以是多字组成的分隔符

1. (defun str-parse (str delimiter / post strlst strl)
   
2.   (if str
   
3.     (progn
   
4.       (setq strlst '()
   
5.      strl   (strlen delimiter)
   
6.       )
   
7.       (while (vl-string-search delimiter str)
   
8. (setq post (vl-string-search delimiter str))
   
9. (setq strlst (append strlst (list (substr str 1 post))))
   
10. (setq str (substr str (+ post (1+ strl))))
    
11.       )
    
12.       (vl-remove "" (append strlst (list str)))
    
13.     )
    
14.   )
    
15. )

(defun str-parse (str delimiter / post strlst strl)<br />   (if str<br />     (progn<br />       (setq strlst '()<br />      strl   (strlen delimiter)<br />       )<br />       (while (vl-string-search delimiter str)<br /> (setq post (vl-string-search delimiter str))<br /> (setq strlst (append strlst (list (substr str 1 post))))<br /> (setq str (substr str (+ post (1+ strl))))<br />       )<br />       (vl-remove "" (append strlst (list str)))<br />     )<br />   )<br /> )

_$ (str-parse "123sdsdsa123sdsdsa123" "sdsdsa")
("123" "123" "123")
_$ (str-parse "123好1的123好1的123" "好1的")
("123" "123" "123")
_$

st788796

奇怪!
_$ (str-parse "aa ,10 b.10x20,.2" "")
_1_$ (vl-string-search delimiter str)
0
_1_$ (vl-string-search "aa ,10 b.10x20,.2" "")
nil
_1_$

/db_自贡黄明儒_

st788796 发表于 2013-8-12 12:23
奇怪!
_$ (str-parse "aa ,10 b.10x20,.2" "")
_1_$ (vl-string-search delimiter str)

我又试(str-parse "aa ,10 b.10x20,.2" "")了，还是死循环

819534890

为了学习好东西，努力回复

st788796

连拼带凑了一个VBS

1. (defun str-split (string str / vbs ret)
   
2.   (if (or
   
3.         **ScriptControl**
   
4.         (setq **ScriptControl** (vlax-create-object "ScriptControl"))
   
5.       )
   
6.     (progn
   
7.       (vlax-put **ScriptControl** "Language" "VBS")
   
8.       (setq vbs
   
9.              (strcat "Dim ret\n"        "s = \""
   
10.                      string                "\"\nsn = \""
    
11.                      str                "\"\nret = Split(s,sn)"
    
12.                     )
    
13.       )
    
14.       (vlax-invoke **ScriptControl** 'ExecuteStatement vbs)
    
15.       (setq ret (vlax-invoke **ScriptControl** 'eval "ret"))
    
16.     )
    
17.   )
    
18.   ret
    
19. )

(defun str-split (string str / vbs ret)<br />   (if (or<br />         **ScriptControl**<br />         (setq **ScriptControl** (vlax-create-object "ScriptControl"))<br />       )<br />     (progn<br />       (vlax-put **ScriptControl** "Language" "VBS")<br />       (setq vbs<br />              (strcat "Dim ret\n"        "s = \""<br />                      string                "\"\nsn = \""<br />                      str                "\"\nret = Split(s,sn)"<br />                     )<br />       )<br />       (vlax-invoke **ScriptControl** 'ExecuteStatement vbs)<br />       (setq ret (vlax-invoke **ScriptControl** 'eval "ret"))<br />     )<br />   )<br />   ret<br /> )

jyzas

不错，下来试试怎样，支持:)

q3_2006

这个要学，还不太明白！

HLCAD

黄大侠又出力作了，支持黄大侠！

/db_自贡黄明儒_

st788796 发表于 2013-8-12 16:35
连拼带凑了一个VBS

你这个怎么用，举几个应该示例吧

st788796

/db_自贡黄明儒_ 发表于 29&nbsp;分钟前

                               
登录/注册后可看大图

你这个怎么用，举几个应该示例吧

和上面的函数一样用法来自: Android客户端

/db_自贡黄明儒_

st788796 发表于 2013-8-13 08:42
和上面的函数一样用法

有介绍ScriptControl用法的资料吗？能否提供

newer

/db_自贡黄明儒_ 发表于 2013-8-13 11:11
有介绍ScriptControl用法的资料吗？能否提供

下载地址：晓东文库