【挑战】获取子表

newer

marting 发表于 2017-6-10 20:25

修改后提升显著，看图

1、正常数据在中间的表现



2、开始接近头



3、开始接近尾部



4、开始接近头NIL表现



5、开始接近尾部NIL表现



mt:sublist 是原来的
mt:sublist1是更新的

上面有自己和自己原来的比较。

原来开始接近开头的表现现在显著提升了（见第二个表），而且还是这些里面的成绩最好的。

marting

newer 发表于 2017-6-10 21:13

感谢，这个测试BENCH真不错，能发现问题。

tengteb

marting 发表于 2017-6-10 22:02
感谢，这个测试BENCH真不错，能发现问题。

mt:sublist1还可以优化一下i超过表长度的情况。

(defun mt:sublist2 (l i n / m s)
  (setq m (length l))
  (cond
    ((<= m i) nil) ;起点超过表长度
    ((progn
       (repeat (/ i 4) (setq l (cddddr l))) ;掐头
       (repeat (rem i 4) (setq l (cdr l))) ;掐头
       (not n) ;至表尾
     ) ;progn
      l
    )
    ((progn (setq m (- (length l) n)) (< m 0)) l) ;截取长度超过表长度(掐头后)，m--尾部长度
    ((< n m);截取长度小于尾部长度
     (repeat (/ n 4)
       (setq s (cons (cadddr l) (cons (caddr l) (cons (cadr l) (cons (car l) s))))
             l (cddddr l)
       )
     )
     (repeat (rem n 4)
       (setq s (cons (car l) s)
             l (cdr l)
       )
     )
     (reverse s)
    )
    (T
     (setq l (reverse l)) ;队尾变队首
     (repeat (/ m 4) (setq l (cddddr l)))
     (repeat (rem m 4) (setq l (cdr l)))
     (reverse l)
    )
  ) ;cond
)

tengteb

在mt:sublist1的基础上，按LL_j前辈的思路，再次优化：
(defun tb:sublist (l i n / canr cdnr m nn x z)

  (defun canr (l n / s)
    (repeat (/ n 4)
      (setq s (cons (cadddr l) (cons (caddr l) (cons (cadr l) (cons (car l) s))))
            l (cddddr l)
      )
    )
    (repeat (rem n 4)
      (setq s (cons (car l) s)
            l (cdr l)
      )
    )
    (reverse s)
  ) ;defun
  (defun cdnr (l n)
    (repeat (/ n 4) (setq l (cddddr l)))
    (repeat (rem n 4) (setq l (cdr l)))
    l
  ) ;defun
  (setq z (length l))
  (cond
    ((>= i z) nil) ;起点超过表长度或截取长度小于1
    ((progn
       (or n (setq n (- z i)))
       (< n 1)
     ) ;progn
     nil
    )
    ((progn
       (setq m (- z i n))
       (if (< m 0)
         (setq n (+ n m)
               m 0
         )
       ) ;if
       (setq nn (* n 3.1) ;cdnr与canr速度修正系数
             x  (max i nn m)
       )
       (= x nn) ;截取部分修正长度最长
     ) ;progn
     (reverse (cdnr (reverse (cdnr l i)) m))
    )
    ((= x m) ;尾部最长
     (canr (cdnr l i) n)
    )
    (T (reverse (canr (cdnr (reverse l) m) n))) ;首部最长
  ) ;cond
)