entmakex 创建图层

Lisphk

一、最基本的

(defun _layer ( name )
    (if (null (tblsearch "LAYER" name))
        (entmake
            (list
               '(0 . "LAYER")
               '(100 . "AcDbSymbolTableRecord")
               '(100 . "AcDbLayerTableRecord")
               '(70 . 0)
                (cons 2 name)
            )
        )
    )
)

测试代码

(defun c:test ( / )
    (foreach layer
       '(
            "Layer1"
            "Layer2"
            "Layer3"
        )
        (_layer layer)
    )
    (princ)
)

二、增加颜色属性

(defun _layer2 ( name colour )
    (if (null (tblsearch "LAYER" name))
        (entmake
            (list
               '(0 . "LAYER")
               '(100 . "AcDbSymbolTableRecord")
               '(100 . "AcDbLayerTableRecord")
               '(70 . 0)
                (cons 2 name)
                (cons 62 colour)
            )
        )
    )
)

三，增加 颜色、线型、线宽、打印属性

(defun _layer4 ( name colour linetype lineweight plot )
    (if (null (tblsearch "LAYER" name))
        (entmake
            (list
               '(0 . "LAYER")
               '(100 . "AcDbSymbolTableRecord")
               '(100 . "AcDbLayerTableRecord")
               '(70 . 0)
                (cons 2 name)
                (cons 6
                    (if (tblsearch "LTYPE" linetype)
                        linetype
                        "Continuous"
                    )
                )
                (cons 62 colour)
                (cons 290 plot)
                (cons 370 lineweight)
            )
        )
    )
)

四，最终版

(defun _CreateLayer ( name color ltype lnwt plot )
    (
        (lambda ( _function )
            (_function
                (list
                   '(0 . "LAYER")
                   '(100 . "AcDbSymbolTableRecord")
                   '(100 . "AcDbLayerTableRecord")
                   '(70 . 0)
                    (cons   2 name)
                    (cons   6 (if (tblsearch "LTYPE" ltype) ltype "Continuous"))
                    (cons  62 color)
                    (cons 290 plot)
                    (cons 370 lnwt)
                )
            )
        )
        (if (tblsearch "LAYER" name)
            (lambda ( data ) (entmod (cons (cons -1 (tblobjname "LAYER" name)) data)))
            entmakex
        )
    )
)

Lisphk

LAYER 的 DXF 参考

LAYER

The following group codes apply to LAYER symbol table entries. In addition to the group codes described here, see Common Group Codes for Symbol Table Entries. For information about abbreviations and formatting used in this table, see Formatting Conventions in This Reference.

LAYER group codes
Group code	Description
100	Subclass marker (AcDbLayerTableRecord)
2	Layer name
70	Standard flags (bit-coded values): 1 = Layer is frozen; otherwise layer is thawed 2 = Layer is frozen by default in new viewports 4 = Layer is locked 16 = If set, table entry is externally dependent on an xref 32 = If both this bit and bit 16 are set, the externally dependent xref has been successfully resolved 64 = If set, the table entry was referenced by at least one entity in the drawing the last time the drawing was edited. (This flag is for the benefit of AutoCAD commands. It can be ignored by most programs that read DXF files and need not be set by programs that write DXF files)
62	Color number (if negative, layer is off)
6	Linetype name
290	Plotting flag. If set to 0, do not plot this layer
370	Lineweight enum value
390	Hard-pointer ID/handle of PlotStyleName object
347	Hard-pointer ID/handle to Material object

Xref-dependent layers are output during SAVEAS. For these layers, the associated linetype name in the DXF file is always CONTINUOUS.

yufeng37

啥也不说了，感谢楼主分享哇！

yanchao316

啥也不说了，感谢楼主分享哇！

longer1000

啥也不说了，感谢楼主分享哇！

zjy2999

多谢！！！！

sicky111

楼上清一色的灌水。

zhangq_cai1

正需要，支持楼主大人了！

bbbxxxccclt

太感谢了：正在找   

/db_自贡黄明儒_

_layer4会发生错误的吧

snow15338

请问线宽0.15  要怎么设置组码370？

229096767

snow15338 发表于 2022-12-3 10:22
请问线宽0.15  要怎么设置组码370？

线宽0.15   (370 . 15)