如何根据DTMTF.LOG在每个三角形重力中兴注记填挖方量

st788796 · 发表于 2014-3-12 09:53:32

本帖最后由 st788796 于 2014-3-12 09:54 编辑

树櫴希德发表于 2014-3-12 09:33
错误: no function definition: XDRX_STATUSBAR_BEGIN在函数库里找不到啊

你没有加载xdrxapi那个arx
在xdrxapi 中，可以注释掉，2014的Rabbion模式下没看到进度条就ok了

树櫴希德 · 发表于 2014-3-12 14:56:52

我写了个XLS的，就是比较麻烦

st788796 · 发表于 2014-3-12 16:32:15

树櫴希德发表于 2014-3-12 14:56
我写了个XLS的，就是比较麻烦

不知道你最终要什么成果，dwg还是excel表，如果是dwg，用lisp处理是一种方法，要excel表就在里面写VBA处理，不要来回折腾

树櫴希德 · 发表于 2014-3-12 17:27:23

用lisp处理就直接死机了，哎

树櫴希德 · 发表于 2014-3-12 17:28:24

我这也是没有办法啊，只希望南方CASS在新版本发现这个问题

st788796 · 发表于 2014-3-12 17:43:39

树櫴希德发表于 2014-3-12 17:28
我这也是没有办法啊，只希望南方CASS在新版本发现这个问题

这个程序仅text_make用了api，可以用entmake 或者 vla-addtext 完成，有思路了，自己改成不用 api lisp-lib

树櫴希德 · 发表于 2014-3-12 17:59:29

支持改进，我输入8543行数字进CAD才2分钟

st788796 · 发表于 2014-3-12 18:13:40

本帖最后由 st788796 于 2014-3-12 19:07 编辑

树櫴希德发表于 2014-3-12 17:59
支持改进，我输入8543行数字进CAD才2分钟

慢在这个text_make，可以试试用entmake一步到位能否快点
make后还执行了三次修改
换个函数试试效率

(defun _mktext (p str / txt)
(entmake (list '(0 . "Text")
'(100 . "AcDbEntity")
'(100 . "AcDbText")
(cons 1 str)
(cons 10 p)
'(40 . 0.2)
'(50 . 0.0)
'(41 . 1.0)
(cons 7 (getvar "textstyle"))
'(71 . 0)
'(72 . 4)
(cons 11 p)
'(73 . 1)
)
)
)

树櫴希德 · 发表于 2014-3-12 21:09:28

大侠，有飞点啊

树櫴希德 · 发表于 2014-3-12 21:10:21

213和262飞了

树櫴希德 · 发表于 2014-3-12 21:11:35

下面是DTMTF.LOG测试文件

st788796 · 发表于 2014-3-13 00:01:59

树櫴希德发表于 2014-3-12 21:11
下面是DTMTF.LOG测试文件

没有你说的情况，用下面程序，无需加载 xd-lisp-lib.vlx，感觉速度快很多

(gc)
(defun c:tt (/ str->pt _mktext fl lst
nl _pi2 _3pi d _Pnts:Center
_List:FromFile
)
(defun _List:FromFile (fn / f l ll)
(if (setq f (open (findfile fn) "r"))
(progn
(while (setq l (read-line f))
(setq ll (cons l ll))
)
(close f)
)
)
ll
)
(defun XD::Pnt:SetZ (p z)
(list (car p) (cadr p) z)
)
(defun str->pt (str)
(XD::Pnt:SetZ
(mapcar 'distof (cdr (xdrx_string_split str ",")))
0.
)
)
(defun _Pnts:Center (p1 p2 p3 /)
(mapcar '(lambda (x y z)
(/ (+ x y z) 3.)
)
p1
p2
p3
)
)
(defun _mktext (p str / txt)
(entmake (list '(0 . "Text")
'(100 . "AcDbEntity")
'(100 . "AcDbText")
(cons 1 str)
(cons 10 p)
'(40 . 0.2)
'(50 . 0.0)
'(41 . 1.0)
(cons 7 (getvar "textstyle"))
'(71 . 0)
'(72 . 4)
(cons 11 p)
'(73 . 1)
)
)
)
(if (setq fl (getfiled "Select Log file" "" "log" 8))
(progn
(setq lst (_List:FromFile fl)
_pi2 (* pi 0.5)
_3pi (- _pi2)
d 0.22
)
(while lst
(setq nl (cons (list (car lst)
(cadr lst)
(caddr lst)
(nth 3 lst)
(nth 4 lst)
)
nl
)
lst (cddr (cddddr lst))
)
)
(mapcar '(lambda (x / p bh ll)
(setq p (_Pnts:Center
(str->pt (cadr x))
(str->pt (caddr x))
(str->pt (cadddr x))
)
bh (substr (last x) 7)
ll (vl-remove "" (xdrx_string_split (car x) " "))
)
(_mktext (polar p _pi2 d) bh)
(_mktext p (strcat (car ll) (cadr ll)))
(_mktext (polar p _3pi d) (strcat (caddr ll) (last ll)))
)
nl
)
)
)
(princ)
)

(gc) 
(defun c:tt (/                str->pt           _mktext    fl         lst 
             nl                _pi2           _3pi              d                 _Pnts:Center 
             _List:FromFile 
            ) 
  (defun _List:FromFile        (fn / f l ll) 
    (if        (setq f (open (findfile fn) "r")) 
      (progn 
        (while (setq l (read-line f)) 
          (setq ll (cons l ll)) 
        ) 
        (close f) 
      ) 
    ) 
    ll 
  ) 
  (defun XD::Pnt:SetZ (p z) 
    (list (car p) (cadr p) z) 
  ) 
  (defun str->pt (str) 
    (XD::Pnt:SetZ 
      (mapcar 'distof (cdr (xdrx_string_split str ","))) 
      0. 
    ) 
  ) 
  (defun _Pnts:Center (p1 p2 p3 /) 
    (mapcar '(lambda (x y z) 
               (/ (+ x y z) 3.) 
             ) 
            p1 
            p2 
            p3 
    ) 
  ) 
  (defun _mktext (p str / txt) 
    (entmake (list '(0 . "Text") 
                   '(100 . "AcDbEntity") 
                   '(100 . "AcDbText") 
                   (cons 1 str) 
                   (cons 10 p) 
                   '(40 . 0.2) 
                   '(50 . 0.0) 
                   '(41 . 1.0) 
                   (cons 7 (getvar "textstyle")) 
                   '(71 . 0) 
                   '(72 . 4) 
                   (cons 11 p) 
                   '(73 . 1) 
             ) 
    ) 
  ) 
  (if (setq fl (getfiled "Select Log file" "" "log" 8)) 
    (progn 
      (setq lst         (_List:FromFile fl) 
            _pi2 (* pi 0.5) 
            _3pi (- _pi2) 
            d         0.22 
      ) 
      (while lst 
        (setq nl  (cons        (list (car lst) 
                              (cadr lst) 
                              (caddr lst) 
                              (nth 3 lst) 
                              (nth 4 lst) 
                        ) 
                        nl 
                  ) 
              lst (cddr (cddddr lst)) 
        ) 
      ) 
      (mapcar '(lambda (x / p bh ll) 
                 (setq p  (_Pnts:Center 
                            (str->pt (cadr x)) 
                            (str->pt (caddr x)) 
                            (str->pt (cadddr x)) 
                          ) 
                       bh (substr (last x) 7) 
                       ll (vl-remove "" (xdrx_string_split (car x) " ")) 
                 ) 
                 (_mktext (polar p _pi2 d) bh) 
                 (_mktext p (strcat (car ll) (cadr ll))) 
                 (_mktext (polar p _3pi d) (strcat (caddr ll) (last ll))) 
               ) 
              nl 
      ) 
    ) 
  ) 
  (princ) 
)

树櫴希德 · 发表于 2014-3-13 09:18:06

很遗憾，XDRX_API2004过期了，无法测试

st788796 · 发表于 2014-3-13 11:06:42

树櫴希德发表于 2014-3-13 09:18
很遗憾，XDRX_API2004过期了，无法测试

无需外部文件的

(gc)
(defun c:tt (/ str->pt _mktext fl
lst nl _pi2 _3pi
d _Pnts:Center _List:FromFile
String:Split
)
(defun String:Split (str delimiter / post strlst stl)
(if str
(progn
(setq stl (strlen delimiter))
(while (vl-string-search delimiter str)
(setq post (vl-string-search delimiter str)
strlst (cons (substr str 1 post) strlst)
str (substr str (+ 1 post stl))
)
)
(reverse (vl-remove "" (cons str strlst)))
)
)
)
(defun _List:FromFile (fn / f l ll)
(if (setq f (open (findfile fn) "r"))
(progn
(while (setq l (read-line f))
(setq ll (cons l ll))
)
(close f)
)
)
ll
)
(defun XD::Pnt:SetZ (p z)
(list (car p) (cadr p) z)
)
(defun str->pt (str)
(XD::Pnt:SetZ
(mapcar 'distof (cdr (String:Split str ",")))
0.
)
)
(defun _Pnts:Center (p1 p2 p3 /)
(mapcar '(lambda (x y z)
(/ (+ x y z) 3.)
)
p1
p2
p3
)
)
(defun _mktext (p str / txt)
(entmake (list '(0 . "Text")
'(100 . "AcDbEntity")
'(100 . "AcDbText")
(cons 1 str)
(cons 10 p)
'(40 . 0.2)
'(50 . 0.0)
'(41 . 1.0)
(cons 7 (getvar "textstyle"))
'(71 . 0)
'(72 . 4)
(cons 11 p)
'(73 . 1)
)
)
)
(if (setq fl (getfiled "Select Log file" "" "log" 8))
(progn
(setq lst (_List:FromFile fl)
_pi2 (* pi 0.5)
_3pi (- _pi2)
d 0.22
)
(while lst
(setq nl (cons (list (car lst)
(cadr lst)
(caddr lst)
(nth 3 lst)
(nth 4 lst)
)
nl
)
lst (cddr (cddddr lst))
)
)
(mapcar '(lambda (x / p bh ll)
(setq p (_Pnts:Center
(str->pt (cadr x))
(str->pt (caddr x))
(str->pt (cadddr x))
)
bh (substr (last x) 7)
ll (vl-remove "" (String:Split (car x) " "))
)
(_mktext (polar p _pi2 d) bh)
(_mktext p (strcat (car ll) (cadr ll)))
(_mktext (polar p _3pi d) (strcat (caddr ll) (last ll)))
)
nl
)
)
)
(princ)
)

(gc) 
(defun c:tt (/                 str->pt     _mktext         fl 
             lst         nl             _pi2         _3pi 
             d                 _Pnts:Center                 _List:FromFile 
             String:Split 
            ) 
  (defun String:Split (str delimiter / post strlst stl) 
    (if        str 
      (progn 
        (setq stl (strlen delimiter)) 
        (while (vl-string-search delimiter str) 
          (setq        post   (vl-string-search delimiter str) 
                strlst (cons (substr str 1 post) strlst) 
                str    (substr str (+ 1 post stl)) 
          ) 
        ) 
        (reverse (vl-remove "" (cons str strlst))) 
      ) 
    ) 
  ) 
  (defun _List:FromFile        (fn / f l ll) 
    (if        (setq f (open (findfile fn) "r")) 
      (progn 
        (while (setq l (read-line f)) 
          (setq ll (cons l ll)) 
        ) 
        (close f) 
      ) 
    ) 
    ll 
  ) 
  (defun XD::Pnt:SetZ (p z) 
    (list (car p) (cadr p) z) 
  ) 
  (defun str->pt (str) 
    (XD::Pnt:SetZ 
      (mapcar 'distof (cdr (String:Split str ","))) 
      0. 
    ) 
  ) 
  (defun _Pnts:Center (p1 p2 p3 /) 
    (mapcar '(lambda (x y z) 
               (/ (+ x y z) 3.) 
             ) 
            p1 
            p2 
            p3 
    ) 
  ) 
  (defun _mktext (p str / txt) 
    (entmake (list '(0 . "Text") 
                   '(100 . "AcDbEntity") 
                   '(100 . "AcDbText") 
                   (cons 1 str) 
                   (cons 10 p) 
                   '(40 . 0.2) 
                   '(50 . 0.0) 
                   '(41 . 1.0) 
                   (cons 7 (getvar "textstyle")) 
                   '(71 . 0) 
                   '(72 . 4) 
                   (cons 11 p) 
                   '(73 . 1) 
             ) 
    ) 
  ) 
  (if (setq fl (getfiled "Select Log file" "" "log" 8)) 
    (progn 
      (setq lst         (_List:FromFile fl) 
            _pi2 (* pi 0.5) 
            _3pi (- _pi2) 
            d         0.22 
      ) 
      (while lst 
        (setq nl  (cons        (list (car lst) 
                              (cadr lst) 
                              (caddr lst) 
                              (nth 3 lst) 
                              (nth 4 lst) 
                        ) 
                        nl 
                  ) 
              lst (cddr (cddddr lst)) 
        ) 
      ) 
      (mapcar '(lambda (x / p bh ll) 
                 (setq p  (_Pnts:Center 
                            (str->pt (cadr x)) 
                            (str->pt (caddr x)) 
                            (str->pt (cadddr x)) 
                          ) 
                       bh (substr (last x) 7) 
                       ll (vl-remove "" (String:Split (car x) " ")) 
                 ) 
                 (_mktext (polar p _pi2 d) bh) 
                 (_mktext p (strcat (car ll) (cadr ll))) 
                 (_mktext (polar p _3pi d) (strcat (caddr ll) (last ll))) 
               ) 
              nl 
      ) 
    ) 
  ) 
  (princ) 
)

树櫴希德 · 发表于 2014-3-13 11:40:42

测试成功，如果能在cad和EXCEL导出表格就好了如：三角形编号，三角形重心坐标（不要Z值），填方，挖方。每300个左右成一页A4打印。

账号		自动登录	找回密码
密码			立即注册

[编程申请] 如何根据DTMTF.LOG在每个三角形重力中兴注记填挖方量