歪果人的几个工具

st788796 · 发表于 2017-8-23 08:24:47

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

本帖最后由 st788796 于 2017-8-23 11:48 编辑

http://www.maestrogroup.com.ua/support/
俄文

Directory Listing

Name	Size	Last Modified
ArxDbg2007.zip	1161819	2012-12-28 13:41:23
ArxDbg2010.zip	884269	2012-12-28 13:46:13
ArxDbg2013.zip	880579	2012-12-28 13:46:24
ArxDbg2015.zip	875333	2014-03-30 02:15:04
ArxDbg2017.zip	863377	2016-03-20 02:41:18
ArxDbg2018.zip	860820	2017-03-22 20:34:19
DWGConvert.zip	509697	2017-03-22 23:29:53
ExplodeProxy.zip	297564	2017-03-22 23:29:18
FDist.zip	170417	2017-03-22 23:28:59
FixFPU.zip	8708	2005-08-11 22:05:22
GeomProps.zip	737997	2017-03-22 23:28:45
LayerFilter.zip	157199	2017-08-13 00:40:25
MPRebalance.zip	50586	2011-03-03 11:06:32
P3DEDIT.zip	10805	2008-09-09 18:17:27
ProgressBars.zip	325108	2017-07-07 01:28:26
SaveDwgPreview.zip	7096	2007-08-01 08:56:10
SlbSplit.zip	16718	2008-05-26 18:18:42
dyndraw.zip	261070	2017-03-22 23:29:38
getdwgprops.zip	154052	2016-03-20 02:38:04
getlispinfo.zip	7916	2005-11-27 13:52:36
orthoosnap.zip	12190	2005-08-23 14:08:04
selsim.zip	317396	2017-03-22 23:27:51
shx2shpuni.zip	35806	2014-08-07 00:59:15
slbinfo.zip	13293	2005-09-06 19:47:27
timecheck.zip	11229	2005-05-13 11:04:02

if I have a proxy-alarm when I start a drawing, I use the folling link:

http://www.maestrogroup.com.ua/support/

There is the explodeProxy.zip

Try it.

I use it three times, one after the other, in the same drawing:

1. EXPLODEALLPROXY
2. REMOVEALLPROXY
3. EXPLODEALLPROXY

After that there are no more proxys. But be careful and use first a copy of your drawing.

Greetings from Germany from garlic

liunian0524 · 发表于 2017-8-23 08:33:02

感谢楼主分享,虽然我看不懂

sh_h · 发表于 2017-8-23 09:24:14

谢谢楼主分享！！！

liuyj · 发表于 2017-8-23 10:08:10

dyndraw那个超级强悍的

liuyj · 发表于 2017-8-23 10:15:19

和xdrx_drag_jig的用法差不多，http://www.theswamp.org上有LeeMac写的几个例子

st788796 · 发表于 2017-8-23 10:33:36

liuyj 发表于 2017-8-23 10:15

看样子和 xdrx_pointmonitor 类似

(defun c:DynDrawTest (/ step blk Obj point)
(setq step 1e-6)
(setq blk (car (entsel "\nSelect a block: "))
;;; pt (dxf 10 (entget blk)) ;_ fim de dxf
;;; LastPt pt
Obj (vlax-ename->vla-object blk)
) ;_ fim de setq
(defun JoyCallBackTest (point /)
(setvar "nomutt" 1) ;_ suppresses the "regen ..." prompt
(cond
((= (type point) 'STR)
(vla-update Obj)
)
((vl-consp point)
(or prev (setq prev point))
(if (< step (distance prev point))
(progn
(setq prev point)
(vla-put-InsertionPoint Obj (vlax-3D-point point))
(vla-update Obj)
) ;_ fim de progn
) ;_ fim de if
)
) ;_ fim de cond
(setvar "nomutt" 0)
point
) ;_ fim de defun
;;;
;;;Define a funcao p/ DynDraw.arx
(vl-acad-defun 'JoyCallBackTest)
(setq
point
(dyndraw "JoyCallBackTest"
"\nSpecify insertion point: [Enter Exit]: "
"" ;_ Keyword string
(+ 2 128 2048)
-1
nil
) ;_ fim de dyndraw
) ;_ fim de setq
;;;
(if (vl-consp point)
(progn
(vla-put-InsertionPoint Obj (vlax-3D-point point))
(vla-update Obj)
) ;_ fim de progn
) ;_ fim de if
;;;
(vl-acad-undefun 'JoyCallBackTest)
(princ)
)

(defun c:DynDrawTest (/ step blk Obj point) 
  (setq step 1e-6) 
  (setq        blk (car (entsel "\nSelect a block: ")) 
;;;        pt     (dxf 10 (entget blk)) ;_ fim de dxf 
;;;        LastPt pt 
        Obj (vlax-ename->vla-object blk) 
  ) ;_ fim de setq 
  (defun JoyCallBackTest (point /) 
    (setvar "nomutt" 1) ;_ suppresses the "regen ..." prompt 
    (cond 
      ((= (type point) 'STR) 
       (vla-update Obj) 
      ) 
      ((vl-consp point) 
       (or prev (setq prev point)) 
       (if (< step (distance prev point)) 
         (progn 
           (setq prev point) 
           (vla-put-InsertionPoint Obj (vlax-3D-point point)) 
           (vla-update Obj) 
         ) ;_ fim de progn 
       ) ;_ fim de if 
      ) 
    ) ;_ fim de cond 
    (setvar "nomutt" 0) 
    point 
  ) ;_ fim de defun 
;;; 
;;;Define a funcao p/ DynDraw.arx 
  (vl-acad-defun 'JoyCallBackTest) 
  (setq 
    point 
     (dyndraw "JoyCallBackTest" 
              "\nSpecify insertion point: [Enter Exit]: " 
              "" ;_ Keyword string 
              (+ 2 128 2048) 
              -1 
              nil 
     ) ;_ fim de dyndraw 
  ) ;_ fim de setq 
;;; 
  (if (vl-consp point) 
    (progn 
      (vla-put-InsertionPoint Obj (vlax-3D-point point)) 
      (vla-update Obj) 
    ) ;_ fim de progn 
  ) ;_ fim de if 
;;; 
  (vl-acad-undefun 'JoyCallBackTest) 
  (princ) 
)

st788796 · 发表于 2017-8-23 10:35:34

;; An example of Dynamic Grid creation using a grRead substitute,
;; Program by Lee Mac, using DynDraw by Alexander Rivilis
;; (http://www.maestrogroup.com.ua/support/dyndraw.zip)
(defun c:DynGrid ( / *error* line vers step bit v m n p1 p2 p3 p4 i j pi/2 prev )
;; © Lee Mac 2010
(defun *error* ( msg )
(or (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*")
(princ (strcat "\n** Error: " msg " **")))
(redraw) (princ)
)
(defun line ( s e )
(entmakex
(list
(cons 0 "LINE")
(cons 10 s)
(cons 11 e)
)
)
)
(setq vers
'((18.0 . "2010")
(17.2 . "2009")
(17.1 . "2008")
(17.0 . "2007")
(16.2 . "2006")
(16.1 . "2005")
(16.0 . "2004")
(15.6 . "2002"))
)
(setq step 1e-6
bit (if (eq "X86"
(strcase
(getenv "PROCESSOR_ARCHITECTURE")
)
)
"x32" "x64"
)
)
(cond
(
(not
(setq v
(cdr
(assoc
(atof
(getvar 'ACADVER)
)
vers
)
)
)
)
(princ "\n** Not Compatible in this Version **")
)
(
(not
(and
(not (initget 6))
(setq m*
(cond
(
(getint
(strcat "\nSpecify Number of Rows <"
(itoa
(setq m* (cond ( m* ) ( 3 )))
)
"> : "
)
)
)
( m* )
)
)
(not (initget 6))
(setq n*
(cond
(
(getint
(strcat "\nSpecify Number of Columns <"
(itoa
(setq n* (cond ( n* ) ( 3 )))
)
"> : "
)
)
)
( n* )
)
)
(setq p1 (getpoint "\nPick First Corner Point: "))
)
)
(princ "\n*Cancel*")
)
(
(and
(null dyndraw)
(not
(arxload
(strcat "DynDraw" v
(if (eq "2010" v) bit "") ".arx"
)
)
)
)
(princ "\n** Arx File not Found **")
)
(
(vl-acad-defun 'UpdateGridCallBack)
(setq p2
(dyndraw "UpdateGridCallBack"
"\nPick Second Point [Columns/Rows] : "
"Columns Rows"
(+ 1 2 128 2048)
-1
nil
)
)
(redraw)
(if (vl-consp p2)
(progn
(setq i (/ (- (cadr p2) (cadr p1)) m*)
j (/ (- (car p2) (car p1)) n*)
pi/2 (/ pi 2.)
p3 (cons (car p2) (cdr p1))
p4 (cons (car p1) (cdr p2))
)
(
(lambda ( k )
(repeat (1- n*)
(apply (function line)
(mapcar
(function
(lambda ( point ) (trans point 1 0))
)
(list (polar p1 0 (* (setq k (1+ k)) j))
(polar p4 0 (* k j))
)
)
)
)
)
0
)
(
(lambda ( k )
(repeat (1- m*)
(apply (function line)
(mapcar
(function
(lambda ( point ) (trans point 1 0))
)
(list (polar p1 pi/2 (* (setq k (1+ k)) i))
(polar p3 pi/2 (* k i))
)
)
)
)
)
0
)
)
)
)
)
(princ)
)
(defun UpdateGridCallBack ( argument )
(cond
(
(eq 'STR (type argument))
(cond
(
(eq "Columns" argument)
(initget 6)
(setq n*
(cond
( (getint (strcat "\nSpecify Number of Columns <" (itoa n*) "> : ")) )
( n* )
)
)
)
(
(eq "Rows" argument)
(initget 6)
(setq m*
(cond
( (getint (strcat "\nSpecify Number of Rows <" (itoa m*) "> : ")) )
( m* )
)
)
)
(
(princ "\n** Invalid Keyword **")
)
)
(setq argument t)
)
(
(vl-consp argument)
(or prev (setq prev argument))
(if (< step (distance prev argument))
(progn
(setq prev argument p2 argument)
(setq i (/ (- (cadr p2) (cadr p1)) m*)
j (/ (- (car p2) (car p1)) n*)
pi/2 (/ pi 2.)
p3 (cons (car p2) (cdr p1))
p4 (cons (car p1) (cdr p2)))
(redraw)
(grvecs (cons 256 (list p1 p3 p3 p2 p1 p4 p4 p2)))
(
(lambda ( k )
(repeat (1- n*)
(grvecs
(cons 256
(list (polar p1 0 (* (setq k (1+ k)) j))
(polar p4 0 (* k j))
)
)
)
)
)
0
)
(
(lambda ( k )
(repeat (1- m*)
(grvecs
(cons 256
(list (polar p1 pi/2 (* (setq k (1+ k)) i))
(polar p3 pi/2 (* k i))
)
)
)
)
)
0
)
)
)
)
)
argument
)

;; An example of Dynamic Grid creation using a grRead substitute, 
;; Program by Lee Mac, using DynDraw by Alexander Rivilis 
;; (http://www.maestrogroup.com.ua/support/dyndraw.zip) 
 
(defun c:DynGrid ( / *error* line vers step bit v m n p1 p2 p3 p4 i j pi/2 prev ) 
  ;; &#169; Lee Mac 2010 
 
  (defun *error* ( msg ) 
    (or (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*") 
        (princ (strcat "\n** Error: " msg " **"))) 
    (redraw) (princ)    
  ) 
 
  (defun line ( s e ) 
    (entmakex 
      (list 
        (cons 0 "LINE") 
        (cons 10 s) 
        (cons 11 e) 
      ) 
    ) 
  ) 
 
  (setq vers 
    '((18.0 . "2010") 
      (17.2 . "2009") 
      (17.1 . "2008") 
      (17.0 . "2007") 
      (16.2 . "2006") 
      (16.1 . "2005") 
      (16.0 . "2004") 
      (15.6 . "2002")) 
  ) 
   
  (setq step 1e-6 
        bit (if (eq "X86" 
                  (strcase 
                    (getenv "PROCESSOR_ARCHITECTURE") 
                  ) 
                ) 
              "x32" "x64" 
             ) 
  ) 
 
  (cond 
    ( 
      (not 
        (setq v 
          (cdr 
            (assoc 
              (atof 
                (getvar 'ACADVER) 
              ) 
              vers 
            ) 
          ) 
        ) 
      ) 
     (princ "\n** Not Compatible in this Version **") 
    ) 
    ( 
      (not 
        (and 
          (not (initget 6)) 
          (setq m* 
            (cond 
              ( 
                (getint 
                  (strcat "\nSpecify Number of Rows <" 
                    (itoa 
                      (setq m* (cond ( m* ) ( 3 ))) 
                    ) 
                    "> : " 
                  ) 
                ) 
              ) 
              ( m* ) 
            ) 
          ) 
          (not (initget 6)) 
          (setq n* 
            (cond 
              ( 
                (getint 
                  (strcat "\nSpecify Number of Columns <" 
                    (itoa 
                      (setq n* (cond ( n* ) ( 3 ))) 
                    ) 
                    "> : " 
                  ) 
                ) 
              ) 
              ( n* ) 
            ) 
          ) 
          (setq p1 (getpoint "\nPick First Corner Point: ")) 
        ) 
      ) 
      (princ "\n*Cancel*") 
    ) 
    ( 
      (and 
        (null dyndraw) 
        (not 
          (arxload 
            (strcat "DynDraw" v 
              (if (eq "2010" v) bit "") ".arx" 
            ) 
          ) 
        ) 
      ) 
     (princ "\n** Arx File not Found **") 
    ) 
    (    
      (vl-acad-defun 'UpdateGridCallBack) 
       
      (setq p2 
        (dyndraw "UpdateGridCallBack" 
          "\nPick Second Point [Columns/Rows] : " 
          "Columns Rows" 
          (+ 1 2 128 2048) 
          -1 
          nil 
        ) 
      ) 
      
      (redraw) 
      
      (if (vl-consp p2) 
        (progn 
          (setq i    (/ (- (cadr p2) (cadr p1)) m*) 
                j    (/ (- (car  p2) (car  p1)) n*) 
                pi/2 (/ pi 2.) 
                p3   (cons (car p2) (cdr p1)) 
                p4   (cons (car p1) (cdr p2)) 
          ) 
          ( 
            (lambda ( k ) 
              (repeat (1- n*) 
                (apply (function line) 
                  (mapcar 
                    (function 
                      (lambda ( point ) (trans point 1 0)) 
                    ) 
                    (list (polar p1 0 (* (setq k (1+ k)) j)) 
                          (polar p4 0 (* k j)) 
                    ) 
                  ) 
                ) 
              ) 
            ) 
            0 
          ) 
          ( 
            (lambda ( k ) 
              (repeat (1- m*) 
                (apply (function line) 
                  (mapcar 
                    (function 
                      (lambda ( point ) (trans point 1 0)) 
                    ) 
                    (list (polar p1 pi/2 (* (setq k (1+ k)) i)) 
                          (polar p3 pi/2 (* k i)) 
                    ) 
                  ) 
                ) 
              ) 
            ) 
            0 
          ) 
        ) 
      ) 
    ) 
  ) 
  (princ) 
) 
 
(defun UpdateGridCallBack ( argument ) 
 
  (cond 
    ( 
      (eq 'STR (type argument)) 
 
      (cond 
        ( 
          (eq "Columns" argument) 
 
          (initget 6) 
          (setq n* 
            (cond 
              ( (getint (strcat "\nSpecify Number of Columns <" (itoa n*) "> : ")) ) 
              ( n* ) 
            ) 
          ) 
        ) 
        ( 
          (eq "Rows" argument) 
 
          (initget 6) 
          (setq m* 
            (cond 
              ( (getint (strcat "\nSpecify Number of Rows <" (itoa m*) "> : ")) ) 
              ( m* ) 
            ) 
          ) 
        ) 
        ( 
          (princ "\n** Invalid Keyword **") 
        ) 
     ) 
      
     (setq argument t) 
    ) 
    ( 
      (vl-consp argument) 
 
      (or prev (setq prev argument)) 
 
      (if (< step (distance prev argument)) 
        (progn 
          (setq prev argument p2 argument) 
 
          (setq i    (/ (- (cadr p2) (cadr p1)) m*) 
                j    (/ (- (car  p2) (car  p1)) n*) 
                pi/2 (/ pi 2.) 
                p3   (cons (car p2) (cdr p1)) 
                p4   (cons (car p1) (cdr p2))) 
 
          (redraw) 
          (grvecs (cons 256 (list p1 p3 p3 p2 p1 p4 p4 p2))) 
          
          ( 
            (lambda ( k ) 
              (repeat (1- n*) 
                (grvecs 
                  (cons 256 
                    (list (polar p1 0 (* (setq k (1+ k)) j)) 
                          (polar p4 0 (* k j)) 
                    ) 
                  ) 
                ) 
              ) 
            ) 
            0 
          ) 
          ( 
            (lambda ( k ) 
              (repeat (1- m*) 
                (grvecs 
                  (cons 256 
                    (list (polar p1 pi/2 (* (setq k (1+ k)) i)) 
                          (polar p3 pi/2 (* k i)) 
                    ) 
                  ) 
                ) 
              ) 
            ) 
            0 
          ) 
        ) 
      ) 
    ) 
  ) 
  argument 
)

WhoCanSay · 发表于 2017-8-23 10:38:14

ExplodeProxy.zip这个还比较实用哈

WhoCanSay · 发表于 2017-8-23 10:43:08

liuyj 发表于 2017-8-23 10:08

能否说说什么用处？

fan_zh · 发表于 2017-8-23 11:28:26

能看懂外语，但看不懂代码

st788796 · 发表于 2017-8-23 11:32:52

fan_zh 发表于 2017-8-23 11:28

你厉害，正好相反

liuyj · 发表于 2017-8-23 11:50:53

WhoCanSay 发表于 2017-8-23 10:43

就是通过回调函数，实现动态的效果。支持关键字，我觉得还是跟xdrx_drag_jig类似，都可以直接替换

kqqt6236 · 发表于 2017-8-24 00:07:35

哪位高人汉化一下

yzhyxh · 发表于 2017-8-24 08:07:04

乘风寻龙 · 发表于 2020-3-12 09:58:13

Specify Number of Rows <1> : 4
Specify Number of Columns <1> : 5
Pick First Corner Point:
** Error: ARXLOAD 失败 **

账号		自动登录	找回密码
密码			立即注册

[精彩文萃] 歪果人的几个工具

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

评分

点评