把LINE的坐标输出到已经打开的EXCEL文件中

marting

(defun c:test(/ doc ent lin xls wks)
  (setq doc (vla-get-activedocument (vlax-get-acad-object)))
  (vla-startundomark doc)
  (and (ssget '((0 . "LINE")))
    (progn
      (setq xls (vlax-get-or-create-object "Excel.Application"))
      (or (setq wks (vlax-get xls 'ActiveSheet))
        (vlax-invoke (vlax-get xls 'workbooks) 'Add)
      )
      (setq wks (vlax-get xls 'ActiveSheet)
            lin 2
      )
      (vlax-put xls 'Visible :vlax-true)
      (vlax-put (vlax-get-property wks 'range "A1") 'value "StartPoint")
      (vlax-put (vlax-get-property wks 'range "B1") 'value "EndPoint")
      (vlax-for ent (setq sel (vla-get-activeselectionset doc))
        (vlax-put (vlax-get-property wks 'range (strcat "A" (itoa lin))) 'value (trans (vlax-get ent 'startpoint) 1 0))
        (vlax-put (vlax-get-property wks 'range (strcat "B" (itoa lin))) 'value (trans (vlax-get ent 'endpoint) 1 0))
        (setq lin (1+ lin))
      )
      (vla-delete sel)
      (mapcar 'vlax-release-object (list wks xls))
      (gc)(gc)
    )
  )
  (vla-endundomark doc)
  (princ)
)

/db_自贡黄明儒_

不错。如果第二次执行不覆盖前一次的结果就更好了。

(vl-load-com)
(defun c:MyExcel (/ E FIL OBJ ROW SS USEDRANGE)
  (or *ACAD* (setq *ACAD* (vlax-get-acad-object)))
  (or *DOC* (setq *DOC* (vla-get-ActiveDocument *ACAD*)))
  (_StartUndo *DOC*)
  (or *excel* (setq *excel* (vlax-get-or-create-object "excel.application")))
  (or *ActiveSheet*
      (setq *ActiveSheet* (vlax-get *excel* 'ActiveSheet))
      (vlax-invoke (vlax-get *excel* 'workbooks) 'Add)
  )

  (vlax-invoke *excel* 'CalculateFullRebuild);此句希望下面的Row每次不同，但未成功
  (setq *ActiveSheet* (vlax-get *excel* 'ActiveSheet))
  (setq UsedRange (vlax-get *ActiveSheet* 'UsedRange))
  (setq Row (vlax-get UsedRange 'Row))  
  (setq        fil '((-4 . "<or")
              (0 . "LINE")
              (-4 . "<AND")
              (0 . "LWPOLYLINE")
              (90 . 2)
              (-4 . "AND>")
              (-4 . "or>")
             )
  )

  (while (setq ss (ssget ":S" fil))
    (repeat (sslength ss)
      (setq e (ssname ss 0))
      (setq obj (vlax-ename->vla-object e))
      (setq Row (1+ Row))
      (vlax-put        (vlax-get-property *ActiveSheet* 'range (strcat "A" (itoa Row)))
                'value
                (vlax-get obj 'startpoint)
      )
      (vlax-put        (vlax-get-property *ActiveSheet* 'range (strcat "B" (itoa Row)))
                'value
                (vlax-get obj 'endpoint)
      )
      (vlax-put        (vlax-get-property *ActiveSheet* 'range (strcat "C" (itoa Row)))
                'value
                (vlax-get obj 'Length)
      )
      (ssdel e ss)
    )
  )

  (vlax-put *excel* 'Visible :vlax-true)

  ;;(vlax-release-object *ActiveSheet*)
  (_EndUndo *DOC*)
  (princ)
)

(vlax-invoke *excel* 'CalculateFullRebuild);此句希望下面的Row每次不同，但未成功
土办法是将row设置成全局变量，但不是很爽。

SHUNDocker

学习学习，感谢楼主！！！