练习:此图的参数化

炫翔 · 发表于 2013-8-15 16:54:28

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

本帖最后由炫翔于 2013-8-15 16:56 编辑

32Q}MLOXFN61NTIH(SSQ8}6.jpg

根据上图的提供的尺寸，做成参数，自动生成图形

也就是说:假如:输入100，与左下角点，就可直接生成上面的图形

以防假冒，主要以说明思路为准！

CAD的做法地址:http://www.xdcad.net/forum/thread-670130-1-1.html

newer · 发表于 2013-8-15 17:28:32

本帖最后由 newer 于 2013-8-15 17:39 编辑

用XDRX API写个，一路都是矩阵。

(defun c:tt()
(if (and (setq dis (getreal "\n长度<退出>:"))
(setq pt (getpoint "\n基点<退出>:"))
)
(progn
(setq p1 (mapcar '+ pt '(30 30 0)) ;;p1 p2 p3左边三个圆心，半径任意，这里是30
p2 (mapcar '+ p1 '(0 60 0))
p3 (polar p1 (/ pi 6.0) 60)
p4 (mapcar '+ p3 '(0 100 0))
mat0(xdrx_matrix_identity 3)
mat (xdrx_matrix_setmirror mat0 (list p3 p4)) ;;中间圆心竖直线P3 P4做镜像线构建镜像矩阵
)
(xdrx_setmark)
(setq e1 (xdrx_circle_make p1 30) ;;绘制左边和中间的3个园
e2 (xdrx_circle_make p2 30)
e3 (xdrx_circle_make p3 30)
)
(xdrx_entity_transformedcopy e1 mat) ;;镜像左边两个圆，得到右边两个圆
(xdrx_entity_transformedcopy e2 mat)
(setq ss (xdrx_getss)
box (xdrx_entity_box ss) ;;所有圆的包围盒
len (distance (car box)(cadr box)) ;;底边的长度和输入的距离比值得到缩放系数
scl (/ dis len)
mat (xdrx_matrix_setscale mat0 scl pt) ;;以基点PT构建缩放矩阵
)
(xdrx_entity_transform ss mat) ;;缩放所有圆
(setq box (xdrx_entity_box ss));;最终结果圆的包围盒
(apply 'xdrx_polyline_make (cons t box));;绘制封闭外框
(xdrx_dimension_MakeAlign (car box)(cadr box) (mapcar '- pt '(0 20 0)));;尺寸标注
)
)
(princ)
)

(defun c:tt() 
   (if (and (setq dis (getreal "\n长度<退出>:")) 
            (setq pt (getpoint "\n基点<退出>:")) 
       ) 
     (progn 
        (setq p1 (mapcar '+ pt '(30 30 0)) ;;p1 p2 p3左边三个圆心，半径任意，这里是30 
              p2 (mapcar '+ p1 '(0 60 0)) 
              p3 (polar p1 (/ pi 6.0) 60) 
              p4 (mapcar '+ p3 '(0 100 0)) 
              mat0(xdrx_matrix_identity 3) 
              mat (xdrx_matrix_setmirror mat0 (list p3 p4)) ;;中间圆心竖直线P3 P4做镜像线构建镜像矩阵 
        ) 
        (xdrx_setmark) 
        (setq e1 (xdrx_circle_make p1 30)  ;;绘制左边和中间的3个园 
              e2 (xdrx_circle_make p2 30) 
              e3 (xdrx_circle_make p3 30) 
        ) 
        (xdrx_entity_transformedcopy e1 mat) ;;镜像左边两个圆，得到右边两个圆 
        (xdrx_entity_transformedcopy e2 mat) 
        (setq ss (xdrx_getss) 
              box (xdrx_entity_box ss) ;;所有圆的包围盒 
              len (distance (car box)(cadr box)) ;;底边的长度和输入的距离比值得到缩放系数 
              scl (/ dis len) 
              mat (xdrx_matrix_setscale mat0 scl pt) ;;以基点PT构建缩放矩阵 
        ) 
        (xdrx_entity_transform ss mat) ;;缩放所有圆 
        (setq box (xdrx_entity_box ss));;最终结果圆的包围盒 
        (apply 'xdrx_polyline_make (cons t box));;绘制封闭外框 
        (xdrx_dimension_MakeAlign (car box)(cadr box) (mapcar '- pt '(0 20 0)));;尺寸标注 
    ) 
   ) 
   (princ) 
)

ll_j · 发表于 2013-8-15 18:02:14

(defun c:tt(/ pt0 pt1 pt2 pt3 pt4 pt5 pt01 pt02 pt03 sc0 dis ang ss)
(setq pt0(getpoint "\n图形基点：")
sc0(getpoint pt0 "\n底边尺寸：") ;可以旋转
dis(distance pt0 sc0)
ang(angle pt0 sc0)
ss (ssadd)
)
(setq pt1 (polar (polar pt0 0 1) (/ pi 2) 1)
pt2 (polar pt1 (/ pi 6) 2)
pt3 (polar pt1 (/ pi 2) 2)
pt4 (polar pt2 (/ pi 6) 2)
pt5 (polar pt4 (/ pi -2) 2)
pt02(polar (polar pt4 0 1) (/ pi 2) 1)
pt01(polar pt0 (/ pi 2) 4)
pt03(polar pt02 (/ pi -2) 4)
)
(ssadd (mkc pt1) ss) ;创建新实体，同时构建新实体选择集
(ssadd (mkc pt2) ss)
(ssadd (mkc pt3) ss)
(ssadd (mkc pt4) ss)
(ssadd (mkc pt5) ss)
(ssadd (mkl pt0 pt01) ss)
(ssadd (mkl pt0 pt03) ss)
(ssadd (mkl pt01 pt02) ss)
(ssadd (mkl pt03 pt02) ss)
(command "._scale" ss "" pt0 (/ dis (distance pt0 pt03)))
(command "._rotate" ss "" pt0 (* 180 (/ ang pi)))
(princ)
)
(defun mkl(pt1 pt2) ;画线
(entmakex
(list '(0 . "LINE")
(cons 10 pt1)
(cons 11 pt2)
)
)
)
(defun mkc(pt) ;画圆
(entmakex
(list '(0 . "CIRCLE")
(cons 10 pt)
'(40 . 1)
)
)
)

(defun c:tt(/ pt0 pt1 pt2 pt3 pt4 pt5 pt01 pt02 pt03 sc0 dis ang ss) 
  (setq pt0(getpoint "\n图形基点：") 
        sc0(getpoint pt0 "\n底边尺寸：")    ;可以旋转 
        dis(distance pt0 sc0) 
        ang(angle pt0 sc0) 
        ss (ssadd) 
  ) 
  (setq pt1 (polar (polar pt0 0 1) (/ pi 2) 1) 
        pt2 (polar pt1 (/ pi 6) 2) 
        pt3 (polar pt1 (/ pi 2) 2) 
        pt4 (polar pt2 (/ pi 6) 2) 
        pt5 (polar pt4 (/ pi -2) 2) 
        pt02(polar (polar pt4 0 1) (/ pi 2) 1) 
        pt01(polar pt0 (/ pi 2) 4) 
        pt03(polar pt02 (/ pi -2) 4) 
  ) 
  (ssadd (mkc pt1) ss)          ;创建新实体，同时构建新实体选择集 
  (ssadd (mkc pt2) ss) 
  (ssadd (mkc pt3) ss) 
  (ssadd (mkc pt4) ss) 
  (ssadd (mkc pt5) ss) 
  (ssadd (mkl pt0 pt01) ss) 
  (ssadd (mkl pt0 pt03) ss) 
  (ssadd (mkl pt01 pt02) ss) 
  (ssadd (mkl pt03 pt02) ss) 
  (command "._scale" ss "" pt0 (/ dis (distance pt0 pt03))) 
  (command "._rotate" ss "" pt0 (* 180 (/ ang pi))) 
  (princ) 
) 
 
(defun mkl(pt1 pt2)  ;画线 
  (entmakex 
    (list '(0 . "LINE") 
          (cons 10 pt1) 
          (cons 11 pt2) 
    ) 
  ) 
) 
 
(defun mkc(pt)  ;画圆 
  (entmakex 
    (list '(0 . "CIRCLE") 
          (cons 10 pt) 
          '(40 . 1) 
    ) 
  ) 
)

newer · 发表于 2013-8-15 18:18:25

你思路是啥啊，翔版主，LL-J长老的程序没注释，思路大家一时想不到，你说说你的思路。

炫翔 · 发表于 2013-8-15 18:20:52

本帖最后由炫翔于 2013-8-15 18:22 编辑

newer 发表于 2013-8-15 18:18
你思路是啥啊，翔版主，LL-J长老的程序没注释，思路大家一时想不到，你说说你的思路。

也是根据极坐标来实现最后缩放，不过，中间，我会考虑阵列的方法
待后面，我给大家看书上的一个解答，貌似更好些

炫翔 · 发表于 2013-8-15 18:31:21

书上的拿出来给大家参考，看看哪种方法程序大小与执行的速度最快

别小看这个实例，实例可以扩大的，但是方法始终是一样的

(defun c:xx()
(setvar "cmdecho" 0)
(setq oldlay (getvar "clayer"))
(setq os (getvar "osmode"))
(setvar "osmode" 0)
(setq w (getreal "输入底部宽度<100>:"))
(setq rp1 (getpoint "\n输入左下角点:"))
(if (null w) (setq w 100.0))
(setq r (/ w 2 (1+ (sqrt 3))))
(setq cp1 (polar rp1 (/ pi 4) (* r (sqrt 2))))
(setq cp2 (polar cp1 (/ pi 6) (* r 2)))
(setq rp2 (polar rp1 0 w))
(setq rp3 (polar rp2 (/ pi 2) (* 4 r)))
(setq gap (* 2 (sqrt 3) r))
(command "-layer" "m" "str" "c" 4 "" "")
(command "rectang" rp1 rp3)
(command "circle" cp1 r)
(command "array" (entlast) "" "r" 2 2 (* r 2) gap)
(command "circle" cp2 r)
(command "-layer" "m" "dim" "c" 1 "" "")
(command "dim1" "hor" rp1 rp2 (polar rp1 (* pi 1.5) 10) "")
(setvar "osmode" os)
(setvar "clayer" oldlay)
(prin1)
)

q3_2006 · 发表于 2013-8-15 19:52:42

ll_j 发表于 2013-8-15 18:02

元老的方法最适合新手，简单易懂，学习了！

st788796 · 发表于 2013-8-15 19:59:16

做出1单位的，后面做成普通块或动态块来自: Android客户端

ayl1004 · 发表于 2013-8-15 20:36:15

长度是直径的1加根号3倍，计算半径，剩下的就简单了

st788796 · 发表于 2013-8-15 20:49:14

ayl1004 发表于 9 分钟前

 登录/注册后可看大图

长度是直径的1加根号3倍，计算半径，剩下的就简单了

正解，计算半径是基本，其他就不拘泥于方式了，command entmake vla transformcopy(api)…来自: Android客户端

newer · 发表于 2013-8-15 20:54:42

st788796 发表于 2013-8-15 20:49
正解，计算半径是基本，其他就不拘泥于方式了，command entmake vla transformcopy(api)…

我的那个程序可没计算半径，利用ACAD自己的图形算法自己去算的。

ll_j · 发表于 2013-8-15 21:18:22

newer 发表于 2013-8-15 18:18
你思路是啥啊，翔版主，LL-J长老的程序没注释，思路大家一时想不到，你说说你的思路。

我的这段代码应该是不用注解的，很容易看懂。既然说了，我就啰嗦几句。

1. 开始的输入，我采用了双getpoint的方法，变通地同时得到距离和转角。
2. 随后采用polar来计算圆心（半径为1）和直线端点，为防止开方计算带来误差，所以所有点都是采用polar的方法计算。
3. 采用entmakex构造圆和直线，好处是可以直接得到实体名，并直接加进选择集。
4. 按比例缩放并旋转到指定位置和大小，这一步用矩阵变换或许更有“力度”，但对于非API代码，这有一定难度，不如command来得直接。

这种程序原本没有什么难度，只是繁琐一些，应该出彩的地方应该是矩阵变换，不过我不太会，只好作罢。不甘寂寞，也就在输入部分加了一点小花。

newer · 发表于 2013-8-15 21:22:42

ll_j 发表于 2013-8-15 21:18
我的这段代码应该是不用注解的，很容易看懂。既然说了，我就啰嗦几句。

1. 开始的输入，我采用了双get ...

没我那句话，也得不到两位精彩的解释，长老： http://bbs.xdcad.net/thread-670123-1-1.html
这个帖子有些习题，长老提携提携新人。

st788796 · 发表于 2013-8-15 22:48:13

newer 发表于 1 小时前

 登录/注册后可看大图

我的那个程序可没计算半径，利用ACAD自己的图形算法自己去算的。

呵呵，开始没仔细看，可以少一次entity_box, transform所有圆和box来自: Android客户端

newer · 发表于 2013-8-15 23:11:42

st788796 发表于 2013-8-15 22:48
呵呵，开始没仔细看，可以少一次entity_box, transform所有圆和box

你还是没仔细看{:soso_e113:}，程序里面从来没算半径到底等于什么，里面的半径30给什么都可以，1,2,3000都行，都是用图形自己得到的。不能少一次BOX。

账号		自动登录	找回密码
密码			立即注册

[有奖答题] 练习:此图的参数化

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

评分

点评

评分

点评

点评

点评

评分

点评