像这样改变当前标注文字高度

Free-Lancer · 发表于 2014-11-20 00:26:36

lucas3 发表于 2014-11-19 23:53
我们都是图框往图上放，要缩放图框的，如果缩放图形和尺寸，可能会出现一些可怕的问题！， ...

不是不可解决，既然用 AutoCAD 还是养成好的画图习惯

(defun c:tt (/ _string:decimal _changescale
_rectang:scale scl height
str ds
)
(defun _string:decimal (val / str)
(setvar "dimzin" 0)
(setq str (rtos val 2 24)
str (vl-string-right-trim "0" str)
str (vl-string-right-trim "." str)
)
)
(defun _changescale (h str)
(vlax-for obj (fy:cset)
(if (wcmatch (vla-get-objectname obj) "*Text")
(vlax-put obj 'height h)
(vlax-put obj 'stylename str)
)
)
)
(defun _rectang:scale (/ p1 p2 str lst v scl kw)
(if
(and (setq p1 (getpoint "\n基点: "))
(setq p2 (getcorner p1 "\n对角点: "))
(progn
(initget "1 2 3 4")
(setq kw (getkword "打印图框大小[A1(1)/A2(2)/A3(3)/A4(4)]: "))
)
(setq lst (assoc kw
'(("1" 841 594)
("2" 594 420)
("3" 420 297)
("4" 297 210)
)
)
)
)
(progn
(setq v (mapcar 'abs (mapcar '- p2 p1))
scl (mapcar '/ v (cdr lst))
)
(list (apply 'max scl) p1 p2)
)
)
)
(fy:begin)
(if (and (setq scl (_rectang:scale))
(progn
(princ "\nPlot Scale = ")
(princ (car scl))
t
)
(setq height (getdist "\n文字高度: "))
(ssget "_C"
(cadr scl)
(caddr scl)
'((0 . "dimension,text"))
)
)
(progn
(setq
str (vl-string-translate "." "-" (_string:decimal (car scl)))
)
(if (not (tblsearch "dimstyle" (strcat "FY-" str)))
(progn
(setq ds (vla-add (fy:acdimstyles) (strcat "FY-" str)))
(mapcar '(lambda (x)
(apply 'setvar x)
)
(cons (list "dimtxt" height)
(cons (list "dimscale" (car scl))
'(("dimdli" 1.0)
("dimexe" 1.5)
("dimexo" 1.0)
("dimasz" 1.5)
("dimtad" 1)
("dimtix" 1)
("dimtofl" 1)
("dimgap" 1.0)
("dimtih" 0)
("dimdsep" ".")
("dimlunit" 2) ;_单位
("dimdec" 2) ;_精度
)
)
)
)
(vla-copyfrom ds (fy:acdoc))
(vla-put-activedimstyle (fy:acdoc) ds)
)
)
(_changescale (* height (car scl)) (strcat "FY-" str))
)
)
(princ)
)

(defun c:tt (/                   _string:decimal               _changescale 
             _rectang:scale                 scl               height 
             str           ds 
            ) 
  (defun _string:decimal (val / str) 
    (setvar "dimzin" 0) 
    (setq str (rtos val 2 24) 
          str (vl-string-right-trim "0" str) 
          str (vl-string-right-trim "." str) 
    ) 
  ) 
  (defun _changescale (h str) 
    (vlax-for obj (fy:cset) 
      (if (wcmatch (vla-get-objectname obj) "*Text") 
        (vlax-put obj 'height h) 
        (vlax-put obj 'stylename str) 
      ) 
    ) 
  ) 
  (defun _rectang:scale        (/ p1 p2 str lst v scl kw) 
    (if 
      (and (setq p1 (getpoint "\n基  点: ")) 
           (setq p2 (getcorner p1 "\n对角点: ")) 
           (progn 
             (initget "1 2 3 4") 
             (setq kw (getkword "打印图框大小[A1(1)/A2(2)/A3(3)/A4(4)]: ")) 
           ) 
           (setq lst (assoc kw 
                            '(("1" 841 594) 
                              ("2" 594 420) 
                              ("3" 420 297) 
                              ("4" 297 210) 
                             ) 
                     ) 
           ) 
      ) 
       (progn 
         (setq v   (mapcar 'abs (mapcar '- p2 p1)) 
               scl (mapcar '/ v (cdr lst)) 
         ) 
         (list (apply 'max scl) p1 p2) 
       ) 
    ) 
  ) 
  (fy:begin) 
  (if (and (setq scl (_rectang:scale)) 
           (progn 
             (princ "\nPlot Scale = ") 
             (princ (car scl)) 
             t 
           ) 
           (setq height (getdist "\n文字高度: ")) 
           (ssget "_C" 
                  (cadr scl) 
                  (caddr scl) 
                  '((0 . "dimension,text")) 
           ) 
      ) 
    (progn 
      (setq 
        str (vl-string-translate "." "-" (_string:decimal (car scl))) 
      ) 
      (if (not (tblsearch "dimstyle" (strcat "FY-" str))) 
        (progn 
          (setq ds (vla-add (fy:acdimstyles) (strcat "FY-" str))) 
          (mapcar '(lambda (x) 
                     (apply 'setvar x) 
                   ) 
                  (cons        (list "dimtxt" height) 
                        (cons (list "dimscale" (car scl)) 
                              '(("dimdli" 1.0) 
                                ("dimexe" 1.5) 
                                ("dimexo" 1.0) 
                                ("dimasz" 1.5) 
                                ("dimtad" 1) 
                                ("dimtix" 1) 
                                ("dimtofl" 1) 
                                ("dimgap" 1.0) 
                                ("dimtih" 0) 
                                ("dimdsep" ".") 
                                ("dimlunit" 2) ;_单位 
                                ("dimdec" 2) ;_精度 
                               ) 
                        ) 
                  ) 
          ) 
          (vla-copyfrom ds (fy:acdoc)) 
          (vla-put-activedimstyle (fy:acdoc) ds) 
        ) 
      ) 
      (_changescale (* height (car scl)) (strcat "FY-" str)) 
    ) 
  ) 
  (princ) 
)

lucas3 · 发表于 2014-11-20 00:49:47

本帖最后由 lucas3 于 2014-11-20 11:09 编辑

Free-Lancer 发表于 2014-11-20 00:26
不是不可解决，既然用 AutoCAD 还是养成好的画图习惯

大师说的极是，我每天上论坛也是想找到标准的画图方式，这于这个设置打印文字字高问题也是参考了好多，琢磨了又琢磨
最后还是觉得燕秀这个计算打印区域标注文字高度的蛮实用的

感谢大师无私的帮助！！！
刚测试了下，方法是合我的意思了，但好像Plot Scale 计算有点问题，比如一个A4的横图框，一个A4的竖图框，面积都是一样，但计算出来的Plot Scale 不一样，横图框计算的Plot Scale ＝1.0 , A4的竖图框计算出来的是Plot Scale = 1.41429。

Free-Lancer · 发表于 2014-11-20 08:52:10

lucas3 发表于 2014-11-20 00:49
大师说的极是，我每天上论坛也是想找到标准的画图方式，这于这个设置打印文字字高问题也是参考了好多，琢 ...

自动按最大值计算比例，增加手动设置比例机会

(defun c:tt (/ _string:decimal _changescale
_rectang:scale scl height
str ds nscl kw
)
(defun _string:decimal (val / str)
(setvar "dimzin" 0)
(setq str (rtos val 2 24)
str (vl-string-right-trim "0" str)
str (vl-string-right-trim "." str)
)
)
(defun _changescale (h str)
(vlax-for obj (fy:cset)
(if (wcmatch (vla-get-objectname obj) "*Text")
(vlax-put obj 'height h)
(vlax-put obj 'stylename str)
)
)
)
(defun _rectang:scale (/ p1 p2 str lst v scl kw)
(if
(and
(setq p1 (getpoint "\n第一点: "))
(setq p2 (getcorner p1 "\n对角点: "))
(progn (initget "1 2 3 4")
(setq kw (getkword
"\n打印图框大小[A0(0)/A1(1)/A2(2)/A3(3)/A4(4)]: "
)
)
)
(setq lst (assoc kw
'(("0" 1089 841)
("1" 841 594)
("2" 594 420)
("3" 420 297)
("4" 297 210)
)
)
)
)
(progn (setq v (apply 'max (mapcar 'abs (mapcar '- p2 p1)))
scl (/ v (apply 'max (cdr lst)))
)
(list scl p1 p2)
)
)
)
(fy:begin)
(if (and (setq scl (_rectang:scale))
(progn (princ "\nPlot Scale = ")
(princ (car scl))
(initget 128 "Y N")
(setq kw (getkword "\n是否接受[是(Y)/否(N)]<Y>: "))
(if (or (= kw "Y") (= kw ""))
t
(if (setq nscl (getreal "\n输入新比例: "))
(setq scl (cons nscl (cdr scl)))
)
)
)
(setq height (getdist "\n文字高度: "))
(ssget "_C"
(cadr scl)
(caddr scl)
'((0 . "dimension,text"))
)
)
(progn
(setq
str (vl-string-translate "." "-" (_string:decimal (car scl)))
)
(if (not (tblsearch "dimstyle" (strcat "FY-" str)))
(progn (setq ds (vla-add (fy:acdimstyles) (strcat "FY-" str)))
(mapcar '(lambda (x) (apply 'setvar x))
(cons (list "dimtxt" height)
(cons (list "dimscale" (car scl))
'(("dimdli" 1.0)
("dimexe" 1.5)
("dimexo" 1.0)
("dimasz" 1.5)
("dimtad" 1)
("dimtix" 1)
("dimtofl" 1)
("dimgap" 1.0)
("dimtih" 0)
("dimdsep" ".")
("dimlunit" 2) ;_单位
("dimdec" 2) ;_精度
)
)
)
)
(vla-copyfrom ds (fy:acdoc))
(vla-put-activedimstyle (fy:acdoc) ds)
)
)
(_changescale (* height (car scl)) (strcat "FY-" str))
)
)
(fy:end)
(princ)
)

(defun c:tt (/                  _string:decimal            _changescale 
             _rectang:scale               scl            height 
             str          ds               nscl            kw 
            ) 
  (defun _string:decimal (val / str) 
    (setvar "dimzin" 0) 
    (setq str (rtos val 2 24) 
          str (vl-string-right-trim "0" str) 
          str (vl-string-right-trim "." str) 
    ) 
  ) 
  (defun _changescale (h str) 
    (vlax-for obj (fy:cset) 
      (if (wcmatch (vla-get-objectname obj) "*Text") 
        (vlax-put obj 'height h) 
        (vlax-put obj 'stylename str) 
      ) 
    ) 
  ) 
  (defun _rectang:scale        (/ p1 p2 str lst v scl kw) 
    (if 
      (and 
        (setq p1 (getpoint "\n第一点: ")) 
        (setq p2 (getcorner p1 "\n对角点: ")) 
        (progn (initget "1 2 3 4") 
               (setq kw        (getkword 
                          "\n打印图框大小[A0(0)/A1(1)/A2(2)/A3(3)/A4(4)]: " 
                        ) 
               ) 
        ) 
        (setq lst (assoc kw 
                         '(("0" 1089 841) 
                           ("1" 841 594) 
                           ("2" 594 420) 
                           ("3" 420 297) 
                           ("4" 297 210) 
                          ) 
                  ) 
        ) 
      ) 
       (progn (setq v        (apply 'max (mapcar 'abs (mapcar '- p2 p1))) 
                    scl        (/ v (apply 'max (cdr lst))) 
              ) 
              (list scl p1 p2) 
       ) 
    ) 
  ) 
  (fy:begin) 
  (if (and (setq scl (_rectang:scale)) 
           (progn (princ "\nPlot Scale = ") 
                  (princ (car scl)) 
                  (initget 128 "Y N") 
                  (setq kw (getkword "\n是否接受[是(Y)/否(N)]<Y>: ")) 
                  (if (or (= kw "Y") (= kw "")) 
                    t 
                    (if        (setq nscl (getreal "\n输入新比例: ")) 
                      (setq scl (cons nscl (cdr scl))) 
                    ) 
                  ) 
           ) 
           (setq height (getdist "\n文字高度: ")) 
           (ssget "_C" 
                  (cadr scl) 
                  (caddr scl) 
                  '((0 . "dimension,text")) 
           ) 
      ) 
    (progn 
      (setq 
        str (vl-string-translate "." "-" (_string:decimal (car scl))) 
      ) 
      (if (not (tblsearch "dimstyle" (strcat "FY-" str))) 
        (progn (setq ds (vla-add (fy:acdimstyles) (strcat "FY-" str))) 
               (mapcar '(lambda (x) (apply 'setvar x)) 
                       (cons (list "dimtxt" height) 
                             (cons (list "dimscale" (car scl)) 
                                   '(("dimdli" 1.0) 
                                     ("dimexe" 1.5) 
                                     ("dimexo" 1.0) 
                                     ("dimasz" 1.5) 
                                     ("dimtad" 1) 
                                     ("dimtix" 1) 
                                     ("dimtofl" 1) 
                                     ("dimgap" 1.0) 
                                     ("dimtih" 0) 
                                     ("dimdsep" ".") 
                                     ("dimlunit" 2) ;_单位 
                                     ("dimdec" 2) ;_精度 
                                    ) 
                             ) 
                       ) 
               ) 
               (vla-copyfrom ds (fy:acdoc)) 
               (vla-put-activedimstyle (fy:acdoc) ds) 
        ) 
      ) 
      (_changescale (* height (car scl)) (strcat "FY-" str)) 
    ) 
  ) 
  (fy:end) 
  (princ) 
)

lucas3 · 发表于 2014-11-20 11:11:08

本帖最后由 lucas3 于 2014-11-20 11:12 编辑

Free-Lancer 发表于 2014-11-20 08:52
自动按最大值计算比例，增加手动设置比例机会

非常谢谢大师！这次体验已经很不错了，只是还有一些小问题，如下：

1.选择A0 总是显示无效的关键字

2.别外一旦标注样式建立后，再次换字高就没作用了
举个例，一个A3图框，选择A4打印，Plot Scale = 1.41414 ，然后提示输入字高，输入3 在这过程中会生成了一个 FY-1-414141414141414 标注样式，但是
再次重复这一过程，选择A3图框，选择A4打印，但是字高我不输入3，输入其它的，比如5 ，比如10 ，图中的标注不会发生变化，因为Plot Scale = 1.41414 ，
所以还会使用FY-1-414141414141414 标注样式，但是图框内的文字高度(text)变了，这个高度好像就是输入的字高*比例，(另外Mtext 高度没变）

3.另外全局比例不用那么多小数位，四舍五入，只需保留小数点后1位即可，比如 1.41414 ＝1.4 ，生成的标注样式名也不用那么长了，文字高度也是一样，
比如第2点提到的改变了text的高度，字高＝输入字高*比例，也会有好些小数，我觉得文字高度只要整数位即可，不要后面的小数位

Free-Lancer · 发表于 2014-11-20 11:18:12

lucas3 发表于 2014-11-20 11:11
非常谢谢大师！这次体验已经很不错了，只是还有一些小问题，如下：

1.选择A0 总是显示无效的关键字

initget 忘了把 0 加入

所以标注修改都是基于标注样式，不会单独去修改标注实体的特性，这样更方便修改

lucas3 · 发表于 2014-11-20 12:06:59

本帖最后由 lucas3 于 2014-11-20 14:04 编辑

Free-Lancer 发表于 2014-11-20 11:18
initget 忘了把 0 加入

所以标注修改都是基于标注样式，不会单独去修改标注实体的特性，这样更方便修 ...

谢谢大师，
那另外提到的几个问题帮我修改下吧另外看到您到发了一个标注子样式的贴子http://bbs.xdcad.org/thread-677358-1-1.html ,
能不能将您32楼代码里的建立标注样式改成这里（http://bbs.xdcad.net/thread-672496-1-1.html）要求的标注样式？
谢谢大师了！{:soso_e183:}

Free-Lancer · 发表于 2014-11-20 15:00:09

lucas3 发表于 2014-11-20 12:06
谢谢大师，
那另外提到的几个问题帮我修改下吧另外看到您到发了一个标注子样式的贴子http://bbs.xdcad.o ...

自己参照说明添加变量

(defun c:tt (/ _string:decimal _changescale
_rectang:scale scl height
str ds nscl kw
)
(defun _string:decimal (val / str)
(setvar "dimzin" 0)
(setq str (rtos val 2 2)
str (vl-string-right-trim "0" str)
str (vl-string-right-trim "." str)
)
)
(defun _changescale (h str)
(vlax-for obj (fy:cset)
(if (wcmatch (vla-get-objectname obj) "*Text")
(vlax-put obj 'height h)
(vlax-put obj 'stylename str)
)
)
)
(defun _rectang:scale (/ p1 p2 str lst v scl kw)
(if
(and
(setq p1 (getpoint "\n第一点: "))
(setq p2 (getcorner p1 "\n对角点: "))
(progn (initget "0 1 2 3 4")
(setq kw (getkword
"\n打印图框大小[A0(0)/A1(1)/A2(2)/A3(3)/A4(4)]: "
)
)
)
(setq lst (assoc kw
'(("0" 1089 841)
("1" 841 594)
("2" 594 420)
("3" 420 297)
("4" 297 210)
)
)
)
)
(progn (setq v (apply 'max (mapcar 'abs (mapcar '- p2 p1)))
scl (/ v (apply 'max (cdr lst)))
)
(list scl p1 p2)
)
)
)
(fy:begin)
(if (and (setq scl (_rectang:scale))
(progn (princ "\nPlot Scale = ")
(princ (car scl))
(initget 128 "Y N")
(setq kw (getkword "\n是否接受[是(Y)/否(N)]<Y>: "))
(if (or (= kw "Y") (= kw ""))
t
(if (setq nscl (getreal "\n输入新比例: "))
(setq scl (cons nscl (cdr scl)))
)
)
)
(setq height (getdist "\n文字高度: "))
(ssget "_C"
(cadr scl)
(caddr scl)
'((0 . "dimension,text"))
)
)
(progn
(setq
str (vl-string-translate "." "-" (_string:decimal (car scl)))
)
(xd::doc:createDimstyleFrom
nil
(strcat "FY-" str)
(cons (list "dimtxt" height)
(cons (list "dimscale" (car scl))
'(("dimdli" 1.0)
("dimexe" 1.5)
("dimexo" 1.0)
("dimasz" 1.5)
("dimtad" 1)
("dimtix" 1)
("dimtofl" 1)
("dimgap" 1.0)
("dimtih" 0)
("dimdsep" ".")
("dimlunit" 2) ;_单位
("dimdec" 2) ;_精度
)
)
)
)
(mapcar '(lambda (x)
(xd::doc:createSubDimstyle (strcat "FY-" str) x nil);_变量自己增加
)
'("$2" "$3" "$4" "$6")
)
(_changescale (* height (car scl)) (strcat "FY-" str))
)
)
(fy:end)
(princ)
)

(defun c:tt (/                  _string:decimal            _changescale 
             _rectang:scale               scl            height 
             str          ds               nscl            kw 
            ) 
  (defun _string:decimal (val / str) 
    (setvar "dimzin" 0) 
    (setq str (rtos val 2 2) 
          str (vl-string-right-trim "0" str) 
          str (vl-string-right-trim "." str) 
    ) 
  ) 
  (defun _changescale (h str) 
    (vlax-for obj (fy:cset) 
      (if (wcmatch (vla-get-objectname obj) "*Text") 
        (vlax-put obj 'height h) 
        (vlax-put obj 'stylename str) 
      ) 
    ) 
  ) 
  (defun _rectang:scale        (/ p1 p2 str lst v scl kw) 
    (if 
      (and 
        (setq p1 (getpoint "\n第一点: ")) 
        (setq p2 (getcorner p1 "\n对角点: ")) 
        (progn (initget "0 1 2 3 4") 
               (setq kw        (getkword 
                          "\n打印图框大小[A0(0)/A1(1)/A2(2)/A3(3)/A4(4)]: " 
                        ) 
               ) 
        ) 
        (setq lst (assoc kw 
                         '(("0" 1089 841) 
                           ("1" 841 594) 
                           ("2" 594 420) 
                           ("3" 420 297) 
                           ("4" 297 210) 
                          ) 
                  ) 
        ) 
      ) 
       (progn (setq v        (apply 'max (mapcar 'abs (mapcar '- p2 p1))) 
                    scl        (/ v (apply 'max (cdr lst))) 
              ) 
              (list scl p1 p2) 
       ) 
    ) 
  ) 
  (fy:begin) 
  (if (and (setq scl (_rectang:scale)) 
           (progn (princ "\nPlot Scale = ") 
                  (princ (car scl)) 
                  (initget 128 "Y N") 
                  (setq kw (getkword "\n是否接受[是(Y)/否(N)]<Y>: ")) 
                  (if (or (= kw "Y") (= kw "")) 
                    t 
                    (if        (setq nscl (getreal "\n输入新比例: ")) 
                      (setq scl (cons nscl (cdr scl))) 
                    ) 
                  ) 
           ) 
           (setq height (getdist "\n文字高度: ")) 
           (ssget "_C" 
                  (cadr scl) 
                  (caddr scl) 
                  '((0 . "dimension,text")) 
           ) 
      ) 
    (progn 
      (setq 
        str (vl-string-translate "." "-" (_string:decimal (car scl))) 
      ) 
      (xd::doc:createDimstyleFrom 
        nil 
        (strcat "FY-" str) 
        (cons (list "dimtxt" height) 
              (cons (list "dimscale" (car scl)) 
                    '(("dimdli" 1.0) 
                      ("dimexe" 1.5) 
                      ("dimexo" 1.0) 
                      ("dimasz" 1.5) 
                      ("dimtad" 1) 
                      ("dimtix" 1) 
                      ("dimtofl" 1) 
                      ("dimgap" 1.0) 
                      ("dimtih" 0) 
                      ("dimdsep" ".") 
                      ("dimlunit" 2) ;_单位 
                      ("dimdec" 2) ;_精度 
                     ) 
              ) 
        ) 
      ) 
      (mapcar '(lambda (x) 
                 (xd::doc:createSubDimstyle (strcat "FY-" str) x nil);_变量自己增加 
               ) 
              '("$2" "$3" "$4" "$6") 
      ) 
      (_changescale (* height (car scl)) (strcat "FY-" str)) 
    ) 
  ) 
  (fy:end) 
  (princ) 
)

lucas3 · 发表于 2014-11-20 15:49:46

Free-Lancer 发表于 2014-11-20 15:00
自己参照说明添加变量

大师，暂不添加变量，就无法生成标注样式吗？没有加变量，测试了下，运行结束后，没有生成标注样式，也没有报错

Free-Lancer · 发表于 2014-11-20 16:01:51

lucas3 发表于 2014-11-20 15:49
大师，暂不添加变量，就无法生成标注样式吗？没有加变量，测试了下，运行结束后，没有生成标注样式，也 ...

不加变量就用当前样式的

lucas3 · 发表于 2014-11-20 16:16:38

Free-Lancer 发表于 2014-11-20 16:01
不加变量就用当前样式的

大师 mapcar '(lambda (x) 这个还无法理解，

(mksubdimsty
"GB孔"
"$4"
'(("DIMTOH" 1) ("DIMTIH" 0))
)

像上面这样，要怎么添加到下面？

   (mapcar '(lambda (x)
               (xd::doc:createSubDimstyle (strcat "FY-" str) x nil);_变量自己增加
            )
            '("$2" "$3" "$4" "$6")
   )

Free-Lancer · 发表于 2014-11-20 16:18:24

(xd::doc:createSubDimstyle
  "GB孔"
  "$4"
  '(("DIMTOH" 1) ("DIMTIH" 0))
)

lucas3 · 发表于 2014-11-20 16:27:02

Free-Lancer 发表于 2014-11-20 16:18
(xd::doc:createSubDimstyle
"GB孔"
"$4"

您的意思是将

(mapcar '(lambda (x)
(xd::doc:createSubDimstyle (strcat "FY-" str) x nil);_变量自己增加
)
'("$2" "$3" "$4" "$6")
)

变成这样吗

(mapcar '(lambda (x)
(xd::doc:createSubDimstyle "GB孔" "$4" '(("DIMTOH" 1) ("DIMTIH" 0))
)
'("$2" "$3" "$4" "$6")
)

Free-Lancer · 发表于 2014-11-20 16:29:43

lucas3 发表于 2014-11-20 16:27
您的意思是将

你需要建立那么多子样式吗？
需要哪个就建哪个

lucas3 · 发表于 2014-11-20 16:40:08

Free-Lancer 发表于 2014-11-20 16:29
你需要建立那么多子样式吗？
需要哪个就建哪个

您的意思是说不要 “(mapcar '(lambda (x)” 这个吗？

我要做到这个效果的，应该怎么改呢？

Free-Lancer · 发表于 2014-11-20 16:46:02

lucas3 发表于 2014-11-20 16:40
您的意思是说不要 “(mapcar '(lambda (x)” 这个吗？

我要做到这个效果的，应该怎么改呢？

(mapcar '(lambda (x)
   (xd::doc:createSubDimstyle
      "GB孔"
      (car x)
      (cadr x)
   )
   '(("$2" nil)
      ("$3" nil)
      ("$4" (("DIMTOH" 1) ("DIMTIH" 0)))
      ("$6" nil)
      )
   )
)

账号		自动登录	找回密码
密码			立即注册

[已解决] 像这样改变当前标注文字高度

点评

点评

点评

点评

点评

点评

点评

点评

点评

点评

点评

点评

点评