64位的cad2014，xdrx_PickSet_dragGen输入距离没有返回值

liuyj · 发表于 2017-8-20 11:14:29

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

先(xdrx_drag_initget (+ 2 4 8 16 128 512 65536) st)，xdrx_PickSet_dragGen函数R18x64的可以直接输入距离，再用xdrx_drag_getlastMatrix得到一个矩阵，但R19x64返回值为nil。0818的API仍未解决，自由拷贝和自由移动无法输入距离。

newer · 发表于 2017-8-20 12:42:57

2016你试了吗，手里没2014

newer · 发表于 2017-8-20 12:49:58

你自己修改了自由拷贝的代码？

现在工具箱的自由拷贝也不让输入距离啊。

如果你修改了代码，把完整代码贴上来。

liuyj · 发表于 2017-8-20 13:34:30

修改的地方请N版多指教

(defun XD::Pickset:Drag (ss pj mode cursor tf /
ang box initget-str k1 k2
k3 m mmatrot mmattrans mrmatrix
mtmatrix mtmatrix0 mtmatrix2 n
pj1 prompt1 promptl pt pt1 pt2
pt3 pt4 scl ss1 tf1
escape-down entlist entlist1 entlist2 vdir
zdir1
)
(xdrx_begin)
(xdrx_SysVar_Push '("osmode" 2727) '("CURSORSIZE" 5))
(xdrx_document_ucson)
(if (not pj)
(progn (setq box (xdrx_entity_box ss)
pj (car box)
)
)
)
(setq promptl (list '(1 "改基点[T]" "T")
'(2 "改转角[R]" "R")
'(4 "转90度[A]" "A")
'(8 "镜像[M]" "M")
'(16 "左右翻[S]" "S")
'(32 "上下翻[D]" "D")
'(256 "缩放[L]" "L")
'(512 "对齐[F]" "F")
'(4096 "回退[U]" "U")
)
)
(setq prompt1 "\n插入点或{")
(setq initget-str " ")
(setq mode (+ 4096 mode))
(foreach n promptl
(setq k1 (car n)
k2 (cadr n)
k3 (caddr n)
)
(if (/= (logand mode k1) 0)
(setq initget-str (strcat initget-str k3 " ")
prompt1 (strcat prompt1 k2 "/")
)
)
)
(setq initget-str (xdrx_string_trimleft (xdrx_string_trimright initget-str)))
(setq prompt1 (strcat prompt1 "}<退出>:"))
(setq mRMatrix t
tf1 t
mTMatrix0 (xdrx_matrix_identity 3)
mRMatrix t
)
(xdrx_pickset_redraw ss)
(xdrx_drag_setmatrix mTMatrix0 t)
(setq undo-mark 0)
(while mRMatrix
(xdrx_drag_initget (+ 2 4 8 16 128 512 65536) initget-str)
(xdrx_initget "T R A M S D L F U")
(xdrx_drag_setmode "Move")
(setq mRMatrix (xdrx_PickSet_dragGen prompt1 ss pj cursor nil))
(if (= mRMatrix -4)
(progn (if (< (ACET-SYS-KEYSTATE 27) 0)
(setq escape-down T
mRMatrix nil
)
(setq mRMatrix (xdrx_drag_getLastMatrix))
)
)
)
(cond
((= mRMatrix "A")
(setq mTMatrix (xdrx_matrix_setRotation
mTMatrix0
(/ pi 2)
'(0 0 1)
(trans pj 1 0)
)
)
(xdrx_drag_setmatrix mTMatrix nil)
)
((= mRMatrix "S")
(setq
mTMatrix (xdrx_matrix_setMirror
mTMatrix0
(list (trans pj 1 0) (trans (polar pj (/ pi 2) 100) 1 0))
)
)
(xdrx_drag_setmatrix mTMatrix nil)
)
((= mRMatrix "D")
(setq mTMatrix (xdrx_matrix_setMirror
mTMatrix0
(list (trans pj 1 0) (trans (polar pj 0.0 100) 1 0))
)
)
(xdrx_drag_setmatrix mTMatrix nil)
)
((= mRMatrix "F")
(setq mTMatrix2 (xdrx_drag_getLastMatrix)
pj (xdrx_drag_getLastPoint)
)
(setq ss1 (xdrx_entity_TransFormedcopy ss mTMatrix2))
(if (and (setq pt1 (getpoint "\n请拾取对齐源参考点:"))
(setq pt2 (getpoint pt1 "\n请拾取另一定确定对齐参考轴:"))
(setq pt3 (getpoint "\n请拾取目标参考点:"))
(setq pt4 (getpoint pt3 "\n请拾取另一点确定目标参考轴:"))
)
(progn (setq mMatRot (XD::Matrix:Align pt1 pt1 pt3 pt2 pt4))
(setq mMatRot (XD::Matrix:Align pj pt1 pt3 pt2 pt4))
(setq mMatRot
(xdrx_matrix_product
(xdrx_matrix_setTransLation mTMatrix0 (mapcar '- pj pt4))
mMatRot
)
)
(setq pj1 (xdrx_point_transform pj mMatRot))
(setq m (xdrx_matrix_settranslation mTMatrix0 (mapcar '- pj pj1))
mMatRot (xdrx_matrix_product mMatrot mTMatrix2)
)
(xdrx_drag_setmatrix mMatRot t)
)
)
(command ".erase" ss1 "")
)
((= mRMatrix "R")
(setq mTMatrix2 (xdrx_drag_getLastMatrix))
(setq ss1 (xdrx_entity_TransFormedcopy ss mTMatrix2))
(xdrx_pickset_redraw ss1 3)
(xdrx_drag_setmatrix mTMatrix0 t)
(xdrx_drag_SetMode "Rotate")
(xdrx_drag_initget (+ 2 4 8 16 128 512 65536))
(setq mTMatrix (xdrx_pickset_draggen
"\n旋转角度[回车输入]:"
ss1
(setq pj1 (trans (xdrx_drag_getLastPoint) 0 1))
2
)
)
(if (= mTMatrix -4)
(if (< (ACET-SYS-KEYSTATE 27) 0)
(setq mRMatrix nil)
)
)
(if (= mTMatrix -1)
(progn (if (not (setq ang (getangle "\n请输入旋转角度<0>:")))
(setq ang 0.0)
)
(setq mTMatrix (xdrx_matrix_setRotation
mTMatrix0
ang
'(0 0 1)
(trans pj1 1 0)
)
)
)
(progn (setq mMatTrans (xdrx_matrix_setTranslation mTMatrix0 (mapcar '- pj pj1))
mTMatrix (xdrx_matrix_product mMatTrans mTMatrix)
mTMatrix (xdrx_matrix_product mTMatrix mTMatrix2)
)
)
)
(xdrx_drag_setmatrix mTMatrix t)
(command ".erase" ss1 "")
)
((= mRMatrix "M")
(setq mTMatrix2 (xdrx_drag_getLastMatrix))
(setq ss1 (xdrx_entity_TransFormedcopy ss mTMatrix2))
(xdrx_pickset_redraw ss1 3)
(xdrx_drag_setmatrix mTMatrix0 t)
(xdrx_drag_SetMode "Mirror")
(xdrx_drag_initget (+ 2 4 8 16 128 512 65536))
(if (and (setq pj1 (getpoint "\n请拾取镜像参考基点<退出>:"))
(setq mTMatrix (xdrx_pickset_draggen
"\n\n请拾取另一点定确定镜像轴<退出>:"
ss1
pj1
2
)
)
)
(progn (setq mMatTrans (xdrx_matrix_setTranslation mTMatrix0 (mapcar '- pj pj1))
mTMatrix (xdrx_matrix_product mMatTrans mTMatrix)
mTMatrix (xdrx_matrix_product mTMatrix mTMatrix2)
)
)
(progn (setq mTMatrix mTMatrix2))
)
(xdrx_drag_setmatrix mTMatrix nil)
(command ".erase" ss1 "")
)
((= mRMatrix "L")
(setq mTMatrix2 (xdrx_drag_getLastMatrix))
(setq ss1 (xdrx_entity_TransFormedcopy ss mTMatrix2))
(xdrx_pickset_redraw ss1 3)
(xdrx_drag_setmatrix mTMatrix0 t)
(setq box (xdrx_entity_box ss1)
scl (- (caadr box) (caar box))
)
(xdrx_drag_SetMode "Scale" (/ scl 2.0))
(xdrx_drag_initget (+ 2 4 8 16 128 512 65536))
(setq mTMatrix (xdrx_pickset_draggen
"\n缩放比例[回车输入]:"
ss1
(setq pj1 (trans (xdrx_drag_getLastPoint) 0 1))
2
)
)
(if (= mTMatrix -4)
(if (< (ACET-SYS-KEYSTATE 27) 0)
(setq mRMatrix nil)
)
)
(if (= mTMatrix -1)
(progn (initget 6)
(if (not (setq scl (getreal "\n请输入缩放比例<1>:")))
(setq scl 1.0)
)
(if (/= scl 1.0)
(progn
(setq
mTMatrix (xdrx_matrix_setScale mTMatrix0 scl (trans pj1 1 0))
)
)
)
)
)
(setq mMatTrans (xdrx_matrix_setTranslation mTMatrix0 (mapcar '- pj pj1))
mTMatrix (xdrx_matrix_product mMatTrans mTMatrix)
mTMatrix (xdrx_matrix_product mTMatrix mTMatrix2)
)
(xdrx_drag_setmatrix mTMatrix nil)
(command ".erase" ss1 "")
)
((= mRMatrix "T")
(setq mTMatrix2 (xdrx_drag_getLastMatrix))
(setq ss1 (xdrx_entity_TransFormedcopy ss mTMatrix2))
(initget 2)
(if (setq pj1 (getpoint "\n请输入新的基点:"))
(progn (setq pj pj1) (xdrx_drag_setmatrix mTMatrix2 T))
)
(command ".erase" ss1 "")
)
((= mRMatrix -1) (setq mRMatrix nil))
((= mRMatrix "U")
(if (> undo-mark 0)
(progn (setq undo-mark (1- undo-mark))
(if (>= undo-mark 0)
(vl-cmdf ".undo" 1)
)
(if (= undo-mark 0)
(princ "\n所有操作已经回退完毕。")
)
)
(princ "\r所有操作已经回退完毕。")
)
)
((or (= (type mRMatrix) 'LIST) (not escape-down))
(XD::UndoMark)
(setq undo-mark (1+ undo-mark))
(if tf
(progn
(setq entlist
(xd::list:groupbyindex
(mapcar
'(lambda (x) (list (xdrx_getpropertyvalue x "IsA") x))
(xdrx_pickset->ents
(xdrx_entity_TransFormedcopy
ss
(xdrx_drag_getLastMatrix)
)
)
)
0
)
)
(setq entlist1 (cdr (assoc "AcDbText" entlist))
entlist2 (cdr (assoc "AcDbMText" entlist))
)
(if (setq entlist (append entlist1 entlist2))
(progn (setq vdir (getvar "viewdir"))
(mapcar
'(lambda (x)
(setq zdir1 (xdrx_getpropertyvalue x "normal")
pt (xd::geom:get9pt x 5)
)
(if (and (equal vdir '(0.0 0.0 1.0) 1e-5)
(equal zdir1 '(0.0 0.0 -1.0) 1e-5)
)
(progn (xdrx_setpropertyvalue
x
"normal"
(xdrx_vector_negate zdir1)
)
(vl-cmdf ".Move" x "" (xd::geom:get9pt x 5) pt)
)
)
)
entlist
)
)
)
)
(progn (xdrx_entity_TransForm ss (xdrx_drag_getLastMatrix))
(setq mRMatrix nil)
)
)
(XD::UndoEnd)
)
)
)
(xdrx_pickset_redraw ss t)
(xdrx_document_ucsoff)
(xdrx_SysVar_Pop)
(xdrx_end)
(princ)
)

(defun XD::Pickset:Drag        (ss          pj           mode            cursor   tf              / 
                         ang          box           initget-str             k1              k2 
                         k3          m           mmatrot  mmattrans              mrmatrix 
                         mtmatrix mtmatrix0            mtmatrix2              n 
                         pj1          prompt1  promptl  pt             pt1      pt2 
                         pt3          pt4           scl            ss1             tf1 
                         escape-down           entlist  entlist1 entlist2 vdir 
                         zdir1 
                        ) 
  (xdrx_begin) 
  (xdrx_SysVar_Push '("osmode" 2727) '("CURSORSIZE" 5)) 
  (xdrx_document_ucson) 
  (if (not pj) 
    (progn (setq box (xdrx_entity_box ss) 
                 pj  (car box) 
           ) 
    ) 
  ) 
  (setq        promptl        (list '(1 "改基点[T]" "T") 
                      '(2 "改转角[R]" "R") 
                      '(4 "转90度[A]" "A") 
                      '(8 "镜像[M]" "M") 
                      '(16 "左右翻[S]" "S") 
                      '(32 "上下翻[D]" "D") 
                      '(256 "缩放[L]" "L") 
                      '(512 "对齐[F]" "F") 
                      '(4096 "回退[U]" "U") 
                     ) 
  ) 
  (setq prompt1 "\n插入点或{") 
  (setq initget-str " ") 
  (setq mode (+ 4096 mode)) 
  (foreach n promptl 
    (setq k1 (car n) 
          k2 (cadr n) 
          k3 (caddr n) 
    ) 
    (if        (/= (logand mode k1) 0) 
      (setq initget-str        (strcat initget-str k3 " ") 
            prompt1        (strcat prompt1 k2 "/") 
      ) 
    ) 
  ) 
  (setq initget-str (xdrx_string_trimleft (xdrx_string_trimright initget-str))) 
  (setq prompt1 (strcat prompt1 "}<退出>:")) 
  (setq        mRMatrix  t 
        tf1          t 
        mTMatrix0 (xdrx_matrix_identity 3) 
        mRMatrix  t 
  ) 
  (xdrx_pickset_redraw ss) 
  (xdrx_drag_setmatrix mTMatrix0 t) 
  (setq undo-mark 0) 
  (while mRMatrix 
    (xdrx_drag_initget (+ 2 4 8 16 128 512 65536) initget-str) 
    (xdrx_initget "T R A M S D L F U") 
    (xdrx_drag_setmode "Move") 
    (setq mRMatrix (xdrx_PickSet_dragGen prompt1 ss pj cursor nil)) 
    (if        (= mRMatrix -4) 
      (progn (if (< (ACET-SYS-KEYSTATE 27) 0) 
               (setq escape-down T 
                     mRMatrix nil 
               ) 
               (setq mRMatrix (xdrx_drag_getLastMatrix)) 
             ) 
      ) 
    ) 
    (cond 
      ((= mRMatrix "A") 
       (setq mTMatrix (xdrx_matrix_setRotation 
                        mTMatrix0 
                        (/ pi 2) 
                        '(0 0 1) 
                        (trans pj 1 0) 
                      ) 
       ) 
       (xdrx_drag_setmatrix mTMatrix nil) 
      ) 
      ((= mRMatrix "S") 
       (setq 
         mTMatrix (xdrx_matrix_setMirror 
                    mTMatrix0 
                    (list (trans pj 1 0) (trans (polar pj (/ pi 2) 100) 1 0)) 
                  ) 
       ) 
       (xdrx_drag_setmatrix mTMatrix nil) 
      ) 
      ((= mRMatrix "D") 
       (setq mTMatrix (xdrx_matrix_setMirror 
                        mTMatrix0 
                        (list (trans pj 1 0) (trans (polar pj 0.0 100) 1 0)) 
                      ) 
       ) 
       (xdrx_drag_setmatrix mTMatrix nil) 
      ) 
      ((= mRMatrix "F") 
       (setq mTMatrix2 (xdrx_drag_getLastMatrix) 
             pj               (xdrx_drag_getLastPoint) 
       ) 
       (setq ss1 (xdrx_entity_TransFormedcopy ss mTMatrix2)) 
       (if (and        (setq pt1 (getpoint "\n请拾取对齐源参考点:")) 
                (setq pt2 (getpoint pt1 "\n请拾取另一定确定对齐参考轴:")) 
                (setq pt3 (getpoint "\n请拾取目标参考点:")) 
                (setq pt4 (getpoint pt3 "\n请拾取另一点确定目标参考轴:")) 
           ) 
         (progn        (setq mMatRot (XD::Matrix:Align pt1 pt1 pt3 pt2 pt4)) 
                (setq mMatRot (XD::Matrix:Align pj pt1 pt3 pt2 pt4)) 
                (setq mMatRot 
                       (xdrx_matrix_product 
                         (xdrx_matrix_setTransLation mTMatrix0 (mapcar '- pj pt4)) 
                         mMatRot 
                       ) 
                ) 
                (setq pj1 (xdrx_point_transform pj mMatRot)) 
                (setq m              (xdrx_matrix_settranslation mTMatrix0 (mapcar '- pj pj1)) 
                      mMatRot (xdrx_matrix_product mMatrot mTMatrix2) 
                ) 
                (xdrx_drag_setmatrix mMatRot t) 
         ) 
       ) 
       (command ".erase" ss1 "") 
      ) 
      ((= mRMatrix "R") 
       (setq mTMatrix2 (xdrx_drag_getLastMatrix)) 
       (setq ss1 (xdrx_entity_TransFormedcopy ss mTMatrix2)) 
       (xdrx_pickset_redraw ss1 3) 
       (xdrx_drag_setmatrix mTMatrix0 t) 
       (xdrx_drag_SetMode "Rotate") 
       (xdrx_drag_initget (+ 2 4 8 16 128 512 65536)) 
       (setq mTMatrix (xdrx_pickset_draggen 
                        "\n旋转角度[回车输入]:" 
                        ss1 
                        (setq pj1 (trans (xdrx_drag_getLastPoint) 0 1)) 
                        2 
                      ) 
       ) 
       (if (= mTMatrix -4) 
         (if (< (ACET-SYS-KEYSTATE 27) 0) 
           (setq mRMatrix nil) 
         ) 
       ) 
       (if (= mTMatrix -1) 
         (progn        (if (not (setq ang (getangle "\n请输入旋转角度<0>:"))) 
                  (setq ang 0.0) 
                ) 
                (setq mTMatrix (xdrx_matrix_setRotation 
                                 mTMatrix0 
                                 ang 
                                 '(0 0 1) 
                                 (trans pj1 1 0) 
                               ) 
                ) 
         ) 
         (progn        (setq mMatTrans        (xdrx_matrix_setTranslation mTMatrix0 (mapcar '- pj pj1)) 
                      mTMatrix        (xdrx_matrix_product mMatTrans mTMatrix) 
                      mTMatrix        (xdrx_matrix_product mTMatrix mTMatrix2) 
                ) 
         ) 
       ) 
       (xdrx_drag_setmatrix mTMatrix t) 
       (command ".erase" ss1 "") 
      ) 
      ((= mRMatrix "M") 
       (setq mTMatrix2 (xdrx_drag_getLastMatrix)) 
       (setq ss1 (xdrx_entity_TransFormedcopy ss mTMatrix2)) 
       (xdrx_pickset_redraw ss1 3) 
       (xdrx_drag_setmatrix mTMatrix0 t) 
       (xdrx_drag_SetMode "Mirror") 
       (xdrx_drag_initget (+ 2 4 8 16 128 512 65536)) 
       (if (and        (setq pj1 (getpoint "\n请拾取镜像参考基点<退出>:")) 
                (setq mTMatrix (xdrx_pickset_draggen 
                                 "\n\n请拾取另一点定确定镜像轴<退出>:" 
                                 ss1 
                                 pj1 
                                 2 
                               ) 
                ) 
           ) 
         (progn        (setq mMatTrans        (xdrx_matrix_setTranslation mTMatrix0 (mapcar '- pj pj1)) 
                      mTMatrix        (xdrx_matrix_product mMatTrans mTMatrix) 
                      mTMatrix        (xdrx_matrix_product mTMatrix mTMatrix2) 
                ) 
         ) 
         (progn (setq mTMatrix mTMatrix2)) 
       ) 
       (xdrx_drag_setmatrix mTMatrix nil) 
       (command ".erase" ss1 "") 
      ) 
      ((= mRMatrix "L") 
       (setq mTMatrix2 (xdrx_drag_getLastMatrix)) 
       (setq ss1 (xdrx_entity_TransFormedcopy ss mTMatrix2)) 
       (xdrx_pickset_redraw ss1 3) 
       (xdrx_drag_setmatrix mTMatrix0 t) 
       (setq box (xdrx_entity_box ss1) 
             scl (- (caadr box) (caar box)) 
       ) 
       (xdrx_drag_SetMode "Scale" (/ scl 2.0)) 
       (xdrx_drag_initget (+ 2 4 8 16 128 512 65536)) 
       (setq mTMatrix (xdrx_pickset_draggen 
                        "\n缩放比例[回车输入]:" 
                        ss1 
                        (setq pj1 (trans (xdrx_drag_getLastPoint) 0 1)) 
                        2 
                      ) 
       ) 
       (if (= mTMatrix -4) 
         (if (< (ACET-SYS-KEYSTATE 27) 0) 
           (setq mRMatrix nil) 
         ) 
       ) 
       (if (= mTMatrix -1) 
         (progn        (initget 6) 
                (if (not (setq scl (getreal "\n请输入缩放比例<1>:"))) 
                  (setq scl 1.0) 
                ) 
                (if (/= scl 1.0) 
                  (progn 
                    (setq 
                      mTMatrix (xdrx_matrix_setScale mTMatrix0 scl (trans pj1 1 0)) 
                    ) 
                  ) 
                ) 
         ) 
       ) 
       (setq mMatTrans (xdrx_matrix_setTranslation mTMatrix0 (mapcar '- pj pj1)) 
             mTMatrix  (xdrx_matrix_product mMatTrans mTMatrix) 
             mTMatrix  (xdrx_matrix_product mTMatrix mTMatrix2) 
       ) 
       (xdrx_drag_setmatrix mTMatrix nil) 
       (command ".erase" ss1 "") 
      ) 
      ((= mRMatrix "T") 
       (setq mTMatrix2 (xdrx_drag_getLastMatrix)) 
       (setq ss1 (xdrx_entity_TransFormedcopy ss mTMatrix2)) 
       (initget 2) 
       (if (setq pj1 (getpoint "\n请输入新的基点:")) 
         (progn (setq pj pj1) (xdrx_drag_setmatrix mTMatrix2 T)) 
       ) 
       (command ".erase" ss1 "") 
      ) 
      ((= mRMatrix -1) (setq mRMatrix nil)) 
      ((= mRMatrix "U") 
       (if (> undo-mark 0) 
         (progn        (setq undo-mark (1- undo-mark)) 
                (if (>= undo-mark 0) 
                  (vl-cmdf ".undo" 1) 
                ) 
                (if (= undo-mark 0) 
                  (princ "\n所有操作已经回退完毕。") 
                ) 
         ) 
         (princ "\r所有操作已经回退完毕。") 
       ) 
      ) 
      ((or (= (type mRMatrix) 'LIST) (not escape-down)) 
       (XD::UndoMark) 
       (setq undo-mark (1+ undo-mark)) 
       (if tf 
         (progn 
           (setq entlist 
                  (xd::list:groupbyindex 
                    (mapcar 
                      '(lambda (x) (list (xdrx_getpropertyvalue x "IsA") x)) 
                      (xdrx_pickset->ents 
                        (xdrx_entity_TransFormedcopy 
                          ss 
                          (xdrx_drag_getLastMatrix) 
                        ) 
                      ) 
                    ) 
                    0 
                  ) 
           ) 
           (setq entlist1 (cdr (assoc "AcDbText" entlist)) 
                 entlist2 (cdr (assoc "AcDbMText" entlist)) 
           ) 
           (if (setq entlist (append entlist1 entlist2)) 
             (progn (setq vdir (getvar "viewdir")) 
                    (mapcar 
                      '(lambda (x) 
                         (setq zdir1 (xdrx_getpropertyvalue x "normal") 
                               pt    (xd::geom:get9pt x 5) 
                         ) 
                         (if (and (equal vdir '(0.0 0.0 1.0) 1e-5) 
                                  (equal zdir1 '(0.0 0.0 -1.0) 1e-5) 
                             ) 
                           (progn (xdrx_setpropertyvalue 
                                    x 
                                    "normal" 
                                    (xdrx_vector_negate zdir1) 
                                  ) 
                                  (vl-cmdf ".Move" x "" (xd::geom:get9pt x 5) pt) 
                           ) 
                         ) 
                       ) 
                      entlist 
                    ) 
             ) 
           ) 
         ) 
         (progn        (xdrx_entity_TransForm ss (xdrx_drag_getLastMatrix)) 
                (setq mRMatrix nil) 
         ) 
       ) 
       (XD::UndoEnd) 
      ) 
    ) 
  ) 
  (xdrx_pickset_redraw ss t) 
  (xdrx_document_ucsoff) 
  (xdrx_SysVar_Pop) 
  (xdrx_end) 
  (princ) 
)

newer · 发表于 2017-8-20 14:42:05

liuyj 发表于 2017-8-20 13:34

(xdrx_drag_initget (+ 2 4 8 16 128 512 65536) st) , ST是什么？

把应用 xd::pickset:drag 这个函数的代码也贴上来吧。

liuyj · 发表于 2017-8-20 15:06:48

(defun c:XDTB_FREECOPY (/ pj ss)
(if (and (princ "\n选取要拷贝的实体<退出>:")
(setq ss (ssget ":L"))
(setq pj (getpoint "\n拾取基点<退出>:"))
)
(XD::Pickset:Drag ss pj (+ 1 2 4 8 16 32 64 128 256 512) 2 t)
)
(princ)
)
(defun c:XDTB_FREEMOVE (/ pj ss)
(if (and (princ "\n选取要拷贝的实体<退出>:")
(setq ss (ssget ":L"))
(setq pj (getpoint "\n拾取基点<退出>:"))
)
(XD::Pickset:Drag ss pj (+ 1 2 4 8 16 32 64 128 256 512) 2 nil)
)
(princ)
)

liuyj · 发表于 2017-8-20 15:07:56

ST就是关键字

newer · 发表于 2017-8-21 11:31:50

liuyj 发表于 2017-8-20 15:07

你试试 xdrx_drag_jig 函数下，在2014下，是否能输入距离？

liuyj · 发表于 2017-8-21 11:47:36

单位的电脑只装了2012，回家再试试。不过就是xdrx_drag_jig可以输入距离，难道要改成用它的不用矩阵？xdrx_drag_jig还有个问题，2012下总是出现，就是光标从块或参照上移动时，尤其是比较复杂的块，总出现什么内部错误，退出还无法存盘，所以我后来避免用它。

XDSoft · 发表于 2017-8-21 12:19:44

(xdrx_drag_initget (+ 2 4 8 16 128 512 65536) st) 改成

(xdrx_drag_initget (+ 2 4 8 16 128 512) st)

别带 65536 就行。

liuyj · 发表于 2017-8-21 13:08:02

那这个65536代表什么？一直没太弄明白。有些xdrx_drag_jig也有这个参数，是不是同样的功能？

XDSoft · 发表于 2017-8-21 13:14:30

liuyj 发表于 2017-8-21 13:08

拖动类，只要是用户控制的参数，都一样的。

65536 是 2014以上版本新加的，禁止输入距离。对低版本设不设无效。

账号		自动登录	找回密码
密码			立即注册

[BUG报告] 64位的cad2014，xdrx_PickSet_dragGen输入距离没有返回值

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

浏览过的版块