(XD::Table:Make)制作表格

st788796 · 发表于 2014-3-10 17:30:22

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

本帖最后由 st788796 于 2014-11-12 10:47 编辑

;|
函数名称:XD::Table:Make
调用格式:(XD::Table:Make lst pt RowHeight Height)
参数说明:
lst --- 按行字串列表 ((str1 str2 ...) (str ...) ...)
pt --- 表格插入点
RowHeight ---- 行高
Height ---- 字高
返回值:表
备注:字高不要大于行高的一半
lst 第一个元素可以是设定的列宽表, 没有的时候按字符宽度适应
|;
;;2014.11.12 修改
;;第一个元素为实数表时为设定的每列列宽，可选
;;第二个元素或第一个元素为 string 时作为表格标题
(defun XD::Table:Make (lst p RowHeight height
/ tf tb i
_ColumnWidths _widthL _spa
maxCol
)
(defun _ColumnWidths (lst h mL / nl)
(setq nL (mapcar '(lambda (x)
(XD::List:FillGap x " " mL)
)
lst
)
)
(mapcar '(lambda (x)
(XD::String:ActualMaxWidth x "" h 1.)
)
(apply 'mapcar (cons 'list nL))
)
)
(if (or (null height) (= height ""))
(setq height (* RowHeight 0.3))
)
;;处理列宽
(if
(and
(listp (car lst))
(apply
'and
(mapcar '(lambda (x) (or (eq (type x) 'REAL) (eq (type x) 'INT)))
(car lst)
)
)
)
(progn
(setq _widthL (car lst)
maxCol (apply 'max (mapcar 'length lst))
)
(if (eq (type (cadr lst)) 'STR)
(setq tile (cadr lst)
lst (cddr lst)
)
(setq tile nil
lst (cdr lst)
)
)
)
(progn
(if (eq (type (car lst)) 'STR)
(setq tile (car lst)
lst (cdr lst)
)
(setq tile nil)
)
(setq maxCol (apply 'max (mapcar 'length lst))
_WidthL (_ColumnWidths lst height maxCol)
)
)
)
(setq tb (xdrx_table_make
p
(1+ (length lst))
RowHeight
maxCol
10.
)
_spa (* 6 (xdrx_table_horzCellMargin tb))
)
(XD::Table:Begin tb)
(xdrx_table_SetTextHeight tb 1 3.0)
(xdrx_entity_scale
tb
p
(/ RowHeight (xdrx_table_rowheight tb 1))
)
(setq i -1)
(mapcar '(lambda (x)
(xdrx_table_setcolumnwidth tb (setq i (1+ i)) x)
)
(mapcar '(lambda (a) (+ _spa a)) _WidthL)
)
;;(xdrx_table_setrowheight tb RowHeight)
(xdrx_table_settextheight tb 7 height)
(xdrx_table_setalignment tb 1 5)
(xdrx_table_SetGridVisibility tb 2 41 nil)
(setq i 0)
(mapcar
'(lambda (x / j)
(setq j -1
i (1+ i)
)
(mapcar '(lambda (a)
(xdrx_table_settextstring
tb
i
(setq j (1+ j))
(if (eq (type a) 'STR)
a
(vl-princ-to-string a)
) ;_2014.11.12
)
)
x
)
)
lst
)
(if tile
(xdrx_table_settextstring tb 0 0 tile)
) ;_2014.11.12
(XD::Table:End tb)
tb
)

;| 
函数名称:XD::Table:Make   
调用格式:(XD::Table:Make lst pt RowHeight Height)   
参数说明: 
lst --- 按行字串列表 ((str1 str2 ...) (str ...) ...) 
 pt --- 表格插入点 
RowHeight ---- 行高 
Height ---- 字高   
返回值:表   
备注:字高不要大于行高的一半 
lst 第一个元素可以是设定的列宽表, 没有的时候按字符宽度适应   
|; 
;;2014.11.12 修改 
;;第一个元素为实数表时为设定的每列列宽，可选 
;;第二个元素或第一个元素为 string 时作为表格标题 
(defun XD::Table:Make (lst         p           RowHeight height 
                       /         tf           tb             i 
                       _ColumnWidths           _widthL   _spa 
                       maxCol 
                      ) 
  (defun _ColumnWidths (lst h mL / nl) 
    (setq nL (mapcar '(lambda (x) 
                        (XD::List:FillGap x " " mL) 
                      ) 
                     lst 
             ) 
    ) 
    (mapcar '(lambda (x) 
               (XD::String:ActualMaxWidth x "" h 1.) 
             ) 
            (apply 'mapcar (cons 'list nL)) 
    ) 
  ) 
  (if (or (null height) (= height "")) 
    (setq height (* RowHeight 0.3)) 
  ) 
  ;;处理列宽 
  (if 
    (and 
      (listp (car lst)) 
      (apply 
        'and 
        (mapcar        '(lambda (x) (or (eq (type x) 'REAL) (eq (type x) 'INT))) 
                (car lst) 
        ) 
      ) 
    ) 
     (progn 
       (setq _widthL (car lst) 
             maxCol  (apply 'max (mapcar 'length lst)) 
       ) 
       (if (eq (type (cadr lst)) 'STR) 
         (setq tile (cadr lst) 
               lst  (cddr lst) 
         ) 
         (setq tile nil 
               lst  (cdr lst) 
         ) 
       ) 
     ) 
     (progn 
       (if (eq (type (car lst)) 'STR) 
         (setq tile (car lst) 
               lst  (cdr lst) 
         ) 
         (setq tile nil) 
       ) 
       (setq maxCol  (apply 'max (mapcar 'length lst)) 
             _WidthL (_ColumnWidths lst height maxCol) 
       ) 
     ) 
  ) 
  (setq        tb   (xdrx_table_make 
               p 
               (1+ (length lst)) 
               RowHeight 
               maxCol 
               10. 
             ) 
        _spa (* 6 (xdrx_table_horzCellMargin tb)) 
  ) 
  (XD::Table:Begin tb) 
  (xdrx_table_SetTextHeight tb 1 3.0) 
  (xdrx_entity_scale 
    tb 
    p 
    (/ RowHeight (xdrx_table_rowheight tb 1)) 
  ) 
  (setq i -1) 
  (mapcar '(lambda (x) 
             (xdrx_table_setcolumnwidth tb (setq i (1+ i)) x) 
           ) 
          (mapcar '(lambda (a) (+ _spa a)) _WidthL) 
  ) 
  ;;(xdrx_table_setrowheight tb RowHeight) 
  (xdrx_table_settextheight tb 7 height) 
  (xdrx_table_setalignment tb 1 5) 
  (xdrx_table_SetGridVisibility tb 2 41 nil) 
  (setq i 0) 
  (mapcar 
    '(lambda (x / j) 
       (setq j -1 
             i (1+ i) 
       ) 
       (mapcar '(lambda        (a) 
                  (xdrx_table_settextstring 
                    tb 
                    i 
                    (setq j (1+ j)) 
                    (if        (eq (type a) 'STR) 
                      a 
                      (vl-princ-to-string a) 
                    ) ;_2014.11.12 
                  ) 
                ) 
               x 
       ) 
     ) 
    lst 
  ) 
  (if tile 
    (xdrx_table_settextstring tb 0 0 tile) 
  ) ;_2014.11.12 
  (XD::Table:End tb) 
  tb 
)

st788796 · 发表于 2014-3-13 15:55:26

有一个问题，Table Cell 的文字为 Mtext，即使当前字体是西文字体，Cell 中同样可以输入中文，CAD会自动使用宋体(windows 7)，这样求出的列宽度会小

/db_自贡黄明儒_ · 发表于 2014-3-13 20:26:01

同一行而言，指定每列宽是不是更实用？

Free-Lancer · 发表于 2014-3-13 20:36:14

按每列中最长字串定该列适合宽度

/db_自贡黄明儒_ · 发表于 2014-3-13 21:27:15

Free-Lancer 发表于 2014-3-13 20:36
按每列中最长字串定该列适合宽度

比如明细表，国标每列宽度是定值，而且不同

st788796 · 发表于 2014-3-13 21:50:22

/db_自贡黄明儒_ 发表于 2014-3-13 21:27
比如明细表，国标每列宽度是定值，而且不同

可以将lst首元素规定为列宽

st788796 · 发表于 2014-3-22 20:25:40

2014.3.22更新

liuyj · 发表于 2014-3-22 22:55:33

除表头外，有块的行对齐设置不起作用，就是这句(xdrx_table_setalignment tb 7 5)

liuyj · 发表于 2014-3-22 22:56:50

另外，字体如何设置为自己想要的样式？看了半天帮助，也不知道xdrx_table_SetTextStyle怎么用

st788796 · 发表于 2014-3-22 23:29:20

liuyj 发表于 2014-3-22 22:56
另外，字体如何设置为自己想要的样式？看了半天帮助，也不知道xdrx_table_SetTextStyle怎么用

1 7 是全部区域设为正中对齐，对块有效
2 这个 Style 还是用 textstyle 系统变量设置，Cell 中用的是 Mtext，这个Mtext 有个自动适应，比如你设置了 EN，但仍可以写入中文，不过会出现字体替代

liuyj · 发表于 2014-3-22 23:46:16

应该是正中对齐，但我在cad2006及cad2010下得到的都是中上对齐

st788796 · 发表于 2014-3-22 23:57:00

liuyj 发表于 2014-3-22 23:46
应该是正中对齐，但我在cad2006及cad2010下得到的都是中上对齐

功能：	设定指定行或者具体行列的单元格的对齐方式
调用格式：	1. (xdrx_table_setAlignment <表格实体名> <Row Type> <对齐方式>) 2. (xdrx_table_setAlignment <表格实体名> <Row> <Column> <对齐方式>)
返回值：	1-9 1 kTopLeft 2 kTopCenter 3 kTopRight 4 kMiddleLeft 5 kMiddleCenter 6 kMiddleRight 7 kBottomLeft 8 kBottomCenter 9 kBottomRight
说明：	<Row Type> 1: kDataRow, 2: kTitleRow, 4: kHeaderRow 1+2+4=7 ：所有行

liuyj · 发表于 2014-3-23 00:11:42

没错，看帮助是应该这样写，可是我怎么弄也是下面这样.

st788796 · 发表于 2014-3-23 00:22:28

这样试一试
(xdrx_table_setalignment (car (entsel)) 1 5)

liuyj · 发表于 2014-3-23 00:34:21

这样可以中心对齐了，不能建立表格的时候直接到位吗？

账号		自动登录	找回密码
密码			立即注册

[表格] (XD::Table:Make)制作表格

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

点评