屏幕打印选取的动态块的信息

Lisphk

[JavaScript] 纯文本查看 复制代码

(defun c:dbinfo ( / ent obj pn prop)
  (vl-load-com)
  (if (and
          (setq ent (car (entsel "\nSelect Dynamic Block: ")))
          (eq "AcDbBlockReference" (vla-get-objectname (setq obj (vlax-ename->vla-object ent))))
          (eq :vlax-true (vla-get-isdynamicblock obj))
      )
      (progn
           (vla-sendcommand (vla-get-activedocument (vlax-get-acad-object)) "textscr\r")
           (foreach item
               (vlax-safearray->list
                      (vlax-variant-value (vla-getdynamicblockproperties obj))
               )
               (if (and
                      (setq pn (vlax-get-property item "PropertyName"))
                      (/= "ORIGIN" (strcase pn))
                      (/= "POSITION" (substr (strcase pn) 1 8))
                      (princ (strcat "\n\nPropertyName = " pn))
                   )
                   (foreach pr '("Description" "Value")
                      (setq prop (vlax-get-property item pr))
                      (princ (strcat "\n" pr " = "))
                      (cond
                         ((= (type prop) 'variant)
                          (princ (vlax-variant-value prop))
                         )
                         ((= prop "") (princ "\"\""))
                         (T (princ prop))
                      )
                    )
               )
           )
      )
      (alert "\n You'll need to pick again - please select a DYNAMIC block.")
  )
  (princ)
)

yangjian001

屏幕打印选取的动态块

asdf1599

真是雪中送炭啊，最近正在研究如何应用lisp操作动态块，谢谢！