(XD::String:Num->CN)数字转中文数字

st788796 · 发表于 2013-12-2 12:46:16

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

本帖最后由 st788796 于 2013-12-2 14:16 编辑

;;数字转中文
;;num string 数字
;;mod t 中文数字 nil 大写中文数字
(defun XD::String:Num->CN (String mod / List:Split
ChkZerop Int->CN l1 l2
nint nzerop dot int zp
l
)
(defun list:split (lst n / ll nl)
(while lst
(repeat n
(setq ll (cons (car lst) ll)
lst (cdr lst)
)
)
(setq nl (cons (reverse ll) nl)
ll nil
)
)
(reverse nl)
)
(defun chkzerop (lst)
(mapcar '(lambda (x)
(mapcar '(lambda (a)
(if (or (= a "0") (null a))
""
a
)
)
x
)
)
lst
)
)
(defun Int->CN (lst mod / str tf)
(setq lst (mapcar '(lambda (x)
(mapcar '(lambda (a b)
(if (= a "")
""
(strcat
(if mod
(cadr (assoc a l2))
(caddr (assoc a l2))
)
(if mod
(car b)
(cadr b)
)
)
)
)
x
l1
)
)
lst
)
lst (mapcar
'(lambda (a / l)
(setq l (mapcar '(lambda (x y)
(if (= x "")
(if (= y "")
"零"
(strcat "零" y)
)
(strcat x y)
)
)
a
(cdr a)
)
)
(vl-string-subst "零" "零零" (strcat (car l) (caddr l)))
)
(reverse (mapcar 'reverse lst))
)
lst (mapcar '(lambda (x)
(if (= x "零")
""
x
)
)
lst
)
)
(if (= (substr (car lst) 1 2) "零")
(setq lst (cons (substr (car lst) 3) (cdr lst)))
)
(setq lst (reverse lst)
str (car lst)
tf t
)
(while (setq lst (cdr lst))
(if tf
(setq str (strcat (car lst) "万" str)
tf nil
)
(setq str (strcat (car lst) "亿" str)
tf t
)
)
)
(setq str (vl-string-subst "万" "零万" str)
str (vl-string-subst "亿" "零亿" str)
)
(if mod
(xdrx_string_replace str "零" "〇")
str
)
)
;;Main
(setq zp (vl-string-search "." String)
l1 '(("" "") ("十" "拾") ("百" "佰") ("千" "仟"))
l2 '(("0" "〇" "零")
("1" "一" "壹")
("2" "二" "贰")
("3" "三" "叁")
("4" "四" "肆")
("5" "五" "伍")
("6" "六" "陆")
("7" "七" "柒")
("8" "八" "捌")
("9" "九" "玖")
)
)
(if (or zp (and zp (zerop zp)))
(setq nzerop (XD::String:RegexpS "\\d" (substr String (+ 2 zp)) "")
nzerop (strcat "点"
(apply 'strcat
(if mod
(mapcar '(lambda (x)
(cadr (assoc x l2))
)
nzerop
)
(mapcar '(lambda (x)
(caddr (assoc x l2))
)
nzerop
)
)
)
)
nint (substr String 1 zp)
)
(setq nzerop ""
nint String
)
)
(if (/= nint "")
(setq nint (chkzerop
(list:split
(reverse (XD::String:RegexpS "\\d" nint "")
)
4
)
)
nint (vl-string-right-trim "零" (Int->CN nint mod))
)
(setq nint "")
)
(strcat nint nzerop)
)

;;数字转中文 
;;num string 数字 
;;mod t 中文数字 nil 大写中文数字 
(defun XD::String:Num->CN (String  mod           /           List:Split 
                           ChkZerop           Int->CN l1           l2 
                           nint           nzerop  dot           int           zp 
                           l 
                          ) 
  (defun list:split (lst n / ll nl) 
    (while lst 
      (repeat n 
        (setq ll  (cons (car lst) ll) 
              lst (cdr lst) 
        ) 
      ) 
      (setq nl (cons (reverse ll) nl) 
            ll nil 
      ) 
    ) 
    (reverse nl) 
  ) 
  (defun chkzerop (lst) 
    (mapcar '(lambda (x) 
               (mapcar '(lambda        (a) 
                          (if (or (= a "0") (null a)) 
                            "" 
                            a 
                          ) 
                        ) 
                       x 
               ) 
             ) 
            lst 
    ) 
  ) 
  (defun Int->CN (lst mod / str tf) 
    (setq lst (mapcar '(lambda (x) 
                         (mapcar '(lambda (a b) 
                                    (if        (= a "") 
                                      "" 
                                      (strcat 
                                        (if mod 
                                          (cadr (assoc a l2)) 
                                          (caddr (assoc a l2)) 
                                        ) 
                                        (if mod 
                                          (car b) 
                                          (cadr b) 
                                        ) 
                                      ) 
                                    ) 
                                  ) 
                                 x 
                                 l1 
                         ) 
                       ) 
                      lst 
              ) 
          lst (mapcar 
                '(lambda (a / l) 
                   (setq l (mapcar '(lambda (x y) 
                                      (if (= x "") 
                                        (if (= y "") 
                                          "零" 
                                          (strcat "零" y) 
                                        ) 
                                        (strcat x y) 
                                      ) 
                                    ) 
                                   a 
                                   (cdr a) 
                           ) 
                   ) 
                   (vl-string-subst "零" "零零" (strcat (car l) (caddr l))) 
                 ) 
                (reverse (mapcar 'reverse lst)) 
              ) 
          lst (mapcar '(lambda (x) 
                         (if (= x "零") 
                           "" 
                           x 
                         ) 
                       ) 
                      lst 
              ) 
    ) 
    (if        (= (substr (car lst) 1 2) "零") 
      (setq lst (cons (substr (car lst) 3) (cdr lst))) 
    ) 
    (setq lst (reverse lst) 
          str (car lst) 
          tf  t 
    ) 
    (while (setq lst (cdr lst)) 
      (if tf 
        (setq str (strcat (car lst) "万" str) 
              tf  nil 
        ) 
        (setq str (strcat (car lst) "亿" str) 
              tf  t 
        ) 
      ) 
    ) 
    (setq str (vl-string-subst "万" "零万" str) 
          str (vl-string-subst "亿" "零亿" str) 
    ) 
    (if        mod 
      (xdrx_string_replace str "零" "〇") 
      str 
    ) 
  ) 
  ;;Main 
  (setq        zp (vl-string-search "." String) 
        l1 '(("" "") ("十" "拾") ("百" "佰") ("千" "仟")) 
        l2 '(("0" "〇" "零") 
             ("1" "一" "壹") 
             ("2" "二" "贰") 
             ("3" "三" "叁") 
             ("4" "四" "肆") 
             ("5" "五" "伍") 
             ("6" "六" "陆") 
             ("7" "七" "柒") 
             ("8" "八" "捌") 
             ("9" "九" "玖") 
            ) 
  ) 
  (if (or zp (and zp (zerop zp))) 
    (setq nzerop (XD::String:RegexpS "\\d" (substr String (+ 2 zp)) "") 
          nzerop (strcat "点" 
                         (apply        'strcat 
                                (if mod 
                                  (mapcar '(lambda (x) 
                                             (cadr (assoc x l2)) 
                                           ) 
                                          nzerop 
                                  ) 
                                  (mapcar '(lambda (x) 
                                             (caddr (assoc x l2)) 
                                           ) 
                                          nzerop 
                                  ) 
                                ) 
                         ) 
                 ) 
          nint         (substr String 1 zp) 
    ) 
    (setq nzerop "" 
          nint String 
    ) 
  ) 
  (if (/= nint "") 
    (setq nint (chkzerop 
                 (list:split 
                   (reverse (XD::String:RegexpS "\\d" nint "") 
                   ) 
                   4 
                 ) 
               ) 
          nint (vl-string-right-trim "零" (Int->CN nint mod)) 
    ) 
    (setq nint "") 
  ) 
  (strcat nint nzerop) 
)

ll_j · 发表于 2013-12-2 12:56:54

一个错误：和“一二三”对应的是“〇”，不是“零”，我看过《咬文嚼字》的一篇东西。
“〇”在搜狗拼音中可以用拼音输入，也可以用“v0”方式输入。
遗憾的是，在几乎所有的中文字库中，这个“〇”做得都不怎么好看。

st788796 · 发表于 2013-12-2 12:58:52

本帖最后由 st788796 于 2013-12-2 13:00 编辑

ll_j 发表于 2013-12-2 12:56
一个错误：和“一二三”对应的是“〇”，不是“零”，我看过《咬文嚼字》的一篇东西。
“〇”在搜狗拼音中 ...

会计上都是"零", 不用 "〇" 吧
如果用的话就把 ("0" "零" "零) 改成 ("0" "〇" "零")

st788796 · 发表于 2013-12-2 13:01:39

ll_j 发表于 2013-12-2 12:56
一个错误：和“一二三”对应的是“〇”，不是“零”，我看过《咬文嚼字》的一篇东西。
“〇”在搜狗拼音中 ...

这样效果？
_$ (xd::string:num->cn ".13002322010001" t)
"点一三〇〇二三二二〇一〇〇〇一"
_$ (xd::string:num->cn "123131000321310.13002322010001" t)
"一百二十三万一千三百一十亿零三十二万一千三百一十点一三〇〇二三二二〇一〇〇〇一"
_$

ll_j · 发表于 2013-12-2 13:12:16

st788796 发表于 2013-12-2 13:01
这样效果？
_$ (xd::string:num->cn ".13002322010001" t)
"点一三〇〇二三二二〇一〇〇〇一"

这是一种特殊的用法，“三万零五十”这里的“零”不是数值的“零”，而是“零头”的“零”，所以，几个连续的“〇”都读成一个“零”。
会计是一个很严谨的专业，很少使用“一二三”这种简体，在标识数字的中文时，一般都用“壹贰叁”这种大写。
中文数字的小写，一般是在日常使用，比如年份，如果表示“二〇一三年”为“二零一三年”，是不是感觉有点...

/db_自贡黄明儒_ · 发表于 2013-12-2 13:18:50

想过这方面的事，一直没有动手，确实有点难。支持一个

st788796 · 发表于 2013-12-2 13:36:37

本帖最后由 st788796 于 2013-12-2 14:42 编辑

零处理还有问题, 待更新

已修改

暂存下提取中文的 Patten

(xd::string:regexps "[一|二|三|四|五|六|七|八|九|十|百|千|万|亿|点|零|〇]+" "飞洒离点点开解放零点一二三四五" "")
("点点" "零点一二三四五")

lianghui2018 · 发表于 2014-3-19 22:09:41

收藏，以待备用~谢谢楼主分享

5664491 · 发表于 2014-4-9 22:03:57

谢谢楼主分享

hh_lj007 · 发表于 2020-12-21 09:12:41

谢谢楼主分享

账号		自动登录	找回密码
密码			立即注册

[字符串] (XD::String:Num->CN)数字转中文数字

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

点评