曲线曲率梳

lgx9612

不会点在曲线上的切线法线的算法，用了一个简单粗爆的方法（直接用原曲线偏移的方法）

[sell=5](defun per_curve_lgx (in-cur_obj_lgx at_point_lgx distance_lgx / out2_point_lgx out1_point_lgx temppoint_lgx)
;;;原创,编写:刘国新
;;;曲线上一点的法线(通过偏移原曲线来计算该点的法线)
(setq temppoint_lgx (vlax-curve-getClosestPointTo in-cur_obj_lgx at_point_lgx t))
(if distance_lgx
(progn
(setq out1_point_lgx (polar at_point_lgx (angle at_point_lgx temppoint_lgx) distance_lgx))
(setq out2_point_lgx (polar at_point_lgx (angle temppoint_lgx at_point_lgx) distance_lgx))
)
(progn
(setq out1_point_lgx (polar at_point_lgx (angle at_point_lgx temppoint_lgx) 5.0))
(setq out2_point_lgx (polar at_point_lgx (angle temppoint_lgx at_point_lgx) 5.0))
)
)
(list at_point_lgx (list out1_point_lgx out2_point_lgx))
)



(defun tan_circel_lgx (obj_incurver_lgx obj_incurver1_lgx given_point_lgx inprecision_lgx / temp_center_lgx normal1_line_lgx in1_curve_lgx loop_lgx go_lgx looop_lgx
                       direct-to_lgx tan_center_lgx looptime_lgx normal_line_lgx save_fromstar_lgx fromstar_lgx cur_length_lgx precision_lgx e_point_lgx s_point_lgx)
;;;原创,编写:刘国新
;;;曲线上一点的曲率半径及该曲率半径的圆心
(if (= inprecision_lgx nil)(setq inprecision_lgx 0.005))
(setq s_point_lgx (trans (vlax-curve-getStartPoint obj_incurver_lgx) 0 1));;;曲线起点
(setq e_point_lgx (trans (vlax-curve-getEndPoint obj_incurver_lgx) 0 1));;;曲线终点
(setq cur_length_lgx (vlax-curve-getDistAtParam obj_incurver_lgx (vlax-curve-getEndParam obj_incurver_lgx)))
(if (= (setq precision_lgx (/ (distance s_point_lgx e_point_lgx) 50.0)) 0.0)
(setq precision_lgx (/ cur_length_lgx 100.0))
)
(if (> precision_lgx 0.1)
(setq precision_lgx 0.1)
)
(setq fromstar_lgx (vlax-curve-getDistAtPoint obj_incurver_lgx given_point_lgx))
(setq save_fromstar_lgx fromstar_lgx)
(setq normal_line_lgx (cadr (per_curve_lgx obj_incurver1_lgx given_point_lgx nil)))
(setq looptime_lgx 1)
(setq tan_center_lgx nil)
(if (<= (/ fromstar_lgx cur_length_lgx) 0.5)(setq direct-to_lgx 1)(setq direct-to_lgx 0))
(setq looop_lgx t)
(while looop_lgx
(if (= direct-to_lgx 1)
(setq go_lgx 1)
(setq go_lgx 0)
)
(setq looptime_lgx (1+ looptime_lgx))
(setq looptime-in_lgx 0)
(progn
(setq loop_lgx t)
(while loop_lgx
(if (or (and (= direct-to_lgx 1)(= go_lgx 1))(and (= direct-to_lgx 0)(= go_lgx 0)))
(setq fromstar_lgx (+ fromstar_lgx precision_lgx))
(setq fromstar_lgx (- fromstar_lgx precision_lgx))
)
(if (or (> fromstar_lgx cur_length_lgx)(< fromstar_lgx 0))
(setq loop_lgx nil)
(progn
(setq in1_curve_lgx (trans (vlax-curve-getPointAtDist obj_incurver_lgx fromstar_lgx) 0 1))
(setq normal1_line_lgx (cadr (per_curve_lgx obj_incurver1_lgx in1_curve_lgx nil)))
(if (setq temp_center_lgx (inters (car normal_line_lgx)(cadr normal_line_lgx)(car normal1_line_lgx)(cadr normal1_line_lgx)nil))
(progn
(setq tan_center_lgx temp_center_lgx)
(setq precision_lgx (/ precision_lgx 2.0))
(setq go_lgx 0)
(setq looptime-in_lgx 0)
)
(progn
(setq go_lgx 1)
(setq looptime-in_lgx (1+ looptime-in_lgx))
)
)
)
)
(if (> looptime-in_lgx 5)(setq loop_lgx nil))
(if (<= precision_lgx inprecision_lgx)(progn (setq loop_lgx nil)(setq looop_lgx nil)))
)
)
(if (= direct-to_lgx 1)
(setq direct-to_lgx 0)
(setq direct-to_lgx 1)
)
(setq fromstar_lgx save_fromstar_lgx)
(if (>= looptime_lgx 3)(setq looop_lgx nil))
)
(if tan_center_lgx
(list tan_center_lgx (distance tan_center_lgx given_point_lgx))
nil
)
)


(defun divid_curve_lgx (cur_obj_lgx cur1_obj_lgx div-nn_lgx outtype_lgx / point_in_curve_lgx every_distance_lgx n_lgx point_list_lgx cur_length_lgx end_param_lgx)
;;;原创,编写:刘国新
;;;等分曲线
;;;outtype_lgx=1 连同法线一起输出
(if cur_obj_lgx
(progn
(if (= cur1_obj_lgx nil)(setq outtype_lgx nil))
(setq end_param_lgx (vlax-curve-getEndParam cur_obj_lgx))
(setq cur_length_lgx (vlax-curve-getDistAtParam cur_obj_lgx end_param_lgx))
(setq point_list_lgx nil)
(setq n_lgx -1)
(setq every_distance_lgx (/ cur_length_lgx (float div-nn_lgx)))
(repeat (1+ div-nn_lgx)
(setq n_lgx (1+ n_lgx))
(setq point_in_curve_lgx (trans (vlax-curve-getPointAtDist cur_obj_lgx (* n_lgx every_distance_lgx)) 0 1))
(if (= outtype_lgx 1)
(setq point_in_curve_lgx (per_curve_lgx cur1_obj_lgx point_in_curve_lgx (/ cur_length_lgx div-nn_lgx)))
)
(setq point_list_lgx (cons point_in_curve_lgx point_list_lgx))
)
)
)
point_list_lgx
)



(defun c:ra_curve_lgx(/ last_screensize_lgx last_viewctr_lgx nmn_lgx showcolor_lgx point_to_lgx c_radius_lgx curve_radius_lgx endpoint-curve_r_lgx show-curve_r_lgx
            curve_scale_lgx eemp_lgx cen&r_lgx current_lgx mmm_lgx ttemp_lgx smalist_r_lgx biggest_r_lgx normal&r_lgx radius-all_lgx currentpoint_lgx grd_lgx1
            loopp_lgx show_range_lgx midu_lgx cal_date_lgx cal_showdate_lgx showdate_lgx cur1_obj_lgx delet_ss_lgx offset_value_lgx callength_lgx end_point_lgx
            star_point_lgx cur_obj_lgx ename_lgx showendpoint no_showcolor_lgx cm_lgx *error*)
;;;原创,编写:刘国新
;;;曲线曲率梳
(defun *error* (msg)
(redraw)
(if delet_ss_lgx
(progn
(redraw delet_ss_lgx 1)
(command "erase" delet_ss_lgx "")
)
)
(setvar "cmdecho" cm_lgx)
(princ)
)
(setq cm_lgx (getvar "cmdecho"))
(setvar "cmdecho" 0)
(setq no_showcolor_lgx 1)
(setq showendpoint nil)
(princ "\n请选择要分析曲线曲率的曲线:")
(setq ename_lgx (car (entsel)))
(setq cur_obj_lgx (vlax-ename->vla-object ename_lgx))
(setq star_point_lgx (trans (vlax-curve-getStartPoint cur_obj_lgx) 0 1));;;曲线起点
(setq end_point_lgx (trans (vlax-curve-getEndPoint cur_obj_lgx) 0 1));;;曲线终点
(setq callength_lgx (vlax-curve-getDistAtParam cur_obj_lgx (vlax-curve-getEndParam cur_obj_lgx)))
(if (= (setq offset_value_lgx (/ (distance star_point_lgx end_point_lgx) 100.0)) 0.0)
(setq offset_value_lgx (/ callength_lgx 200.0))
)
(if (or (> offset_value_lgx 0.1)(<= offset_value_lgx 0))
(setq offset_value_lgx 0.1)
)
(vla-offset cur_obj_lgx (- offset_value_lgx))
(setq delet_ss_lgx (entlast))
(redraw delet_ss_lgx 2)
(setq cur1_obj_lgx (vlax-ename->vla-object (entlast)))
(setq showdate_lgx nil)
(setq cal_showdate_lgx nil)
(setq cal_date_lgx nil)
(if (< (setq midu_lgx (fix (/ callength_lgx 0.1))) 50)
(setq midu_lgx 50)
)
(if (> midu_lgx 200)
(setq midu_lgx 200)
)
(if (< (setq show_range_lgx (/ callength_lgx 100)) 3.0)
(setq show_range_lgx 3.0)
)
(princ "\n刘国新工具箱=>曲线的曲率梳 /W(右键) 加大密度  /S(左键) 减少密度  /A 缩小比例 /D 加大比例 /E 曲率端点的连接 /R 颜色区分")
(princ "\n刘国新工具箱=>曲线的曲率梳 回车或空格退出\n")
(setq loopp_lgx t)
(while loopp_lgx ;;;;;循环
(setq grd_lgx1 (apply 'GRREAD '(t 7 0)))
(setq currentpoint_lgx (cadr grd_lgx1))
(if (= cal_date_lgx nil)
(progn;;;;;计算
(setq radius-all_lgx nil)
(setq normal&r_lgx nil)
(setq biggest_r_lgx nil)
(setq smalist_r_lgx nil)
(setq ttemp_lgx (divid_curve_lgx cur_obj_lgx nil midu_lgx nil))
(setq mmm_lgx (length ttemp_lgx))
(repeat mmm_lgx
(setq mmm_lgx (1- mmm_lgx))
(setq current_lgx (nth mmm_lgx ttemp_lgx))
(if (setq cen&r_lgx (tan_circel_lgx cur_obj_lgx cur1_obj_lgx current_lgx nil))
(progn
(setq normal&r_lgx (cons (list (list (car cen&r_lgx) current_lgx)(cadr cen&r_lgx)) normal&r_lgx))
;;;(redraw)
;;;(grvecs (list 4 (car cen&r_lgx) current_lgx))
(setq eemp_lgx (cadr cen&r_lgx))
(if (= biggest_r_lgx nil)
(setq biggest_r_lgx eemp_lgx)
(if (> eemp_lgx biggest_r_lgx)
(setq biggest_r_lgx eemp_lgx)
)
)
(if (= smalist_r_lgx nil)
(setq smalist_r_lgx eemp_lgx)
(if (< eemp_lgx smalist_r_lgx)
(setq smalist_r_lgx eemp_lgx)
)
)
(setq radius-all_lgx (cons eemp_lgx radius-all_lgx))
)
)
)
(if (= curve_scale_lgx nil)
(progn
(setq curve_scale_lgx (/ show_range_lgx (/ 1.0 biggest_r_lgx)))
(if (> (* curve_scale_lgx (/ 1.0 smalist_r_lgx)) (/ callength_lgx 2.0))
(setq curve_scale_lgx (/ (/ callength_lgx 2.0) (/ 1.0 smalist_r_lgx)))
)
)
)
(setq cal_date_lgx 1)
(setq cal_showdate_lgx nil)
)
)
(if radius-all_lgx
(if (= cal_showdate_lgx nil)
(progn;;;;;显示计算
(if (= curve_scale_lgx nil)
(setq curve_scale_lgx 100.0)
)
(if (and unduplicate_lgx in_order_lgx)
(if (/= no_showcolor_lgx nil)
(progn
(setq radius-all_lgx (car (unduplicate_lgx radius-all_lgx)));;;去重复
(setq radius-all_lgx (in_order_lgx radius-all_lgx));;;顺序排列
)
)
(setq no_showcolor_lgx nil)
)
(setq show-curve_r_lgx nil)
(setq endpoint-curve_r_lgx nil);;;曲率梳的末端
(setq mmm_lgx (length normal&r_lgx))
(repeat mmm_lgx
(setq mmm_lgx (1- mmm_lgx))
(setq current_lgx (nth mmm_lgx normal&r_lgx))
(setq curve_radius_lgx (* curve_scale_lgx (/ 1.0 (cadr current_lgx))))
(setq c_radius_lgx (cadr current_lgx))
(setq currentpoint_lgx (car current_lgx))
(setq point_to_lgx (polar (cadr currentpoint_lgx) (angle (car currentpoint_lgx) (cadr currentpoint_lgx)) curve_radius_lgx))
(if (equal smalist_r_lgx biggest_r_lgx 0.005)
(setq no_showcolor_lgx nil)
)
(if (= no_showcolor_lgx nil)
(setq showcolor_lgx 1)
(progn
(setq nmn_lgx (/ (length radius-all_lgx) 7.0))
(cond
((and (>= c_radius_lgx (nth 0 radius-all_lgx))(< c_radius_lgx (nth (fix (* 1.0 nmn_lgx)) radius-all_lgx)))
(setq showcolor_lgx 1)
)
((and (>= c_radius_lgx (nth (fix (* 1.0 nmn_lgx)) radius-all_lgx))(< c_radius_lgx (nth (fix (* 2.0 nmn_lgx)) radius-all_lgx)))
(setq showcolor_lgx 2)
)
((and (>= c_radius_lgx (nth (fix (* 2.0 nmn_lgx)) radius-all_lgx))(< c_radius_lgx (nth (fix (* 3.0 nmn_lgx)) radius-all_lgx)))
(setq showcolor_lgx 3)
)
((and (>= c_radius_lgx (nth (fix (* 3.0 nmn_lgx)) radius-all_lgx))(< c_radius_lgx (nth (fix (* 4.0 nmn_lgx)) radius-all_lgx)))
(setq showcolor_lgx 4)
)
((and (>= c_radius_lgx (nth (fix (* 4.0 nmn_lgx)) radius-all_lgx))(< c_radius_lgx (nth (fix (* 5.0 nmn_lgx)) radius-all_lgx)))
(setq showcolor_lgx 5)
)
((and (>= c_radius_lgx (nth (fix (* 5.0 nmn_lgx)) radius-all_lgx))(< c_radius_lgx (nth (fix (* 6.0 nmn_lgx)) radius-all_lgx)))
(setq showcolor_lgx 6)
)
((and (>= c_radius_lgx (nth (fix (* 6.0 nmn_lgx)) radius-all_lgx))(<= c_radius_lgx (last radius-all_lgx)))
(setq showcolor_lgx 7)
)
)
)
)
(setq show-curve_r_lgx (cons (cadr currentpoint_lgx) show-curve_r_lgx))
(setq show-curve_r_lgx (cons point_to_lgx show-curve_r_lgx))
(setq show-curve_r_lgx (cons showcolor_lgx show-curve_r_lgx))
(if (= showendpoint 1)
(if endpoint-curve_r_lgx
(progn
(setq show-curve_r_lgx (cons (car endpoint-curve_r_lgx) show-curve_r_lgx))
(setq show-curve_r_lgx (cons point_to_lgx show-curve_r_lgx))
(setq show-curve_r_lgx (cons showcolor_lgx show-curve_r_lgx))
)
)
)
(setq endpoint-curve_r_lgx (cons point_to_lgx endpoint-curve_r_lgx))
)
(setq cal_showdate_lgx 1)
(setq showdate_lgx nil)
)
)
(progn
(setq loopp_lgx nil)
(princ "\n直线或曲线曲率半径无限大")
)
)
(if (or (= showdate_lgx nil) (not (equal last_viewctr_lgx (getvar "viewctr")))(not (equal last_screensize_lgx (GETVAR "VIEWSIZE"))))
(progn
(redraw)
(grvecs (cons 1 show-curve_r_lgx))
(setq showdate_lgx 1)
)
)
(setq last_viewctr_lgx (getvar "viewctr"))
(setq last_screensize_lgx (GETVAR "VIEWSIZE"))
(cond
((= (car grd_lgx1) 2);;;键盘输入
;;;(princ "键盘==>")(princ grd_lgx1)
(cond
((or(= (cadr grd_lgx1) 119)(= (cadr grd_lgx1) 87));;;W 加密
(setq cal_date_lgx nil)
(setq midu_lgx (fix (/ midu_lgx 0.8)))
)
((or(= (cadr grd_lgx1) 115)(= (cadr grd_lgx1) 83));;;S减密
(setq cal_date_lgx nil)
(setq midu_lgx (fix (* midu_lgx 0.8)))
)
((or(= (cadr grd_lgx1) 69)(= (cadr grd_lgx1) 101));;;E末端的显示
(setq cal_showdate_lgx nil)
(if(= showendpoint 1)
(setq showendpoint nil)
(setq showendpoint 1)
)
)
((or(= (cadr grd_lgx1) 97)(= (cadr grd_lgx1) 65));;;A曲率梳的比例
(setq cal_showdate_lgx nil)
(setq curve_scale_lgx (* curve_scale_lgx 0.8))
)
((or(= (cadr grd_lgx1) 100)(= (cadr grd_lgx1) 68));;;D曲率梳的比例
(setq cal_showdate_lgx nil)
(setq curve_scale_lgx (/ curve_scale_lgx 0.8))
)
((or(= (cadr grd_lgx1) 82)(= (cadr grd_lgx1) 114));;;R颜色
(setq cal_showdate_lgx nil)
(if(= no_showcolor_lgx 1)
(setq no_showcolor_lgx nil)
(setq no_showcolor_lgx 1)
)
)
((or(= (cadr grd_lgx1) 13)(= (cadr grd_lgx1) 32))
(setq loopp_lgx nil)
)
)
)
((= (car grd_lgx1) 3);;;鼠标左键
(setq cal_date_lgx nil)
(setq midu_lgx (fix (* midu_lgx 0.8)))
)
((= (car grd_lgx1) 11);;;鼠标右键
;;;(setq loopp_lgx nil)
(setq cal_date_lgx nil)
(setq midu_lgx (fix (/ midu_lgx 0.8)))
)
)
)
(redraw)
(redraw delet_ss_lgx 1)
(command "erase" delet_ss_lgx "")
(setvar "cmdecho" cm_lgx)
(princ)
)
[/sell]

newer

VL的 getFirstDeriv 函数就是求切线

2. 
   
3. 语法
   
4. 
   
5.      (vlax-curve-getFirstDeriv curve-obj param)
   
6. 
   
7. 功能
   
8. 
   
9.   返回曲线在指定位置的一阶导数（在 WCS 中）。
   
10. 
    
11. 说明
    
12. 
    
13. 1）参数 curve-obj 为要测量的 VLA 对象。
    
14. 
    
15. 2）参数 param 为数值，指定曲线上的参数。
    
16. 
    
17. 返回值：
    
18. 
    
19. 若成功则返回三维矢量表，否则返回 nil。
    
20. 
    
21. 范例
    
22. 
    
23. 假定 splineObj 指向 vlax-curve-getDistAtParam 范例中的样条曲线。
    
24. 
    
25. 1）使用 vlax-curve-getStartParam 获取曲线的开始参数：
    
26. 
    
27. _$ (setq stparameter  (vlax-curve-getStartParam splineObj))
    
28. 
    
29. 0.0
    
30. 
    
31. 2）获取曲线的结束参数：
    
32. 
    
33. _$ (setq endparameter (vlax-curve-getEndParam splineObj))
    
34. 
    
35. 18.2920
    
36. 
    
37. 3）确定沿曲线中点参数的 一阶导数：
    
38. 
    
39. _$ (vlax-curve-getFirstDeriv splineObj
    
40. 
    
41.   ( / (- endparameter stparameter) 2))
    
42. 
    
43. (0.622631 -3.25251 0.0)
    

<br /> 语法<br /> <br />      (vlax-curve-getFirstDeriv curve-obj param)<br /> <br /> 功能<br /> <br />   返回曲线在指定位置的一阶导数（在 WCS 中）。<br /> <br /> 说明<br /> <br /> 1）参数 curve-obj 为要测量的 VLA 对象。<br /> <br /> 2）参数 param 为数值，指定曲线上的参数。<br /> <br /> 返回值：<br /> <br /> 若成功则返回三维矢量表，否则返回 nil。<br /> <br /> 范例<br /> <br /> 假定 splineObj 指向 vlax-curve-getDistAtParam 范例中的样条曲线。<br /> <br /> 1）使用 vlax-curve-getStartParam 获取曲线的开始参数：<br /> <br /> _$ (setq stparameter  (vlax-curve-getStartParam splineObj))<br /> <br /> 0.0<br /> <br /> 2）获取曲线的结束参数：<br /> <br /> _$ (setq endparameter (vlax-curve-getEndParam splineObj))<br /> <br /> 18.2920<br /> <br /> 3）确定沿曲线中点参数的 一阶导数：<br /> <br /> _$ (vlax-curve-getFirstDeriv splineObj <br /> <br />   ( / (- endparameter stparameter) 2))<br /> <br /> (0.622631 -3.25251 0.0)<br />

lgx9612

谢谢大师的指教!谢谢!

newer

lgx9612 发表于 2016-6-14 22:47
谢谢大师的指教!谢谢!

不必客气，vlax-curve-getsecondderiv 求曲线上点的二阶导数，也就是法向量，也是切向量的垂向量。这个法向量的长度等于该点的“曲率半径”。

lucas3

刘师傅，模具上也要用到这个吗、

lucas3

刘师傅，有没有自动图框的程 序？我对这个比较感兴趣

lgx9612

lucas3 发表于 2016-6-14 23:33
刘师傅，有没有自动图框的程 序？我对这个比较感兴趣

工具是有的
安装版    http://pan.baidu.com/s/1nvGRWHb
解压缩版 http://pan.baidu.com/s/1b2LaJO

lucas3

lgx9612 发表于 2016-6-15 17:06
工具是有的
安装版    http://pan.baidu.com/s/1nvGRWHb
解压缩版 http://pan.baidu.com/s/1b2LaJO

刘师傅，每家公司的图框都不一样， 图框类型不一样，如果能提供源码，那真是大功大德！

aeo

什么用的
挺好看

sai_st

好评 刚想用这个分析 ，好评

xvjiex

感谢分享曲线曲率梳