使用 Vla 方法的 Pline 反转

eachy · 发表于 2016-7-1 20:39:45

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

<div>
(defun c:tt (/ e n obj j p plst wlst sw ew bulges tf)
(if (setq e (car (entsel)))
(progn
(setq n (vlax-curve-getendparam e)
obj (vlax-ename->vla-object e)
j -1
tf (vlax-curve-isclosed e)
)
(if tf
(setq n (1- n))
)
;;构造逆序点表
(while (< j n)
(setq p (vlax-curve-getpointatparam e (setq j (1+ j)))
plst (cons (car p) (cons (cadr p) plst))
)
)
(setq j -1)
(while (< j n)
(vla-getwidth obj (setq j (1+ j)) 'sw 'ew)
(setq wlst (cons (list ew sw) wlst) ;_逆序宽度
bulges (cons (* -1 (vla-getbulge obj j)) bulges) ;_逆序bulge
)
)
(vlax-put obj 'Coordinates plst) ;_设置点
(setq j -1)
(mapcar (function
(lambda (a b)
(vla-setwidth obj (setq j (1+ j)) (car a) (cadr a)) ;_设置每段宽度
(vla-setbulge obj j b) ;_设置bulge )
)
)
(cdr wlst)
(cdr bulges)
)
(if tf
(progn
(vla-put-closed obj :vlax-true)
(vla-setbulge obj n (car bulges))
(vla-setwidth obj n (caar wlst) (cadar wlst))
)
)
)
)
(princ)
)

<div> 
(defun c:tt (/ e n obj j p plst  wlst sw ew bulges tf) 
  (if (setq e (car (entsel))) 
    (progn 
      (setq n        (vlax-curve-getendparam e) 
            obj        (vlax-ename->vla-object e) 
            j        -1 
            tf        (vlax-curve-isclosed e) 
      ) 
      (if tf 
        (setq n (1- n)) 
      ) 
      ;;构造逆序点表 
      (while (< j n) 
        (setq p           (vlax-curve-getpointatparam e (setq j (1+ j))) 
              plst (cons (car p) (cons (cadr p) plst)) 
        ) 
      ) 
      (setq j -1) 
      (while (< j n) 
        (vla-getwidth obj (setq j (1+ j)) 'sw 'ew) 
        (setq wlst   (cons (list ew sw) wlst) ;_逆序宽度 
              bulges (cons (* -1 (vla-getbulge obj j)) bulges) ;_逆序bulge 
        ) 
      ) 
      (vlax-put obj 'Coordinates plst) ;_设置点 
      (setq j -1) 
      (mapcar (function 
                (lambda        (a b) 
                  (vla-setwidth obj (setq j (1+ j)) (car a) (cadr a)) ;_设置每段宽度 
                  (vla-setbulge obj j b) ;_设置bulge ) 
                ) 
              ) 
              (cdr wlst) 
              (cdr bulges) 
      ) 
      (if tf 
        (progn 
          (vla-put-closed obj :vlax-true) 
          (vla-setbulge obj n (car bulges)) 
         (vla-setwidth obj n (caar wlst) (cadar wlst)) 
        ) 
      ) 
    ) 
  ) 
  (princ) 
)

sicky111 · 发表于 2016-7-1 23:31:02

可以做成一个子函数调用

HLCAD · 发表于 2016-7-2 08:04:24

这才是我们值得尊敬的“eachy”站长！从您那真的可以学到许多东西！谢谢！

479274135 · 发表于 2017-7-5 14:23:12

学习了

kqqt6236 · 发表于 2017-7-6 00:13:03

学习了，谢谢！

账号		自动登录	找回密码
密码			立即注册

[教学] 使用 Vla 方法的 Pline 反转

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

评分