转义通配符

marting · 发表于 2017-5-9 15:24:58

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

本帖最后由 marting 于 2017-5-9 17:40 编辑

SSGET的一些字符串是统配符，比如. # , *等等，如果要过滤的字符串中包括这些，会过滤不到，用下面这个函数转义下就OK 了。

(defun XD::STRING:Escapewildcards (str / tf)
(vl-list->string (apply
'append
(mapcar
'(lambda (c)
(if (or
(> c 128)
tf
)
(progn
(if (not tf)
(setq tf t)
(setq tf nil)
)
(list c)
)
(progn
(setq tf nil)
(if (member c '(35 64 46 42 63 126 91 93 45 44))
(list 96 c)
(list c)
)
)
)
)
(vl-string->list str)
)
)
)
)

(defun XD::STRING:Escapewildcards (str / tf) 
  (vl-list->string (apply 
                     'append 
                     (mapcar 
                       '(lambda (c) 
                          (if (or 
                                (> c 128) 
                                tf 
                              ) 
                            (progn 
                              (if (not tf) 
                                (setq tf t) 
                                (setq tf nil) 
                              ) 
                              (list c) 
                            ) 
                            (progn 
                              (setq tf nil) 
                              (if (member c '(35 64 46 42 63 126 91 93 45 44)) 
                                (list 96 c) 
                                (list c) 
                              ) 
                            ) 
                          ) 
                        ) 
                       (vl-string->list str) 
                     ) 
                   ) 
  ) 
)

命令: (XD::STRING:ESCAPEWILDCARDS "建筑#34.2设计,CAD")
"建筑`#34`.2设计`,CAD"

YueFeng · 发表于 2017-5-9 17:06:29

(defun $YF_StrEscapewildcards (str / strlst n result var)
(setq strlst (vl-string->list str)
 n 0
 result '()
)
(repeat (length strlst)
 (setq var (nth n strlst))
 (if
 (and
 (member var '(35 64 46 42 63 126 91 93 45 44))
 (> n 0)
 (< (nth (1- n) strlst) 127)
 )
 (setq result (append result (list 96 var)))
 (setq result (append result (list var)))
 )
 (setq n (1+ n))
)
(vl-list->string result)
)

111121111111111 · 发表于 2017-5-9 15:50:33

YueFeng · 发表于 2017-5-9 16:19:48

(vl-list->string '(180 64))
双字符的汉字有问题

marting · 发表于 2017-5-9 16:25:11

YueFeng 发表于 2017-5-9 16:19

举个函数调用的完整例子，看看转什么样了？转义符ASCII应该不在汉字的ASCII内。

命令: (XD::STRING:ESCAPEWILDCARDS "建#.筑#34.2设计,CAD")
"建`#`.筑`#34`.2设计`,CAD"

把你出错的字符列下看看

HLCAD · 发表于 2017-5-9 16:54:52

大师，确实有BUG的，如:
(XD::STRING:Escapewildcards "碄") ==》 "碻@"

YueFeng · 发表于 2017-5-9 17:04:38

汉字是双字节的ascii码

YueFeng · 发表于 2017-5-9 17:07:11

($YF_StrEscapewildcards "碄#.3.14")
"碄`#`.3`.14"

marting · 发表于 2017-5-9 17:27:30

本帖最后由 marting 于 2017-5-9 17:42 编辑

YueFeng 发表于 2017-5-9 16:19

修改了代码，拷贝回去再试试

命令: (vl-list->string '(180 64))
"碄"

命令: (XD::STRING:Escapewildcards "碄.建筑12.334设计#")
"碄`.建筑12`.334设计`#"

原地踏步 · 发表于 2017-5-16 09:14:56

YueFeng版主的程序更简洁，但marting的速度更快

账号		自动登录	找回密码
密码			立即注册

[字符串] 转义通配符

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

评分