打开锁定冻结图层

wowan1314

今天发现有些图纸里面我的图层命令不能用了！   

用VLISP重新编了下。 对VLISP不熟悉，不知道编的对不对，但是能用！

;;选层关闭
(defun c:t1 nil (prompt "\n选层关闭")(yylayset 1))
;;非选层关闭
(defun c:t11 nil (prompt "\n非选层关闭")(yylaysetf 1))
;;打开所有
(defun c:t111 nil (prompt "\n打开所有")(yylaysetall 1))
;;选层锁定
(defun c:t2 nil (prompt "\n选层锁定")(yylayset 2))
;;非选层锁定
(defun c:t22 nil (prompt "\n非选层锁定")(yylaysetf 2))
;;解锁所有
(defun c:t222 nil (prompt "\n解锁所有")(yylaysetall 2))
;;选层冻结
(defun c:t3 nil (prompt "\n选层冻结")(yylayset 3))
;;---图层函数定义------------------------
(defun yylaysel (/ ss en i la oldla)
    (setq ss (ssget) i 0)
    (if ss
        (while (setq en (ssname ss i))
            (setq la (cdr(assoc 8 (entget en))) i(1+ i))
            (if oldla (setq oldla (strcat la "," oldla))(setq oldla la))
        )
    )
    oldla
)
;;所有图层(打开 解锁)
(defun yylaysetall (key)
    (vlax-for tem (vla-get-layers(yy:doc))
        (cond
            ((= key 1) (vla-put-layeron tem :vlax-true))
            ((= key 2) (vla-put-lock tem :vlax-false))
        )
    )
    (princ)
)
;;选层(关闭 锁定 冻结)
(defun yylayset (key / la)
    (setq la (yylays))
    (if la
        (vlax-for tem (vla-get-layers(yy:doc))
            (if (wcmatch (vla-get-name tem) la)
                (cond
                    ((= key 1) (vla-put-layeron tem :vlax-false))
                    ((= key 2) (vla-put-lock tem :vlax-true))
                    ((= key 3) (vla-put-freeze tem :vlax-true))
                )
            )
        )
    )
    (princ)
)
;;非选层(关闭 锁定)
(defun yylaysetf (key / la)
    (setq la (yylays))
    (if la
        (vlax-for tem (vla-get-layers(yy:doc))
            (if (wcmatch (vla-get-name tem) la)
                (cond
                    ((= key 1) (vla-put-layeron tem :vlax-true))
                    ((= key 2) (vla-put-lock tem :vlax-false))
                )
                (cond
                    ((= key 1) (vla-put-layeron tem :vlax-false))
                    ((= key 2) (vla-put-lock tem :vlax-true))
                )
            )
        )
    )
    (princ)
)

wowan1314

marting 发表于 2017-5-25 22:49

忍不住，在家完善了下。
;;--------------------------[图层函数定义]------------------------;;
;;(yy:doc)-->返回:当前激活文档对象
(defun yy:doc nil
    (eval
        (list 'defun
            'yy:doc
            'nil
            (vla-get-activedocument (vlax-get-acad-object))
        )
    )
    (yy:doc)
)
;;汇总选层函数
(defun yylaysel (/ ss en i la oldla)
    (setq ss (ssget) i 0)
    (if ss
        (while (setq en (ssname ss i))
            (setq la (cdr(assoc 8 (entget en))) i(1+ i))
            (if oldla (setq oldla (strcat la "," oldla))(setq oldla la))
        )
    )
    oldla
)
;;所有图层(打开 解锁 解冻)函数
(defun yylaysetall (key)
    (vlax-for tem (vla-get-layers(yy:doc))
        (cond
            ((= key 1) (vla-put-layeron tem :vlax-true))
            ((= key 2) (vla-put-lock tem :vlax-false))
            ((= key 3) (vl-catch-all-apply 'vla-put-freeze (list tem :vlax-false)))
        )
    )
    (princ)
)
;;选层(关闭 锁定 冻结)函数
(defun yylayset (key / la)
    (setq la (yylaysel))
    (if la
        (vlax-for tem (vla-get-layers(yy:doc))
            (if (wcmatch (vla-get-name tem) la)
                (cond
                    ((= key 1) (vla-put-layeron tem :vlax-false))
                    ((= key 2) (vla-put-lock tem :vlax-true))
                    ((= key 3)
                        (if (= (vla-get-name tem) (getvar "clayer"))
                            (princ(strcat "\n无法冻结当前图层 " (getvar "clayer")))
                            (vla-put-freeze tem :vlax-true)
                        )
                    )
                )
            )
        )
    )
    (princ)
)
;;非选层(关闭 锁定 冻结)函数
(defun yylaysetf (key / la)
    (setq la (yylaysel))
    (if la
        (vlax-for tem (vla-get-layers(yy:doc))
            (if (wcmatch (vla-get-name tem) la)
                (cond
                    ((= key 1) (vla-put-layeron tem :vlax-true))
                    ((= key 2) (vla-put-lock tem :vlax-false))
                    ((= key 3) (vl-catch-all-apply 'vla-put-freeze (list tem :vlax-false)))
                )
                (cond
                    ((= key 1) (vla-put-layeron tem :vlax-false))
                    ((= key 2) (vla-put-lock tem :vlax-true))
                    ((= key 3)
                        (if (= (vla-get-name tem) (getvar "clayer"))
                            (princ(strcat "\n无法冻结当前图层 " (getvar "clayer")))
                            (vla-put-freeze tem :vlax-true)
                        )
                    )
                )
            )
        )
    )
    (princ)
)
;;;---------------------------[选层关闭]--------------------------
(defun c:t1 nil (prompt "\n选层关闭")(yylayset 1))
;;;---------------------------[非选层关闭]--------------------------
(defun c:t11 nil (prompt "\n非选层关闭")(yylaysetf 1))
;;;---------------------------[打开所有层]--------------------------
(defun c:t111 nil (prompt "\n打开所有")(yylaysetall 1))
;;;---------------------------[选层锁定]--------------------------
(defun c:t2 nil (prompt "\n选层锁定")(yylayset 2))
;;;---------------------------[非选层锁定]--------------------------
(defun c:t22 nil (prompt "\n非选层锁定")(yylaysetf 2))
;;;---------------------------[解锁所有层]--------------------------
(defun c:t222 nil (prompt "\n解锁所有层")(yylaysetall 2))
;;;---------------------------[选层冻结]--------------------------
(defun c:t3 nil (prompt "\n选层冻结")(yylayset 3))
;;;---------------------------[非选层冻结]--------------------------
(defun c:t33 nil (prompt "\n非选层冻结")(yylaysetf 3))
;;;---------------------------[解冻所有层]--------------------------
(defun c:t333 nil (prompt "\n解冻所有层")(yylaysetall 3)(vla-Regen (yy:doc) acActiveViewport)(princ))

newer

多写VLISP代码，你就会喜欢她的。

很多，容器--提取单个---对单个操作， 符号表，块都这样，能写一大堆功能各异的工具了。

VLISP比LISP看着更结构化。

newer

缺 yylays 函数

wowan1314

yylays就是yylaysel手欠改了个名字。好像缺yy：doc。明天去公司再补充

wowan1314

本人及本专业对程序要求都不高。所以我的程序都只管能用即可。今天看了下90左右的命令有三百多个command。希望cad别瞎改就好。不然都得重写

marting

不知道冻结的时候是否判断了不对当前层操作，否则会错误退出的。

wowan1314

marting 发表于 2017-5-25 20:21

没判断。
本来冻结也写进代码了。不过发现有问题就删了，反正冻结用的不多。
如果只是对当前层不能操作还容易判断些。
明天再测试完善下吧

marting

wowan1314 发表于 2017-5-25 20:32

VLISP屏蔽错误，继续执行是很方便的

冻结的代码改成

(vl-catch-all-apply '(lambda nil (vla-put-freeze tem :vlax-true)))


就行了。

wowan1314

marting 发表于 2017-5-25 20:58

很巧妙的办法。不过我觉的简单的话还是给用户提示下比较好。

marting

wowan1314 发表于 2017-5-25 22:27

其实没必要提示，你目的是冻结选择的层。
如果想提示
那就：

1. (if (vl-catch-all-error-p (vl-catch-all-apply '(lambda nil (vla-put-freeze tem :vlax-true)))))
   
2.    (princ "\n不能冻结当前层.")
   
3. )
   

(if (vl-catch-all-error-p (vl-catch-all-apply '(lambda nil (vla-put-freeze tem :vlax-true)))))<br />    (princ "\n不能冻结当前层.")<br /> )<br />

453055586

大师，能否将锁定的图层颜色显淡

吴外安放

谢谢版主分享