检查坐标标注的原点

lucas3 · 发表于 2014-8-14 09:13:23

本帖最后由 lucas3 于 2014-8-14 09:59 编辑

先选择原点，框选标注（只针对坐标标注，过滤其它），检查座标标注的的原点是否在选择的那个原点，如果不是，就改色，（红色或黄色，如果标注是红色，就改黄色……）并显示出信息：有几个标注的原点不在指定的原点位上。

Free-Lancer · 发表于 2014-8-14 09:13:24

本帖最后由 Free-Lancer 于 2014-8-16 16:15 编辑

lucas3 发表于 2014-8-14 16:13
看起来还挺复杂的呀，

很简单啊!

(defun c:tt (/ p ss i e el pt typ len)
(if (and (setq p (getpoint "\nBase Point: "))
(setq ss (ssget '((0 . "Dimension") (-4 . "&=") (70 . 6))))
)
(progn
(setq p (trans p 1 0)
i (sslength ss)
)
(while (setq e (ssname ss (setq i (1- i))))
(setq el (entget e)
pt (cdr (assoc 13 el))
typ (cdr (assoc 70 el))
)
(if (= (setq len (cdr (assoc 1 el))) "")
(setq len (cdr (assoc 42 el)))
(setq len (distof len))
)
(if (= 64 (logand 64 typ))
(if (not (equal len (abs (- (car p) (car pt))) 1e-3))
(entmod (append el '((62 . 2)))) ;_黄色
(entmod (append el '((62 . 256)))) ;_恢复图层颜色
)
(if (not (equal len (abs (- (cadr p) (cadr pt))) 1e-3))
(entmod (append el '((62 . 2))))
(entmod (append el '((62 . 256))))
)
)
)
)
)
(princ)
)

(defun c:tt (/ p ss i e el pt typ len) 
  (if (and (setq p (getpoint "\nBase Point: ")) 
           (setq ss (ssget '((0 . "Dimension") (-4 . "&=") (70 . 6)))) 
      ) 
    (progn 
      (setq p (trans p 1 0) 
            i (sslength ss) 
      ) 
      (while (setq e (ssname ss (setq i (1- i)))) 
        (setq el  (entget e) 
              pt  (cdr (assoc 13 el)) 
              typ (cdr (assoc 70 el)) 
        ) 
        (if (= (setq len (cdr (assoc 1 el))) "") 
          (setq len (cdr (assoc 42 el))) 
          (setq len (distof len)) 
        ) 
        (if (= 64 (logand 64 typ)) 
          (if (not (equal len (abs (- (car p) (car pt))) 1e-3)) 
            (entmod (append el '((62 . 2)))) ;_黄色 
            (entmod (append el '((62 . 256)))) ;_恢复图层颜色 
          ) 
          (if (not (equal len (abs (- (cadr p) (cadr pt))) 1e-3)) 
            (entmod (append el '((62 . 2)))) 
            (entmod (append el '((62 . 256)))) 
          ) 
        ) 
      ) 
    ) 
  ) 
  (princ) 
)

csharp · 发表于 2014-8-14 10:20:13

你用什么工具标注的一般都有检查功能，除非是自己一个个写上去的，另外，坐标一般都应该有自己的图层

lucas3 · 发表于 2014-8-14 11:13:48

csharp 发表于 2014-8-14 10:20
你用什么工具标注的一般都有检查功能，除非是自己一个个写上去的，另外，坐标一般都应该有自己的图层

怎么检查？　坐标标注同一般标注都属于标注层，坐标标注_dimordinate　以原UCS 0,0 为原点的，移动ucs后，再运行dimordinate标注，它们的原点都不一样了！

csharp · 发表于 2014-8-14 11:48:20

lucas3 发表于 2014-8-14 11:13
怎么检查？　坐标标注同一般标注都属于标注层，坐标标注_dimordinate　以原UCS 0,0 为原点的，移动ucs后 ...

把dwg发上来，用图说话

lucas3 · 发表于 2014-8-14 13:00:32

本帖最后由 lucas3 于 2014-8-14 13:01 编辑

csharp 发表于 2014-8-14 11:48
把dwg发上来，用图说话

如图所示，使用两个不同原点标注出来的，实际画图中，一张图只有一个座标原点，有时不小心或者他人移动过UCS，标注出来就会出问题，所以想
运行程序后，指定一个原点，框选坐标标注，来判断哪些标注不是基于此原点标注出来的，ＤＷＧ在附件中，谢谢！

Free-Lancer · 发表于 2014-8-14 15:12:45

lucas3 发表于 2014-8-14 13:00
如图所示，使用两个不同原点标注出来的，实际画图中，一张图只有一个座标原点，有时不小心或者他人移动过 ...

(defun c:tt (/ p ss)
(if (and (setq p (getpoint "\nBase Point: "))
(setq ss (ssget '((0 . "Dimension") (-4 . "&=") (70 . 6))))
)
(progn
(setq p (trans p 1 0))
(mapcar '(lambda (x / pt len)
(setq pt (xdrx_getpropertyvalue
x
"DefiningPoint"
)
)
(if (= (xdrx_getpropertyvalue x "DimensionText") "")
(setq len (xdrx_getpropertyvalue x "Measurement"))
(setq
len (distof
(xdrx_getpropertyvalue x "DimensionText")
)
)
)
(if (xdrx_getpropertyvalue x "IsUsingXAxis")
(if (not (equal len (abs (- (car p) (car pt))) 1e-3))
(xdrx_entity_setcolor x 2)
)
(if (not (equal len (abs (- (cadr p) (cadr pt))) 1e-3))
(xdrx_entity_setcolor x 2)
)
)
)
(xdrx_pickset->ents ss)
)
)
)
(princ)
)

(defun c:tt (/ p ss) 
  (if (and (setq p (getpoint "\nBase Point: ")) 
           (setq ss (ssget '((0 . "Dimension") (-4 . "&=") (70 . 6)))) 
      ) 
    (progn 
      (setq p (trans p 1 0)) 
      (mapcar '(lambda (x / pt len) 
                 (setq pt (xdrx_getpropertyvalue 
                           x 
                           "DefiningPoint" 
                         ) 
                 ) 
                 (if (= (xdrx_getpropertyvalue x "DimensionText") "") 
                   (setq len (xdrx_getpropertyvalue x "Measurement")) 
                   (setq 
                     len (distof 
                           (xdrx_getpropertyvalue x "DimensionText") 
                         ) 
                   ) 
                 ) 
                 (if (xdrx_getpropertyvalue x "IsUsingXAxis") 
                   (if (not (equal len (abs (- (car p) (car pt))) 1e-3)) 
                     (xdrx_entity_setcolor x 2) 
                   ) 
                   (if (not (equal len (abs (- (cadr p) (cadr pt))) 1e-3)) 
                     (xdrx_entity_setcolor x 2) 
                   ) 
                 ) 
               ) 
              (xdrx_pickset->ents ss) 
      ) 
    ) 
  ) 
  (princ) 
)

lucas3 · 发表于 2014-8-14 15:31:56

Free-Lancer 发表于 2014-8-14 15:12

大师，是这样的效果，可是又要加载API，能不能不用API呀，用您的函数库，好不？

Free-Lancer · 发表于 2014-8-14 16:08:24

lucas3 发表于 2014-8-14 15:31
大师，是这样的效果，可是又要加载API，能不能不用API呀，用您的函数库，好不？

这个不能用 ActiveX 了，对坐标标注类型在你这个应用中实在没有可用的，只能用 Autolisp 的 DXF 组码，10 是标注点(DefiningPoint)，70 运算才可以判断 X 、Y标注类型(IsUsingXAxis)，1 是否手动输入(DimensionText)，42 实际测量值(Measurement)

知道了这些，用 ssname 遍历改写上面的程序即可

64 = 坐标类型。这是一个仅通过整数值 6 使用的位值（位 7）。如果设置此位，坐标为 X 类型；如果不设置此位，坐标为 Y 类型

lucas3 · 发表于 2014-8-14 16:13:39

Free-Lancer 发表于 2014-8-14 16:08
这个不能用 ActiveX 了，对坐标标注类型在你这个应用中实在没有可用的，只能用 Autolisp 的 DXF 组码，1 ...

看起来还挺复杂的呀，{:soso_e109:}{:soso_e109:}{:soso_e109:}

lucas3 · 发表于 2014-8-14 18:21:11

Free-Lancer 发表于 2014-8-14 09:13
很简单啊!

再次感谢Free-Lancer大师，又一次帮助了我！谢谢！{:soso_e183:}

lucas3 · 发表于 2014-8-16 08:51:05

Free-Lancer 发表于 2014-8-14 09:13
很简单啊!

Free-Lancer大师，发现一个BUG啊

如图所示，我使用左下角原点１标注的左边的矩形，　使用右下角原点２标注的右边的矩形
然后使用您的检查程序，基点指定为左下角的原点１，框选标注检测，结果是右边图形的Ｙ坐标
变色，这不对啊，无论使用原点１或原点２，Ｙ坐标都是一样的啊，应改是Ｘ坐标变色才对
大师，您给看一看

csharp · 发表于 2014-8-16 09:56:29

本帖最后由 csharp 于 2014-8-16 10:48 编辑

发现这个标注标不出负坐标
你的右侧图形，在右下角为原点时 X 应为负值，实际标注为正值，这是 CAD 的 BUG

lucas3 · 发表于 2014-8-16 15:53:31

csharp 发表于 2014-8-16 09:56
发现这个标注标不出负坐标
你的右侧图形，在右下角为原点时 X 应为负值，实际标注为正值，这是 CAD 的 ...

是的，这个BUG我知道，如果要正负坐标可以用Free-lancer大师的那个文字替代的方式，现在不考虑这个BUG,就拿我那个图片来讲，应该变色的是Ｘ轴座标，而不是Ｙ轴座标，因为两个座标原点的Ｙ轴在一条线上

Free-Lancer · 发表于 2014-8-16 16:16:33

lucas3 发表于 2014-8-16 15:53
是的，这个BUG我知道，如果要正负坐标可以用Free-lancer大师的那个文字替代的方式，现在不考虑这个BUG,就 ...

有两处搞混了，重新下载

账号		自动登录	找回密码
密码			立即注册

[编程申请] 检查坐标标注的原点

最佳答案

点评

评分

点评

点评

点评

点评

评分

点评

点评

点评

点评

点评

点评