设置动态块的属性值

marting · 发表于 2017-5-19 13:29:40

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

(defun set-dynprop (blk prop value / def err)
;|
blk pointer to block reference
prop dynmic property name
value value to set to prop
call sample:
(set-dynprop (car (entsel "\nSelect block")) "base" 2)
|;
(if (and (setq blk (cond
((= (type blk) 'ename)
(setq blk (vlax-ename->vla-object blk))
)
((= (type blk) 'vla-object) blk)
) ;_ end of cond
) ;_ end of setq
(= (vla-get-objectname blk) "AcDbBlockReference")
(vlax-method-applicable-p blk 'getdynamicblockproperties)
(setq def (car (vl-remove-if-not
(function
(lambda (x)
(= (strcase prop) (strcase (vla-get-propertyname x)))
) ;_ end of LAMBDA
) ;_ end of function
(vlax-safearray->list (vlax-variant-value (vla-getdynamicblockproperties blk)))
) ;_ end of vl-remove-if-not
) ;_ end of car
) ;_ end of setq
) ;_ end of and
(if (vl-catch-all-error-p
(setq err (vl-catch-all-apply
(function
(lambda ()
(vla-put-value def value)
) ;_ end of LAMBDA
) ;_ end of function
) ;_ end of VL-CATCH-ALL-APPLY
) ;_ end of setq
) ;_ end of VL-CATCH-ALL-ERROR-P
(princ (strcat "\nError setting value "
(vl-princ-to-string value)
" to property \""
prop
"\" : "
(vl-catch-all-error-message err)
) ;_ end of strcat
) ;_ end of princ
) ;_ end of if
) ;_ end of if
) ;_ end of defun

(defun set-dynprop (blk prop value / def err) 
                   ;| 
blk    pointer to block reference 
prop   dynmic property name 
value  value to set to prop 
 
call sample: 
(set-dynprop (car (entsel "\nSelect block")) "base" 2) 
|; 
  (if (and (setq blk (cond 
                       ((= (type blk) 'ename) 
                        (setq blk (vlax-ename->vla-object blk)) 
                        ) 
                       ((= (type blk) 'vla-object) blk) 
                       ) ;_ end of cond 
                 ) ;_ end of setq 
           (= (vla-get-objectname blk) "AcDbBlockReference") 
           (vlax-method-applicable-p blk 'getdynamicblockproperties) 
           (setq def (car (vl-remove-if-not 
                            (function 
                              (lambda (x) 
                                (= (strcase prop) (strcase (vla-get-propertyname x))) 
                                ) ;_ end of LAMBDA 
                              ) ;_ end of function 
                            (vlax-safearray->list (vlax-variant-value (vla-getdynamicblockproperties blk))) 
                            ) ;_ end of vl-remove-if-not 
                          ) ;_ end of car 
                 ) ;_ end of setq 
           ) ;_ end of and 
    (if (vl-catch-all-error-p 
          (setq err (vl-catch-all-apply 
                      (function 
                        (lambda () 
                          (vla-put-value def value) 
                          ) ;_ end of LAMBDA 
                        ) ;_ end of function 
                      ) ;_ end of VL-CATCH-ALL-APPLY 
                ) ;_ end of setq 
          ) ;_ end of VL-CATCH-ALL-ERROR-P 
      (princ (strcat "\nError setting value " 
                     (vl-princ-to-string value) 
                     " to property \"" 
                     prop 
                     "\" : " 
                     (vl-catch-all-error-message err) 
                     ) ;_ end of strcat 
             ) ;_ end of princ 
      ) ;_ end of if 
    ) ;_ end of if 
  ) ;_ end of defun

kqqt6236 · 发表于 2017-5-20 00:10:37

谢谢分享！

sh_h · 发表于 2017-6-26 13:32:05

大师，这个怎么用啊？...

aeo · 发表于 2017-6-26 15:25:39

(vla-put-value def value) 可以直接赋值value呀 !?
不是应该是Variant吗？

yoyoho · 发表于 2017-6-26 17:43:24

谢谢分享学习！

sicky111 · 发表于 2017-7-4 00:07:03

这个有用。

lxw0320 · 发表于 2019-9-23 12:44:00

这个很好，可以参考

Yruz · 发表于 2019-9-23 14:38:11

不错，很好很有用

代敬龙 · 发表于 2020-2-5 22:49:06

谢谢，下载，学习，下，

账号		自动登录	找回密码
密码			立即注册

[每日一码] 设置动态块的属性值

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。