Spline精确包围盒ClosestPointToProjection应用

csharp · 发表于 2014-9-6 17:21:42

lgx9612 发表于 2014-9-6 16:50
看看你的代码能否正确的把如附件中spline的曲线计算成功?
请看http://bbs.xdcad.net/forum.php?mod=viewth ...

你用的取模拟点方式，不如 AutoDESK 提供的方法精确方便

lgx9612 · 发表于 2014-9-6 19:20:18

csharp 发表于 2014-9-6 17:21
你用的取模拟点方式，不如 AutoDESK 提供的方法精确方便

AutoDESK 提供的方法?可否教我?

csharp · 发表于 2014-9-6 19:31:28

lgx9612 发表于 2014-9-6 19:20
AutoDESK 提供的方法?可否教我?

主题标题中已经说出了函数名称

lgx9612 · 发表于 2014-9-6 19:51:24

本帖最后由 lgx9612 于 2014-9-6 19:56 编辑

csharp 发表于 2014-9-6 19:31
主题标题中已经说出了函数名称

ClosestPointToProjection?不行吧（最起码1阶spline不行）？我的应用中到目前为止我的代码对spline完全可以成功计算,但其它用到函数来实现都不能百分百成功，我的附件中的spline用函数来就不能成功。

Free-Lancer · 发表于 2014-9-7 12:12:00

lgx9612 发表于 2014-9-6 19:51
ClosestPointToProjection?不行吧（最起码1阶spline不行）？我的应用中到目前为止我的代码对spline完全可 ...

41楼
http://bbs.xdcad.net/forum.php?m ... 782&pid=3498849

函数中的 ptl 应为局部变量，否则就出错，把 ptl 加入局部变量就 ok

lgx9612 · 发表于 2014-9-7 19:02:47

Free-Lancer 发表于 2014-9-7 12:12
41楼
http://bbs.xdcad.net/forum.php?mod=redirect&goto=findpost&ptid=671782&pid=3498849

但凡用GetBoundingBox这个函数就不能百分之百可以完全包容所选的spline线,有的包不住,更有完全在spline线之外,
但凡用Curve_GetClosestPointToProject 这个函数就不能百分之百成功计算最外的最小包容框点。或许大家在应用过程中没有碰到这种情况，但我的附件中的几条spline线就会让你的函数无能为力。完全在spline线之外的实例我就找不到了，因为之前做的实验没有保存起来，我实验的spline线不下万条.

st788796 · 发表于 2014-9-7 23:09:40

lgx9612 发表于 2014-9-7 19:02
但凡用GetBoundingBox这个函数就不能百分之百可以完全包容所选的spline线,有的包不住,更有完全在spline线 ...

不在于你试验多少条，看看 Help

(defun c:t1 (/ ss)
(if (setq ss (ssget '((0 . "spline"))))
('((x / e i)
(setq i x)
(while (setq e (ssname ss (setq i (1+ i))))
(Pline:Make (Pnts:Box (SPline:box e)) t)
)
)
-1
)
)
(princ)
)
(defun Spline:Box (e / el pts ll ptl)
(if (and (setq el (entget e))
(= (cdr (assoc 0 el)) "SPLINE")
)
(progn
(setq pts (mapcar 'cdr
(vl-remove-if-not '(lambda (x) (= (car x) 10)) el)
)
ll (list (apply 'mapcar (cons 'min pts))
(apply 'mapcar (cons 'max pts))
)
)
(foreach n (list (getvar "ucsxdir") (getvar "ucsydir"))
(foreach p ll
(setq x (vlax-curve-getclosestpointtoprojection e p n t))
(and x (setq ptl (cons x ptl)))
)
)
(list (apply 'mapcar (cons 'min ptl))
(apply 'mapcar (cons 'max ptl))
)
)
)
)
(defun Pnts:Box (pts / bp up)
(setq bp (apply 'mapcar (cons 'min pts))
up (apply 'mapcar (cons 'max pts))
)
(list bp
(list (car up) (cadr bp) 0.)
up
(list (car bp) (cadr up) 0.)
)
)
;;;---------------------------------------------------------------;
;;;功能: 制造多段线 ;
;;;输入: pts --- 点表(2D) ;
;;;输出: 实体 ;
;;;---------------------------------------------------------------;
(defun Pline:Make (pts tf)
(entmakex (append '((0 . "LWPOLYLINE")
(100 . "AcDbEntity")
(100 . "AcDbPolyline")
)
(list (cons 90 (length pts))
(cons 70
(if tf
1
0
)
)
)
(mapcar '(lambda (x)
(list 10 (car x) (cadr x))
)
pts
)
)
)
)

(defun c:t1 (/ ss) 
  (if (setq ss (ssget '((0 . "spline")))) 
    ('((x / e i) 
       (setq i x) 
       (while (setq e (ssname ss (setq i (1+ i)))) 
         (Pline:Make (Pnts:Box (SPline:box e)) t) 
       ) 
      ) 
      -1 
    ) 
  ) 
  (princ) 
) 
(defun Spline:Box (e / el pts ll ptl) 
  (if (and (setq el (entget e)) 
           (= (cdr (assoc 0 el)) "SPLINE") 
      ) 
    (progn 
      (setq pts        (mapcar        'cdr 
                        (vl-remove-if-not '(lambda (x) (= (car x) 10)) el) 
                ) 
            ll        (list (apply 'mapcar (cons 'min pts)) 
                      (apply 'mapcar (cons 'max pts)) 
                ) 
      ) 
      (foreach n (list (getvar "ucsxdir") (getvar "ucsydir")) 
        (foreach p ll 
          (setq x (vlax-curve-getclosestpointtoprojection e p n t)) 
          (and x (setq ptl (cons x ptl))) 
        ) 
      ) 
      (list (apply 'mapcar (cons 'min ptl)) 
            (apply 'mapcar (cons 'max ptl)) 
      ) 
    ) 
  ) 
) 
(defun Pnts:Box        (pts / bp up) 
  (setq        bp (apply 'mapcar (cons 'min pts)) 
        up (apply 'mapcar (cons 'max pts)) 
  ) 
  (list        bp 
        (list (car up) (cadr bp) 0.) 
        up 
        (list (car bp) (cadr up) 0.) 
  ) 
) 
;;;---------------------------------------------------------------; 
;;;功能: 制造多段线                                               ; 
;;;输入: pts --- 点表(2D)                                         ; 
;;;输出: 实体                                                     ; 
;;;---------------------------------------------------------------; 
(defun Pline:Make (pts tf) 
  (entmakex (append '((0 . "LWPOLYLINE") 
                      (100 . "AcDbEntity") 
                      (100 . "AcDbPolyline") 
                     ) 
                    (list (cons 90 (length pts)) 
                          (cons        70 
                                (if tf 
                                  1 
                                  0 
                                ) 
                          ) 
                    ) 
                    (mapcar '(lambda (x) 
                               (list 10 (car x) (cadr x)) 
                             ) 
                            pts 
                    ) 
            ) 
  ) 
)

lgx9612 · 发表于 2014-9-7 23:23:49

st788796 发表于 2014-9-7 23:09
不在于你试验多少条，看看 Help

呵呵，给你这么好的案例你不试一下。教程是死的，应用是活的。给个链接你看看吧，http://bbs.mjtd.com/thread-110754-3-1.html。

st788796 · 发表于 2014-9-7 23:40:50

lgx9612 发表于 2014-9-7 23:23
呵呵，给你这么好的案例你不试一下。教程是死的，应用是活的。给个链接你看看吧，http://bbs.mjtd.com/th ...

你用的是旧的，错是因为函数没有写对，还是自己体会这个函数说明吧

lgx9612 · 发表于 2014-9-7 23:54:25

st788796 发表于 2014-9-7 23:40
你用的是旧的，错是因为函数没有写对，还是自己体会这个函数说明吧

受教，我还是井底之蛙呀，我用的还是cad2004呀。

Free-Lancer · 发表于 2014-9-8 00:19:36

lgx9612 发表于 2014-9-7 23:54
受教，我还是井底之蛙呀，我用的还是cad2004呀。

给你用图直观说明一下这个函数，曲线向一个平面投影，结果是返回曲线上距离该平面最近的一个点，如果将曲线向四个方向投影，就会有四个点，将这四个点做个 BOX ，自然就是 SPline 的精确 BOX
这个函数 ARX  原型
virtual Acad::ErrorStatus getClosestPointTo(
const AcGePoint3d& givenPnt,
   const AcGeVector3d& direction,
   AcGePoint3d& pointOnCurve,
   Adesk::Boolean extend = Adesk::kFalse
) const;

lgx9612 · 发表于 2014-9-8 00:30:41

Free-Lancer 发表于 2014-9-8 00:19
给你用图直观说明一下这个函数，曲线向一个平面投影，结果是返回曲线上距离该平面最近的一个点，如果将曲 ...

谢谢大师深夜做图教导，非常感谢。此函数实已理解，但可能因为我的版本较低，所以ClosestPointToProjection对一阶的spline出错了。因此我才会井底之蛙，对此函数的不支持。

liuhaixin88 · 发表于 2014-9-9 09:35:57

lgx9612 发表于 2014-9-8 00:30
谢谢大师深夜做图教导，非常感谢。此函数实已理解，但可能因为我的版本较低，所以ClosestPointToProjecti ...

为什么还固守 CAD2004? http://bbs.mjtd.com/thread-110754-4-1.html

就这个问题，都折腾够久了吧，{:soso_e100:}

lgx9612 · 发表于 2014-9-9 19:02:30

liuhaixin88 发表于 2014-9-9 09:35
为什么还固守 CAD2004? http://bbs.mjtd.com/thread-110754-4-1.html

呵呵，工作在用呀，没有办法。是折腾够久的了。

st788796 · 发表于 2014-9-9 20:33:43

lgx9612 发表于 2014-9-9 19:02
呵呵，工作在用呀，没有办法。是折腾够久的了。

明天找个2004试试

账号		自动登录	找回密码
密码			立即注册

[每日一码] Spline精确包围盒ClosestPointToProjection应用

点评

点评

点评

点评

点评

点评

点评

点评

点评

评分

点评

点评