style字体中的属性如何修改？

挚友01

(setq tem_1 (tblnext "STYLE" T))
(while tem_1   
； 可提取DWG文件所有字体的属性，但如何修改某个字体中的单个属性呢，如倾斜角
用(entmod (subst (cons (car (assoc...可以吗?

marting

entmod当然可以。

挚友01

entmod是对选择的实体进行修改，可...
如何修改，怎么编写。。。先谢了

marting

挚友01 发表于 2017-1-23 11:00

你想修改什么？ entmod不只是修改实体，

挚友01

我要一次性将资料图中的字体某个属性一次性修改，类似于循环style

st788796

STYLE 组码

组码
说明

100
子类标记 (AcDbTextStyleTableRecord)

2
样式名

70
标准标记值（按位编码值）：

1 = 如果设置了此位，则此条目用于说明形

4 = 垂直文字

16 = 如果设置了此位，则表条目外部依赖于外部参照

32 = 如果同时设置了此位和位 16，则表明已成功融入了外部依赖的外部参照

64 = 如果设置了此位，则表明在上次编辑图形时，图形中至少有一个图元参照了表条目。（此标志对 AutoCAD 命令很有用。大多数读取 DXF 文件的程序都可以忽略它，并且无需由写入 DXF 文件的程序对其进行设置）

40
固定的文字高度；如果文字高度未固定，则为 0

41
宽度因子

50
倾斜角度

71
文字生成标志：

2 = 反向文字（镜像 X）

4 = 倒置文字（镜像 Y）

42
上次使用的高度

3
主要字体文件名

4
大字体文件名；如果无，则为空


STYLE 表项目也可用来记录 LOAD 命令请求的形文件。这种情况下，在 70 组标志中设置第一位 (1)，并且只有 3 组（形文件名）有意义（其他所有组均为输

marting

挚友01 发表于 2017-1-23 11:13

下面代码把文字样式STANDARD的宽度因子改成0.777

(defun c:tt ()
  (if (setq styl (tblobjname "style" "standard"))
    (progn
      (setq ed (entget styl)
            old (assoc 41 ed)
            new (cons 41 0.777)
            ed (subst
                 new
                 old
                 ed
               )
      )
      (entmod ed)
    )
  )
  (princ)
)

st788796

ObliqueAngle

Double; read-write
The angle in radians within the range of -85 to +85 degrees. A positive angle denotes a lean to the right; a negative value will have 2*PI added to it to convert it to its positive equivalent.

Remarks

The oblique angle is the object's "angle of slant" away from its vertical axis.

挚友01

非常感谢，我试试

挚友01

(defun c:1 ()
(setq tem_1 (tblnext "STYLE" T))
(while tem_1
  (if (/= (cdr (assoc 40 tem_1)) 0)
    (entmod (subst (cons 40 0) (assoc 40 tem_1) tem_1))
  )
  (setq tem_1 (tblnext "STYLE"))
)         
(princ)
)
没反映.... ???????

marting

挚友01 发表于 2017-1-23 12:14

你查看下 (tblnext "STYLE" T)返回的是什么？
(tblnext "STYLE" T)
((0 . "STYLE") (2 . "Standard") (70 . 0) (40 . 3.0) (41 . 0.66) (50 . 0.785398)
(71 . 0) (42 . 2.5) (3 . "txt") (4 . "gbcbig.shx"))


是表，你要得到每个样式的实体名，然后修改entget的表才行

挚友01

成了，非常感谢，当时我就没明白怎么获取“实体名”，再次表示感谢，说的很明白，很让人能理解^0^
下次有不明白的问题就请教您了，哈哈
(defun c:1 ()
(setq tem_1 (tblnext "STYLE" T))
(while tem_1
  (if (/= (cdr (assoc 40 tem_1)) 0)
    (progn
       (setq tem_1 (entget (tblobjname (cdr (assoc 0 tem_1)) (cdr (assoc 2 tem_1)))))
       (entmod (subst (cons 40 0) (assoc 40 tem_1) tem_1))
    )
  )
(setq tem_1 (tblnext "STYLE"))
)         
(princ)
)

Lisphk

挚友01 发表于 2017-1-23 12:14

(defun c:1 ()
  (setq tem_1 (tblnext "STYLE" T))
  (while tem_1
    (if        (/= (cdr (assoc 40 tem_1)) 0)
      (progn
        (setq e         (tblobjname "style" (cdr (assoc 2 tem_1)))
              ed (entget e)
        )
        (entmod (subst (cons 40 0) (assoc 40 ed) ed))
      )
    )
    (setq tem_1 (tblnext "STYLE"))
  )
  (princ)
)

或者：

(defun c:tt ()
  (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
  (vlax-for styl (vla-get-textstyles adoc)
    (vla-put-height styl 0.0)
  )
  (princ)
)

st788796

tblnext不对