LDATA 替代方法

csharp · 发表于 2015-3-23 07:43:13

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

;; /* Replaces vlax-ldata-* commands
;; /* NEW_LDATA
;;Warren Ledford WarrenWare ACADv2007 2/21/2007
;; /*************** USAGE ***************/
;; /* (new_ldata-put ) - Replaces vlax-ldata-put
;; /* (new_ldata-get ) - Replaces vlax-ldata-get
;; /* (new_ldata-list ) - Replaces vlax-ldata-list
;; /* (new_ldata-delete ) - Replaces vlax-ldata-delete
;; /* (new_ldata-listkeys ) - NEW COMMAND, Returns a list of keys in dictionary
;; /* (new_ldata-deldict ) - NEW COMMAND, Removes Dictionary Container
;; /* (new_ldata-convert ) - NEW COMMAND, Converts vlax-ldata to new_ldata: Must be performed in version Autocad that can use vlax-ldata-* commansds
(defun addrecord (dictName key dataList / xname)
(setq dataList (append (list '(0 . "XRECORD") '(100 . "AcDbXrecord"))
dataList
)
xname (entmakex dataList)
) ;_end setq
(dictadd (getdictname dictName) key xname)
) ;_end defun addrecord
(defun changerecord (dictName key dataList)
(if (getrecord dictName key)
(progn
(delrecord dictName key)
(addrecord dictName key dataList)
) ;_end progn
) ;_endif
) ;_end defun changerecord
(defun createdict (dictName / dictionary xname newdict)
(if (not (dictsearch (namedobjdict) dictName))
(progn
(setq dictionary '((0 . "DICTIONARY") (100 . "AcDbDictionary"))
xname (entmakex dictionary)
newdict (dictadd (namedobjdict) dictName xname)
) ;_end setq
) ;_end progn
) ;_endif
) ;_end defun createdict
(defun new_ldata-deldict (dictName)
(dictremove (namedobjdict) dictName)
) ;_end defun new_ldata-deldict
(defun delrecord (dictName key)
(dictremove (getdictname dictName) key)
) ;_end defun delrecord
(defun getdict (dictName)
(dictsearch (namedobjdict) dictName)
) ;_end defun getdict
(defun getdictname (dictName / tmp)
(if (setq tmp (dictsearch (namedobjdict) dictName))
(cdr (assoc -1 tmp))
) ;_endif
) ;_end defun getdictname
(defun getkeys (dictName / tmp)
(if (setq tmp (getdict dictname))
(new_ldata-massoc 3 tmp)
) ;_endif
) ;_end defun getkeys
(defun new_ldata-list (dictName)
(mapcar '(lambda (x) (cons x (cdar (getrecord dictName x))))
(getkeys dictName)
) ;_end mapcar
) ;_end defun new_ldata-list
(defun getrecord (dictName key /)
(cdr
(cddddr (cddddr (dictsearch (getdictname dictName) key)))
)
) ;_end defun getrecord
(defun listdictionaries ()
(new_ldata-massoc 3 (entget (namedobjdict)))
) ;_end defun listdictionaries
(defun new_ldata-massoc (key alist / x nlist)
(foreach x alist
(if (eq key (car x))
(setq nlist (cons (cdr x) nlist))
) ;_endif
) ;_end foreach
(reverse nlist)
) ;_end defun new_ldata-massoc
(defun new_ldata-put (dictName key data / fmtdata)
(setq fmtdata (list (cons 300 data)))
(if (not (createdict dictName))
;;/* Here check to see if key exists
(if (member key (getkeys dictName))
(changerecord dictName key fmtdata) ;_ /* Record exists
) ;_endif
) ;_endif
(addrecord dictName key fmtdata) ;_ /* Record doesn't exist
) ;_end defun new_ldata-put
(defun new_ldata-get (dictName key)
(cdar (getrecord dictName key))
) ;_end defun new_ldata-get
(defun new_ldata-listkeys (dictName)
(getkeys dictName)
) ;_end defun new_ldata-listkeys
(defun new_ldata-delete (dictName key)
(delrecord dictName key)
) ;_end defun new_ldata-delete
(defun new_ldata-convert (dictName)
(foreach x (mapcar 'car (vlax-ldata-list dictName))
(new_ldata-put
"ww_ldata-convert_dict"
x
(vlax-ldata-get dictName x)
)
) ;_end foreach
(new_ldata-deldict dictName)
(foreach x (mapcar 'car (new_ldata-list "ww_ldata-convert_dict"))
(new_ldata-put
dictName
x
(new_ldata-get "ww_ldata-convert_dict" x)
)
) ;_end foreach
(new_ldata-deldict "ww_ldata-convert_dict")
) ;_end defun new_ldata-convert

;; /* Replaces vlax-ldata-* commands 
;; /* NEW_LDATA 
;;Warren Ledford WarrenWare ACADv2007 2/21/2007 
 
;; /*************** USAGE ***************/ 
;; /* (new_ldata-put ) - Replaces vlax-ldata-put 
;; /* (new_ldata-get ) - Replaces vlax-ldata-get 
;; /* (new_ldata-list ) - Replaces vlax-ldata-list 
;; /* (new_ldata-delete ) - Replaces vlax-ldata-delete 
;; /* (new_ldata-listkeys ) - NEW COMMAND, Returns a list of keys in dictionary 
;; /* (new_ldata-deldict ) - NEW COMMAND, Removes Dictionary Container 
;; /* (new_ldata-convert ) - NEW COMMAND, Converts vlax-ldata to new_ldata: Must be performed in version Autocad that can use vlax-ldata-* commansds 
 
(defun addrecord (dictName key dataList / xname) 
  (setq        dataList (append (list '(0 . "XRECORD") '(100 . "AcDbXrecord")) 
                         dataList 
                 ) 
        xname         (entmakex dataList) 
  ) ;_end setq 
  (dictadd (getdictname dictName) key xname) 
) ;_end defun addrecord 
 
 
(defun changerecord (dictName key dataList) 
  (if (getrecord dictName key) 
    (progn 
      (delrecord dictName key) 
      (addrecord dictName key dataList) 
    ) ;_end progn 
  ) ;_endif 
) ;_end defun changerecord 
 
 
(defun createdict (dictName / dictionary xname newdict) 
  (if (not (dictsearch (namedobjdict) dictName)) 
    (progn 
      (setq dictionary '((0 . "DICTIONARY") (100 . "AcDbDictionary")) 
            xname      (entmakex dictionary) 
            newdict    (dictadd (namedobjdict) dictName xname) 
      ) ;_end setq 
    ) ;_end progn 
  ) ;_endif 
) ;_end defun createdict 
 
 
(defun new_ldata-deldict (dictName) 
  (dictremove (namedobjdict) dictName) 
) ;_end defun new_ldata-deldict 
 
 
(defun delrecord (dictName key) 
  (dictremove (getdictname dictName) key) 
) ;_end defun delrecord 
 
 
(defun getdict (dictName) 
  (dictsearch (namedobjdict) dictName) 
) ;_end defun getdict 
 
 
(defun getdictname (dictName / tmp) 
  (if (setq tmp (dictsearch (namedobjdict) dictName)) 
    (cdr (assoc -1 tmp)) 
  ) ;_endif 
) ;_end defun getdictname 
 
 
(defun getkeys (dictName / tmp) 
  (if (setq tmp (getdict dictname)) 
    (new_ldata-massoc 3 tmp) 
  ) ;_endif 
) ;_end defun getkeys 
 
 
(defun new_ldata-list (dictName) 
  (mapcar '(lambda (x) (cons x (cdar (getrecord dictName x)))) 
          (getkeys dictName) 
  ) ;_end mapcar 
) ;_end defun new_ldata-list 
 
 
(defun getrecord (dictName key /) 
  (cdr 
    (cddddr (cddddr (dictsearch (getdictname dictName) key))) 
  ) 
) ;_end defun getrecord 
 
 
(defun listdictionaries        () 
  (new_ldata-massoc 3 (entget (namedobjdict))) 
) ;_end defun listdictionaries 
 
 
(defun new_ldata-massoc        (key alist / x nlist) 
  (foreach x alist 
    (if        (eq key (car x)) 
      (setq nlist (cons (cdr x) nlist)) 
    ) ;_endif 
  ) ;_end foreach 
 
  (reverse nlist) 
) ;_end defun new_ldata-massoc 
 
 
(defun new_ldata-put (dictName key data / fmtdata) 
  (setq fmtdata (list (cons 300 data))) 
 
  (if (not (createdict dictName)) 
    ;;/* Here check to see if key exists 
    (if        (member key (getkeys dictName)) 
      (changerecord dictName key fmtdata) ;_ /* Record exists 
    ) ;_endif 
  ) ;_endif 
 
  (addrecord dictName key fmtdata) ;_ /* Record doesn't exist 
) ;_end defun new_ldata-put 
 
 
(defun new_ldata-get (dictName key) 
  (cdar (getrecord dictName key)) 
) ;_end defun new_ldata-get 
 
 
(defun new_ldata-listkeys (dictName) 
  (getkeys dictName) 
) ;_end defun new_ldata-listkeys 
 
 
(defun new_ldata-delete        (dictName key) 
  (delrecord dictName key) 
) ;_end defun new_ldata-delete 
 
 
(defun new_ldata-convert (dictName) 
  (foreach x (mapcar 'car (vlax-ldata-list dictName)) 
    (new_ldata-put 
      "ww_ldata-convert_dict" 
      x 
      (vlax-ldata-get dictName x) 
    ) 
  ) ;_end foreach 
 
  (new_ldata-deldict dictName) 
 
  (foreach x (mapcar 'car (new_ldata-list "ww_ldata-convert_dict")) 
    (new_ldata-put 
      dictName 
      x 
      (new_ldata-get "ww_ldata-convert_dict" x) 
    ) 
  ) ;_end foreach 
 
  (new_ldata-deldict "ww_ldata-convert_dict") 
) ;_end defun new_ldata-convert

Ldata 是 Autodesk 专为 Autolisp 定制的一个词典，由 vlax-ldata-* 函数操作，这个词典的 Object 类型为 VLO-VL ， Lisp 操作方便了，其它语言 (ARX 、Net、Com)操作就麻烦，上面函数用 XRecord 代替了 VLO-VL，XRecord 几个语言操作都没有问题，其实上面函数只需要 new_ldata-put 一个函数，生成的词典就可以交互了。vlax-ldata-list vlax-ldata-get vlax-ldata-delete 还可以继续使用。

csharp · 发表于 2015-3-23 07:46:31

本帖最后由 csharp 于 2015-3-23 08:12 编辑

补充一句，Ldata 中任何数据都是用 300 组码以 string 形式保存，get 时执行 read

另 Entity 不能用上面代码保存，Entity 在 LDATA 中是用多个 340 组码保存的，300 组码是一个指向表

qq1254582201 · 发表于 2021-8-13 16:38:11

好东西，收藏了

账号		自动登录	找回密码
密码			立即注册

[精彩文萃] LDATA 替代方法

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。