怎么求曲线上不等间距的点

hhjxt66

各位大哥，已知一条样条曲线及线上一点，有没有什么方法可以找到线上这样一组点（如：知道第二个点距离第一个点500，第三个距居第二个点200，第四距第三1500，等等，这些点不等间距，且均在样条曲线上），用CAD定距等分太麻烦了，少数几个点还能等分，数量多了，效率低呢。这个有什么快速方法么？或者小插件么？小弟感激不尽，529702907@qq.com

hhjxt66

大哥些给点建议哦，在线等

hhjxt66

newer

hhjxt66 发表于 2016-10-28 21:38

你先说明下，这些点你想怎么交互输入给插件？ 每次需要做的间距肯定要不同吧。

newer

写个函数吧

(defun XD::Curve:GetPointsAtDistGroup (e pt disl / dis1 p1 pts x)
  (if (not (setq dis1 (vlax-curve-getdistatpoint e pt)))
    (setq pt (vlax-curve-getClosestPointTo e pt)
          dis1 (vlax-curve-getdistatpoint e pt)
    )
  )
  (setq pts (list pt))
  (mapcar
    '(lambda (x)
       (if (setq p1 (vlax-curve-getpointatdist e (setq dis1 (+ dis1 x))))
         (setq pts (cons p1 pts))
       )
     )
    disl
  )
  (reverse pts)
)

(setq a (XD::CURVE:GETPOINTSATDISTGROUP e p1 '(100 200 300 400)))
((2865.54 773.647 0.0) (2873.57 873.299 0.0) (2964.42 1031.75 0.0) (3210.97
865.563 0.0) (3511.21 931.797 0.0))

hhjxt66

newer 发表于 2016-10-28 22:14

比如知道曲线上第一个点，我想在曲线上找到距该点500的第二点，然后距第二点750的第三点....我只用输入这些距离，程序能找到这些点?这可以么？

hhjxt66

newer 发表于 2016-10-28 22:32

这函数怎么用啊，兄弟

hhjxt66

我好好研究下这程序，汗颜了，谢谢newer

newer

hhjxt66 发表于 2016-10-30 03:01

上面不是给你用法了嘛

(setq a (XD::CURVE:GETPOINTSATDISTGROUP e p1 '(100 200 300 400)))
((2865.54 773.647 0.0) (2873.57 873.299 0.0) (2964.42 1031.75 0.0) (3210.97
865.563 0.0) (3511.21 931.797 0.0))


'(100 200 300 400) 这个里面的数字就是你说的那些距离，你改这个就行了

newer

函数修改了下

(defun XD::Curve:GetPointsAtDistGroup (e pt disl / dis1 p1 pts x)
  (if (not (setq dis1 (vlax-curve-getdistatpoint e pt)))
    (setq pt (vlax-curve-getClosestPointTo e pt)
          dis1 (vlax-curve-getdistatpoint e pt)
    )
  )
  (setq pts (list pt))
  (mapcar
    '(lambda (x)
       (if (and (setq p1 (vlax-curve-getpointatdist e (setq dis1 (+ dis1 x))))
                (not (equal p1 (vlax-curve-getstartpoint e)))
           )
         (setq pts (cons p1 pts))
       )
     )
    disl
  )
  (reverse pts)
)

下面是用这个函数写的插件，根据你输入的数据，在间隔点上画个圆。 安装 XDRX_API 环境后，执行TT

(defun c:tt()
    (if (and (/= "" (setq disl (getstring "\n输入距离间隔（逗号分隔）<退出>:")))
             (setq disl (xdrx_string_regexps "[^,]+" disl))
             (setq e (car (xdrx_entsel "\n选取曲线<退出>:" '((0 . "*LINE,ELLIPSE,CIRCLE,ARC")))))
             (setq pt (getpoint "\n点取开始点<退出>:"))
        )
      (progn
        (setq disl (mapcar 'atof disl))
        (setq pt (xdrx_curve_getclosestpoint e pt))
        (setq pts (XD::Curve:GetPointsAtDistGroup e pt disl)
              r (/ (car disl) 3.0)
        )
        (mapcar '(lambda(x)(xdrx_circle_make x r)) pts)
      )
    )
    (princ)
)

hhjxt66

newer 发表于 2016-10-30 13:05

嗯，我要的就是这种效果，运行了下有错误，这咋整啊
命令: tt
输入距离间隔（逗号分隔）<退出>:100,200,600
选取曲线<退出>:
点取开始点<退出>: <对象捕捉 开>
错误: no function definition: XD::CURVE:GETPOINTSATDISTGROUP

newer

hhjxt66 发表于 2016-10-30 19:58

你把上面两个代码都加载啊。

提示你缺的函数，就是第一段代码。

hhjxt66

newer 发表于 2016-10-30 20:48

可以啦，辛苦了newer！谢谢

newer

hhjxt66 发表于 2016-10-30 21:24

这个工作中你主要做什么用啊？ 如果会，做个动画文件传上来吧。

hhjxt66

newer 发表于 2016-10-30 21:28

主要做建筑结构设计，这个功能常用的，特别路桥领域，这个不错的