关于修改外部参照绝对路径的问题

Lisphk

插入外部参照或图像后，当初选的是绝对路径，现在想修改为相对路径有什么方法吗？

tjuzkj

(command "_.-xref" "_path" < Xref Name > < New Path >)
< Xref Name >为外部参照名
< New Path >为绝对路径

st788796

..\\filename

Lisphk

tjuzkj 发表于 2013-9-2 13:02
(command "_.-xref" "_path" < Xref Name > < New Path >)
< Xref Name >为外部参照名
< New Path >为绝 ...

已经插入了，怎么改？

Lisphk

st788796 发表于 2013-9-2 13:06
..\\filename

已经插入了，在哪里面修改？

tjuzkj

;;-------------=={ 相对路径转化为完整路径 }==-------------;;
;;                                                            ;;
;;  Converts a Relative XRef path to a Full Path.             ;;
;;------------------------------------------------------------;;
;;  Author: Lee Mac, Copyright  2011 - www.lee-mac.com       ;;
;;------------------------------------------------------------;;
;;  Arguments:                                                ;;
;;  dir  - Directory of the Drawing in which the Xref resides ;;
;;  path - Relative Xref Path                                 ;;
;;------------------------------------------------------------;;
;;  Returns:  Full XRef Path                                  ;;
;;------------------------------------------------------------;;

(defun LM:XRef:Relative->Full ( dir path ) (setq dir (vl-string-right-trim "\\" dir))
  (cond
    ( (eq ".." (substr path 1 2))

      (LM:XRef:Relative->Full
        (substr dir 1 (vl-string-position 92 dir nil t))
        (substr path 4)
      )
    )
    ( (eq "."  (substr path 1 1))

      (strcat dir (substr path 2))
    )
    ( (strcat dir "\\" path) )
  )
)

tjuzkj

;;-------------=={ 完整路径转换为相对路径 }==-------------;;
;;                                                            ;;
;;  Converts a Full XRef path to a Relative Path.             ;;
;;------------------------------------------------------------;;
;;  Author: Lee Mac, Copyright  2011 - www.lee-mac.com       ;;
;;------------------------------------------------------------;;
;;  Arguments:                                                ;;
;;  dir  - Directory of the Drawing in which the Xref resides ;;
;;  path - Full Xref Path                                     ;;
;;------------------------------------------------------------;;
;;  Returns:  Relative XRef Path                              ;;
;;------------------------------------------------------------;;

(defun LM:XRef:Full->Relative ( dir path / p q ) (setq dir (vl-string-right-trim "\\" dir))
  (cond
    ( (and
        (setq p (vl-string-position 58  dir))
        (setq q (vl-string-position 58 path))
        (not (eq (strcase (substr dir 1 p)) (strcase (substr path 1 q))))
      )     
      path
    )
    ( (and
        (setq p (vl-string-position 92  dir))
        (setq q (vl-string-position 92 path))
        (eq (strcase (substr dir 1 p)) (strcase (substr path 1 q)))
      )
      (LM:Xref:Full->Relative (substr dir (+ 2 p)) (substr path (+ 2 q)))
    )
    ( (and
        (setq q (vl-string-position 92 path))
        (eq (strcase dir) (strcase (substr path 1 q)))
      )
      (strcat ".\\" (substr path (+ 2 q)))
    )
    ( (eq "" dir)
      path
    )
    ( (setq p (vl-string-position 92 dir))
      (LM:Xref:Full->Relative (substr dir (+ 2 p)) (strcat "..\\" path))
    )
    ( (LM:Xref:Full->Relative "" (strcat "..\\" path)) )
  )
)

tjuzkj

下面是个完整的程序，可以在相对路径与完整路径之间相互转化。

st788796

tjuzkj 发表于 2013-9-10 10:28
下面是个完整的程序，可以在相对路径与完整路径之间相互转化。

关键修改还是用的 command xref

clinber

tjuzkj 发表于 2013-9-10 10:28
下面是个完整的程序，可以在相对路径与完整路径之间相互转化。

命令: REPATHXREFS
DOSLib from Robert McNeel & Associates is required.
It's available for free at www.mcneel.com.
Exiting... 参数类型错误: VLA-OBJECT nil

对于win7 64位的系统 cad2014也是64位的 运行了出现这个问题，应该怎么办呢