块与块连线程序求助

grs432 · 发表于 2014-11-28 15:56:16

st788796 发表于 2014-11-28 15:12
配合上面程序的统计

统计上，在下边显示上没有问题，怎样加入转到EXCEL表中的功能，如果加入在CAD中列表和EXCEL表中2选1会更好。
论坛已发布了EXCEL的函数，但是我现在的水平还不知道怎样加入。有待于学习。。
目前只能测试st788796老师的程序写好自己的测试结果。。争取以后自己对st788796老师的程序进行对自己有用的优化。。

grs432 · 发表于 2014-11-28 16:06:04

newer 发表于 2014-11-28 15:49
最起码做个漂亮的演示动画贴上来让大家看看。

现在做的动画有点糙，，会在程序最后完美的时候统一做个各个动画，，现在在引出回路字体大小上还要调整一下，，要自己手动改，所以在动画上看不到，自己也是急于测试，，没有注意这方面，也是发完后才发现这个问题。

grs432 · 发表于 2014-11-28 17:05:01

st788796 发表于 2014-11-28 14:42
http://bbs.xdcad.net/thread-677386-1-1.html

更新，将块名记录在文字的扩展记录中

有时候论坛上的程序会出现“错误: ADS 请求错误” 程序不执行，把CAD关了，重新打开再执行命令会好。。这是为什么？？

csharp · 发表于 2014-11-28 17:27:19

grs432 发表于 2014-11-28 15:50
现在测试增加和减少点上，在多段线中间加点和减点没有问题，不足之处是弧度与原来有不同，影响美观。
...

再试试

(defun c:tt (/ _removevertexat _addvertexat e tf p key pr)
(defun _pnt:toline (p p1 p2)
(last (trans (mapcar '- p p1) 0 (mapcar '- p2 p1)))
)
(defun _removevertexat (e p / n bulge p p1 p2 d)
(setq n (fix (xdrx_curve_getparamatpoint e p)))
(cond
((zerop n)
(xdrx_polyline_removevertexat e 0)
)
((= n (1- (xdrx_polyline_numverts e)))
(xdrx_polyline_removevertexat e n)
)
(t
(setq bulge (xdrx_polyline_getbulgeat e n)
p (xdrx_curve_getpointatparam e (+ n 0.5))
p1 (xdrx_polyline_getpointat e (1- n))
p2 (xdrx_polyline_getpointat e (1+ n))
d (distance
p
(xdrx_line_midp
(xdrx_polyline_getpointat e n)
p2
)
)
)
(xdrx_polyline_removevertexat e n)
(xdrx_polyline_setbulgeat
e
(1- n)
(if (minusp bulge)
(- (/ (* 2.0 d) (distance p1 p2)))
(/ (* 2.0 d) (distance p1 p2))
)
)
)
)
)
(defun _addvertexat (e p / n p1 p2 pm d bulge p0)
(setq p0 (xdrx_curve_getclosestpoint e p)
n (fix (xdrx_curve_getparamatpoint e p0))
)
(cond
((zerop n)
(setq p1 (xdrx_curve_getstartpoint e)
p2 (xdrx_curve_getpointatparam e 1.0)
pm (xdrx_curve_getpointatparam e 0.5)
d (distance pm (xdrx_line_midp p1 p2))
bulge (xdrx_polyline_getbulgeat e 0)
)
(if (minusp (_pnt:toline p p1 p2))
(progn
(xdrx_polyline_setpointat e 0 p)
(xdrx_polyline_addvertexat e 1 p1)
(xdrx_polyline_setbulgeat
e
0
(if (minusp bulge)
(- (/ (* 2.0 d) (distance p p1)))
(/ (* 2.0 d) (distance p p1))
)
)
(xdrx_polyline_setbulgeat
e
1
(if (minusp bulge)
(- (/ (* 2.0 d) (distance p1 p2)))
(/ (* 2.0 d) (distance p1 p2))
)
)
)
(progn
(xdrx_polyline_addvertexat e 1 p)
(xdrx_polyline_setbulgeat
e
0
(if (minusp bulge)
(- (/ (* 2.0 d) (distance p p1)))
(/ (* 2.0 d) (distance p p1))
)
)
(xdrx_polyline_setbulgeat
e
1
(if (minusp bulge)
(- (/ (* 2.0 d) (distance p p2)))
(/ (* 2.0 d) (distance p p2))
)
)
)
)
)
((= n (- (xdrx_polyline_numverts e) 2))
(setq p1 (xdrx_curve_getpointatparam e n)
p2 (xdrx_curve_getendpoint e)
pm (xdrx_curve_getpointatparam e (+ n 0.5))
d (distance pm (xdrx_line_midp p1 p2))
bulge (xdrx_polyline_getbulgeat e n)
)
(if (>= (_pnt:toline p p1 p2) (distance p1 p2))
(progn
(xdrx_polyline_setpointat e (1+ n) p)
(xdrx_polyline_addvertexat e (1+ n) p2)
(xdrx_polyline_setbulgeat
e
n
(if (minusp bulge)
(- (/ (* 2.0 d) (distance p1 p2)))
(/ (* 2.0 d) (distance p1 p2))
)
)
(xdrx_polyline_setbulgeat
e
(1+ n)
(if (minusp bulge)
(- (/ (* 2.0 d) (distance p2 p)))
(/ (* 2.0 d) (distance p2 p))
)
)
)
(progn
(xdrx_polyline_addvertexat e (1+ n) p)
(xdrx_polyline_setbulgeat
e
n
(if (minusp bulge)
(- (/ (* 2.0 d) (distance p1 p)))
(/ (* 2.0 d) (distance p1 p))
)
)
(xdrx_polyline_setbulgeat
e
n
(if (minusp bulge)
(- (/ (* 2.0 d) (distance p p2)))
(/ (* 2.0 d) (distance p p2))
)
)
)
)
)
((= n (1- (xdrx_polyline_numverts e)))
(setq p1 (xdrx_curve_getpointatparam e (1- n))
p2 (xdrx_curve_getendpoint e)
pm (xdrx_curve_getpointatparam e (- n 0.5))
d (distance pm (xdrx_line_midp p1 p2))
bulge (xdrx_polyline_getbulgeat e (1- n))
)
(if (>= (_pnt:toline p p1 p2) (distance p1 p2))
(progn
(xdrx_polyline_setpointat e n p)
(xdrx_polyline_addvertexat e n p2)
(xdrx_polyline_setbulgeat
e
(1- n)
(if (minusp bulge)
(- (/ (* 2.0 d) (distance p1 p2)))
(/ (* 2.0 d) (distance p1 p2))
)
)
(xdrx_polyline_setbulgeat
e
n
(if (minusp bulge)
(- (/ (* 2.0 d) (distance p2 p)))
(/ (* 2.0 d) (distance p2 p))
)
)
)
)
)
(t
(setq p1 (xdrx_polyline_getpointat e n)
p2 (xdrx_polyline_getpointat e (1+ n))
pm (xdrx_curve_getpointatparam e (+ n 0.5))
d (distance pm (xdrx_line_midp p1 p2))
bulge (xdrx_polyline_getbulgeat e n)
)
(xdrx_polyline_addvertexat e (1+ n) p)
(xdrx_polyline_setbulgeat
e
n
(if (minusp bulge)
(- (/ (* 2.0 d) (distance p p1)))
(/ (* 2.0 d) (distance p p1))
)
)
(xdrx_polyline_setbulgeat
e
(1+ n)
(if (minusp bulge)
(- (/ (* 2.0 d) (distance p p2)))
(/ (* 2.0 d) (distance p p2))
)
)
)
)
)
;;main program
(if (setq e (car (xdrx_entsel "\n选择回路线: " '((0 . "lwpolyline")))))
(progn
(setq tf t
key "D"
pr "\r"
)
(while tf
(initget 128 "A D")
(setq p
(getpoint (strcat pr "拾取点[删点(D)/增点(A)]<" key ">: "))
)
(cond
((and (not (null p)) (listp p))
(if (= key "D")
(_removevertexat e p)
(_addvertexat e p)
)
(setq pr "\r")
)
((= p "A") (setq key "A") (setq pr "\n"))
((= p "D") (setq key "D") (setq pr "\n"))
(t (setq tf nil))
)
)
)
)
(princ)
)

(defun c:tt (/ _removevertexat _addvertexat e tf p key pr) 
  (defun _pnt:toline (p p1 p2) 
    (last (trans (mapcar '- p p1) 0 (mapcar '- p2 p1))) 
  ) 
  (defun _removevertexat (e p / n bulge p p1 p2 d) 
    (setq n (fix (xdrx_curve_getparamatpoint e p))) 
    (cond 
      ((zerop n) 
       (xdrx_polyline_removevertexat e 0) 
      ) 
      ((= n (1- (xdrx_polyline_numverts e))) 
       (xdrx_polyline_removevertexat e n) 
      ) 
      (t 
       (setq bulge (xdrx_polyline_getbulgeat e n) 
             p           (xdrx_curve_getpointatparam e (+ n 0.5)) 
             p1           (xdrx_polyline_getpointat e (1- n)) 
             p2           (xdrx_polyline_getpointat e (1+ n)) 
             d           (distance 
                     p 
                     (xdrx_line_midp 
                       (xdrx_polyline_getpointat e n) 
                       p2 
                     ) 
                   ) 
       ) 
       (xdrx_polyline_removevertexat e n) 
       (xdrx_polyline_setbulgeat 
         e 
         (1- n) 
         (if (minusp bulge) 
           (- (/ (* 2.0 d) (distance p1 p2))) 
           (/ (* 2.0 d) (distance p1 p2)) 
         ) 
       ) 
      ) 
    ) 
  ) 
  (defun _addvertexat (e p / n p1 p2 pm d bulge p0) 
    (setq p0 (xdrx_curve_getclosestpoint e p) 
          n  (fix (xdrx_curve_getparamatpoint e p0)) 
    ) 
    (cond 
      ((zerop n) 
       (setq p1           (xdrx_curve_getstartpoint e) 
             p2           (xdrx_curve_getpointatparam e 1.0) 
             pm           (xdrx_curve_getpointatparam e 0.5) 
             d           (distance pm (xdrx_line_midp p1 p2)) 
             bulge (xdrx_polyline_getbulgeat e 0) 
       ) 
       (if (minusp (_pnt:toline p p1 p2)) 
         (progn 
           (xdrx_polyline_setpointat e 0 p) 
           (xdrx_polyline_addvertexat e 1 p1) 
           (xdrx_polyline_setbulgeat 
             e 
             0 
             (if (minusp bulge) 
               (- (/ (* 2.0 d) (distance p p1))) 
               (/ (* 2.0 d) (distance p p1)) 
             ) 
           ) 
           (xdrx_polyline_setbulgeat 
             e 
             1 
             (if (minusp bulge) 
               (- (/ (* 2.0 d) (distance p1 p2))) 
               (/ (* 2.0 d) (distance p1 p2)) 
             ) 
           ) 
         ) 
         (progn 
           (xdrx_polyline_addvertexat e 1 p) 
           (xdrx_polyline_setbulgeat 
             e 
             0 
             (if (minusp bulge) 
               (- (/ (* 2.0 d) (distance p p1))) 
               (/ (* 2.0 d) (distance p p1)) 
             ) 
           ) 
           (xdrx_polyline_setbulgeat 
             e 
             1 
             (if (minusp bulge) 
               (- (/ (* 2.0 d) (distance p p2))) 
               (/ (* 2.0 d) (distance p p2)) 
             ) 
           ) 
         ) 
       ) 
      ) 
      ((= n (- (xdrx_polyline_numverts e) 2)) 
       (setq p1           (xdrx_curve_getpointatparam e n) 
             p2           (xdrx_curve_getendpoint e) 
             pm           (xdrx_curve_getpointatparam e (+ n 0.5)) 
             d           (distance pm (xdrx_line_midp p1 p2)) 
             bulge (xdrx_polyline_getbulgeat e n) 
       ) 
       (if (>= (_pnt:toline p p1 p2) (distance p1 p2)) 
         (progn 
           (xdrx_polyline_setpointat e (1+ n) p) 
           (xdrx_polyline_addvertexat e (1+ n) p2) 
           (xdrx_polyline_setbulgeat 
             e 
             n 
             (if (minusp bulge) 
               (- (/ (* 2.0 d) (distance p1 p2))) 
               (/ (* 2.0 d) (distance p1 p2)) 
             ) 
           ) 
           (xdrx_polyline_setbulgeat 
             e 
             (1+ n) 
             (if (minusp bulge) 
               (- (/ (* 2.0 d) (distance p2 p))) 
               (/ (* 2.0 d) (distance p2 p)) 
             ) 
           ) 
         ) 
         (progn 
           (xdrx_polyline_addvertexat e (1+ n) p) 
           (xdrx_polyline_setbulgeat 
             e 
             n 
             (if (minusp bulge) 
               (- (/ (* 2.0 d) (distance p1 p))) 
               (/ (* 2.0 d) (distance p1 p)) 
             ) 
           ) 
           (xdrx_polyline_setbulgeat 
             e 
             n 
             (if (minusp bulge) 
               (- (/ (* 2.0 d) (distance p p2))) 
               (/ (* 2.0 d) (distance p p2)) 
             ) 
           ) 
         ) 
       ) 
      ) 
      ((= n (1- (xdrx_polyline_numverts e))) 
       (setq p1           (xdrx_curve_getpointatparam e (1- n)) 
             p2           (xdrx_curve_getendpoint e) 
             pm           (xdrx_curve_getpointatparam e (- n 0.5)) 
             d           (distance pm (xdrx_line_midp p1 p2)) 
             bulge (xdrx_polyline_getbulgeat e (1- n)) 
       ) 
       (if (>= (_pnt:toline p p1 p2) (distance p1 p2)) 
         (progn 
           (xdrx_polyline_setpointat e n p) 
           (xdrx_polyline_addvertexat e n p2) 
           (xdrx_polyline_setbulgeat 
             e 
             (1- n) 
             (if (minusp bulge) 
               (- (/ (* 2.0 d) (distance p1 p2))) 
               (/ (* 2.0 d) (distance p1 p2)) 
             ) 
           ) 
           (xdrx_polyline_setbulgeat 
             e 
             n 
             (if (minusp bulge) 
               (- (/ (* 2.0 d) (distance p2 p))) 
               (/ (* 2.0 d) (distance p2 p)) 
             ) 
           ) 
         ) 
       ) 
      ) 
      (t 
       (setq p1           (xdrx_polyline_getpointat e n) 
             p2           (xdrx_polyline_getpointat e (1+ n)) 
             pm           (xdrx_curve_getpointatparam e (+ n 0.5)) 
             d           (distance pm (xdrx_line_midp p1 p2)) 
             bulge (xdrx_polyline_getbulgeat e n) 
       ) 
       (xdrx_polyline_addvertexat e (1+ n) p) 
       (xdrx_polyline_setbulgeat 
         e 
         n 
         (if (minusp bulge) 
           (- (/ (* 2.0 d) (distance p p1))) 
           (/ (* 2.0 d) (distance p p1)) 
         ) 
       ) 
       (xdrx_polyline_setbulgeat 
         e 
         (1+ n) 
         (if (minusp bulge) 
           (- (/ (* 2.0 d) (distance p p2))) 
           (/ (* 2.0 d) (distance p p2)) 
         ) 
       ) 
      ) 
    ) 
  ) 
  ;;main program 
  (if (setq e (car (xdrx_entsel "\n选择回路线: " '((0 . "lwpolyline"))))) 
    (progn 
      (setq tf        t 
            key        "D" 
            pr        "\r" 
      ) 
      (while tf 
        (initget 128 "A D") 
        (setq p 
               (getpoint (strcat pr "拾取点[删点(D)/增点(A)]<" key ">: ")) 
        ) 
        (cond 
          ((and (not (null p)) (listp p)) 
           (if (= key "D") 
             (_removevertexat e p) 
             (_addvertexat e p) 
           ) 
           (setq pr "\r") 
          ) 
          ((= p "A") (setq key "A") (setq pr "\n")) 
          ((= p "D") (setq key "D") (setq pr "\n")) 
          (t (setq tf nil)) 
        ) 
      ) 
    ) 
  ) 
  (princ) 
)

grs432 · 发表于 2014-11-28 17:52:44

csharp 发表于 2014-11-28 17:27
再试试

试了，好像有问题。。没有解决！！

st788796 · 发表于 2014-11-28 18:03:21

本帖最后由 st788796 于 2014-11-28 20:37 编辑

grs432 发表于 2014-11-28 17:52
试了，好像有问题。。没有解决！！

前面写的太乱了，简化一下

;;对回路连线增删顶点
(defun c:XDTB_CircuitNode (/ _removevertexat
_addvertexat _pnt:toline
e tf p
key pr
)
(defun _pnt:toline (p p1 p2)
(last (trans (mapcar '- p p1) 0 (mapcar '- p2 p1)))
)
(defun _removevertexat (e p / n bulge p p1 p2 d)
(setq n (fix (xdrx_curve_getparamatpoint e p)))
(if (or (zerop n) (= n (1- (xdrx_polyline_numverts e))))
(xdrx_polyline_removevertexat e n)
(progn
(setq bulge (xdrx_polyline_getbulgeat e n)
p (xdrx_curve_getpointatparam e (+ n 0.5))
p1 (xdrx_polyline_getpointat e (1- n))
p2 (xdrx_polyline_getpointat e (1+ n))
d (distance
p
(xdrx_line_midp
(xdrx_polyline_getpointat e n)
p2
)
)
)
(xdrx_polyline_removevertexat e n)
(xdrx_polyline_setbulgeat
e
(1- n)
(if (minusp bulge)
(- (/ (* 2.0 d) (distance p1 p2)))
(/ (* 2.0 d) (distance p1 p2))
)
)
)
)
)
(defun _addvertexat (e p / n p1 p2 pm d bulge p0 tf1 tmp tf)
(setq p0 (xdrx_curve_getclosestpoint e p)
n (fix (xdrx_curve_getparamatpoint e p0))
)
(if (setq tf1 (= n (1- (xdrx_polyline_numverts e))))
(setq p1 (xdrx_curve_getpointatparam e (1- n))
p2 (xdrx_curve_getpointatparam e n)
pm (xdrx_curve_getpointatparam e (- n 0.5))
bulge (xdrx_polyline_getbulgeat e (1- n))
)
(setq p1 (xdrx_curve_getpointatparam e n)
p2 (xdrx_curve_getpointatparam e (1+ n))
pm (xdrx_curve_Getpointatparam e (+ n 0.5))
bulge (xdrx_polyline_getbulgeat e n)
)
)
(setq d (distance pm (xdrx_line_midp p1 p2))
tf (_pnt:toline p p1 p2)
)
(cond
((and (zerop n) (minusp tf))
(xdrx_polyline_setpointat e 0 p)
(setq tmp p1
p1 p
p tmp
)
)
((and tf1 (>= (_pnt:toline p p1 p2) (distance p1 p2)))
(xdrx_polyline_setpointat e n p)
(setq tmp p2
p2 p
p tmp
n (1- n)
)
)
(t)
)
(xdrx_polyline_addvertexat e (1+ n) p)
(xdrx_polyline_setbulgeat
e
n
(if (minusp bulge)
(- (/ (* 2.0 d) (distance p p1)))
(/ (* 2.0 d) (distance p p1))
)
)
(xdrx_polyline_setbulgeat
e
(1+ n)
(if (minusp bulge)
(- (/ (* 2.0 d) (distance p p2)))
(/ (* 2.0 d) (distance p p2))
)
)
)
;;main program
(if (setq e (car (xdrx_entsel "\n选择回路线: " '((0 . "lwpolyline")))))
(progn
(setq tf t
key "D"
pr "\r"
)
(while tf
(initget 128 "A D")
(setq p
(getpoint (strcat pr "拾取点[删点(D)/增点(A)]<" key ">: "))
)
(cond
((and (not (null p)) (listp p))
(if (= key "D")
(_removevertexat e p)
(_addvertexat e p)
)
(setq pr "\r")
)
((= p "A") (setq key "A") (setq pr "\n"))
((= p "D") (setq key "D") (setq pr "\n"))
(t (setq tf nil))
)
)
)
)
(princ)
)

;;对回路连线增删顶点 
(defun c:XDTB_CircuitNode (/               _removevertexat 
                           _addvertexat                   _pnt:toline 
                           e               tf           p 
                           key               pr 
                          ) 
  (defun _pnt:toline (p p1 p2) 
    (last (trans (mapcar '- p p1) 0 (mapcar '- p2 p1))) 
  ) 
  (defun _removevertexat (e p / n bulge p p1 p2 d) 
    (setq n (fix (xdrx_curve_getparamatpoint e p))) 
    (if        (or (zerop n) (= n (1- (xdrx_polyline_numverts e)))) 
      (xdrx_polyline_removevertexat e n) 
      (progn 
        (setq bulge (xdrx_polyline_getbulgeat e n) 
              p            (xdrx_curve_getpointatparam e (+ n 0.5)) 
              p1    (xdrx_polyline_getpointat e (1- n)) 
              p2    (xdrx_polyline_getpointat e (1+ n)) 
              d            (distance 
                      p 
                      (xdrx_line_midp 
                        (xdrx_polyline_getpointat e n) 
                        p2 
                      ) 
                    ) 
        ) 
        (xdrx_polyline_removevertexat e n) 
        (xdrx_polyline_setbulgeat 
          e 
          (1- n) 
          (if (minusp bulge) 
            (- (/ (* 2.0 d) (distance p1 p2))) 
            (/ (* 2.0 d) (distance p1 p2)) 
          ) 
        ) 
      ) 
    ) 
  ) 
  (defun _addvertexat (e p / n p1 p2 pm d bulge p0 tf1 tmp tf) 
    (setq p0 (xdrx_curve_getclosestpoint e p) 
          n  (fix (xdrx_curve_getparamatpoint e p0)) 
    ) 
    (if        (setq tf1 (= n (1- (xdrx_polyline_numverts e)))) 
      (setq p1          (xdrx_curve_getpointatparam e (1- n)) 
            p2          (xdrx_curve_getpointatparam e n) 
            pm          (xdrx_curve_getpointatparam e (- n 0.5)) 
            bulge (xdrx_polyline_getbulgeat e (1- n)) 
      ) 
      (setq p1          (xdrx_curve_getpointatparam e n) 
            p2          (xdrx_curve_getpointatparam e (1+ n)) 
            pm          (xdrx_curve_Getpointatparam e (+ n 0.5)) 
            bulge (xdrx_polyline_getbulgeat e n) 
      ) 
    ) 
    (setq d  (distance pm (xdrx_line_midp p1 p2)) 
          tf (_pnt:toline p p1 p2) 
    ) 
    (cond 
      ((and (zerop n) (minusp tf)) 
       (xdrx_polyline_setpointat e 0 p) 
       (setq tmp p1 
             p1         p 
             p         tmp 
       ) 
      ) 
      ((and tf1 (>= (_pnt:toline p p1 p2) (distance p1 p2))) 
       (xdrx_polyline_setpointat e n p) 
       (setq tmp p2 
             p2         p 
             p         tmp 
             n         (1- n) 
       ) 
      ) 
      (t) 
    ) 
    (xdrx_polyline_addvertexat e (1+ n) p) 
    (xdrx_polyline_setbulgeat 
      e 
      n 
      (if (minusp bulge) 
        (- (/ (* 2.0 d) (distance p p1))) 
        (/ (* 2.0 d) (distance p p1)) 
      ) 
    ) 
    (xdrx_polyline_setbulgeat 
      e 
      (1+ n) 
      (if (minusp bulge) 
        (- (/ (* 2.0 d) (distance p p2))) 
        (/ (* 2.0 d) (distance p p2)) 
      ) 
    ) 
  ) 
  ;;main program 
  (if (setq e (car (xdrx_entsel "\n选择回路线: " '((0 . "lwpolyline"))))) 
    (progn 
      (setq tf        t 
            key        "D" 
            pr        "\r" 
      ) 
      (while tf 
        (initget 128 "A D") 
        (setq p 
               (getpoint (strcat pr "拾取点[删点(D)/增点(A)]<" key ">: ")) 
        ) 
        (cond 
          ((and (not (null p)) (listp p)) 
           (if (= key "D") 
             (_removevertexat e p) 
             (_addvertexat e p) 
           ) 
           (setq pr "\r") 
          ) 
          ((= p "A") (setq key "A") (setq pr "\n")) 
          ((= p "D") (setq key "D") (setq pr "\n")) 
          (t (setq tf nil)) 
        ) 
      ) 
    ) 
  ) 
  (princ) 
)

st788796 · 发表于 2014-11-28 20:38:45

;;由现有线生成用于统计的回路
(defun c:XDTB_CreateCircuit (/ pl txt blk)
(if
(and (setq pl
(car (xdrx_entsel "\n拾取回路Pline: " '((0 . "LWPOLYLINE")))
)
)
(setq txt (car (xdrx_entsel "\n拾取回路编号: " '((0 . "*TEXT")))))
(setq blk (car (xdrx_entsel "\n拾取图块: " '((0 . "INSERT")))))
)
(progn
(xdrx_group_make "*" pl txt)
(xdrx_xdata_setbyproperty
txt
"XDCircuit"
"String"
(car (xdrx_getpropertyvalue blk "BlockTableRecord"))
)
(vlax-ldata-put
txt
"Circuit"
(xdrx_getpropertyvalue pl "Handle")
)
)
)
(princ)
)

st788796 · 发表于 2014-11-28 20:40:16

统计生成表格及生成 xls 文件

;;统计回路
(defun c:XDTB_CalCircuit (/ ss nl)
(if (setq ss (ssget '((0 . "text") (-3 ("XDCircuit")))))
(progn
(setq
nl (mapcar
'(lambda (x / pl)
(if (setq pl (handent (vlax-ldata-get x "Circuit")))
(list (xdrx_getpropertyvalue x "textstring")
(xdrx_xdata_get x "XDCircuit")
(itoa (xdrx_getpropertyvalue pl "numVerts"))
)
)
)
(xdrx_pickset->ents ss)
)
nl (cons '("回路编号" "名称" "数量")
(vl-sort nl '(lambda (x1 x2) (< (car x1) (car x2))))
)
)
(if (setq p (getpoint "\n插入点<回车显示>: "))
(xd::table:make nl p 8. 3.)
(foreach x nl
(princ "\n")
(princ x)
)
)
(xd::excel:createToFile
(strcat (getvar "dwgprefix")
(vl-filename-base (getvar "dwgname"))
".xls"
)
nl
) ;_写出 excel 文件
(xdrx_system_shellexecute
(strcat (getvar "dwgprefix")
(vl-filename-base (getvar "dwgname"))
".xls"
)
)
)
)
(princ)
)

;;统计回路 
(defun c:XDTB_CalCircuit (/ ss nl) 
  (if (setq ss (ssget '((0 . "text") (-3 ("XDCircuit"))))) 
    (progn 
      (setq 
        nl (mapcar 
             '(lambda (x / pl) 
                (if (setq pl (handent (vlax-ldata-get x "Circuit"))) 
                  (list        (xdrx_getpropertyvalue x "textstring") 
                        (xdrx_xdata_get x "XDCircuit") 
                        (itoa (xdrx_getpropertyvalue pl "numVerts")) 
                  ) 
                ) 
              ) 
             (xdrx_pickset->ents ss) 
           ) 
        nl (cons '("回路编号" "名称" "数量") 
                 (vl-sort nl '(lambda (x1 x2) (< (car x1) (car x2)))) 
           ) 
      ) 
      (if (setq p (getpoint "\n插入点<回车显示>: ")) 
        (xd::table:make nl p 8. 3.) 
        (foreach x nl 
          (princ "\n") 
          (princ x) 
        ) 
      ) 
      (xd::excel:createToFile 
        (strcat        (getvar "dwgprefix") 
                (vl-filename-base (getvar "dwgname")) 
                ".xls" 
        ) 
        nl 
      ) ;_写出 excel 文件 
      (xdrx_system_shellexecute 
        (strcat        (getvar "dwgprefix") 
                (vl-filename-base (getvar "dwgname")) 
                ".xls" 
        ) 
      ) 
    ) 
  ) 
  (princ) 
)

st788796 · 发表于 2014-11-28 20:45:26

http://bbs.xdcad.net/thread-677386-1-1.html

绘制功能再次更新

grs432 · 发表于 2014-11-29 00:33:48

st788796 发表于 2014-11-28 20:45
http://bbs.xdcad.net/thread-677386-1-1.html

绘制功能再次更新

现在几乎是完美了，如果加上能自定义预置字典内容，记忆字典个别内容可删除，回路字体大小可以设置的话，可以说是没有什么挑剔了，我会准备个完整的图纸在此贴将动画整理发布一下。。在此感谢st788796老师的耐心梳理我对程序的调试意见，并给出了正确的程序执行方式，真的在工作上方便了好多呀！完成今天的成果，我真是无法用语言来表达对st788796老师的感激之情，再次感谢呀！！{:soso_e183:}{:soso_e183:}
后期我个人会自己加强自己对lisp的学习，希望能自己读懂st788796老师所写的内容！！{:soso_e112:}{:soso_e113:}{:soso_e129:}

st788796 · 发表于 2014-11-29 08:36:00

grs432 发表于 2014-11-29 00:33
现在几乎是完美了，如果加上能自定义预置字典内容，记忆字典个别内容可删除，回路字体大小可以设置的话， ...

可以增加文字高度、图层、是否编组及词典附加内容四个选项，不过附加内容不知道还有没有其他用途，是否合统计有关

grs432 · 发表于 2014-11-29 11:30:14

st788796 发表于 2014-11-29 08:36
可以增加文字高度、图层、是否编组及词典附加内容四个选项，不过附加内容不知道还有没有其他用途，是否合 ...

st788796老师您好，看到您给做的UI页面真的很高兴，很漂亮，目前可以说UI的界面已经基本满足了我自己的工作，如果界面再多的UI设置选项，我想可能会浪费您的时间，但是我还是做了自己工作方面的主要构成UI，这个只是参考。很担心太浪费您的时间，所以现在只做您写的UI就可以。 QQ截图20141129111336.jpg

st788796 · 发表于 2014-11-29 12:22:27

grs432 发表于 2014-11-29 11:30
st788796老师您好，看到您给做的UI页面真的很高兴，很漂亮，目前可以说UI的界面已经基本满足了我自己的工 ...

词典是非图形实体，没有图层
不懂你们专业，就UI内容而言，首先区分出哪些是固定的，可以用外部数据库，哪些是根据连接计算的，哪些需要写图上，哪些不写但需要记录到文字以便后续统计

下面的那些选项可以用Grid控件

grs432 · 发表于 2014-11-29 13:11:28

st788796 发表于 2014-11-29 12:22
词典是非图形实体，没有图层
不懂你们专业，就UI内容而言，首先区分出哪些是固定的，可以用外部数据库， ...

OK,明白了。我整理出来。

grs432 · 发表于 2014-11-29 22:20:07

st788796 发表于 2014-11-29 12:22
词典是非图形实体，没有图层
不懂你们专业，就UI内容而言，首先区分出哪些是固定的，可以用外部数据库， ...

账号		自动登录	找回密码
密码			立即注册

[已解决] 块与块连线程序求助

点评

点评

点评

点评