【已解决】（指定起始点的相对最短路径连线）自交的多段线变成顶点不变的不自交的...

newer · 发表于 2018-2-10 11:47:04

本帖最后由 newer 于 2018-2-10 12:01 编辑

aimisiyou 发表于 2018-2-10 06:54

肯定有更短的，因为指定起点了，所以肯定不会是最短的了。最短的只能有一条，而且肯定是交叉的，另外，从交叉变不交叉，也会影像些外观。只能是理论和实践需要的折中

ynhh · 发表于 2018-2-10 13:13:26

谢谢您的分享
谢谢您的分享

Lisphk · 发表于 2018-2-10 14:00:57

本帖最后由 Lisphk 于 2018-2-10 14:06 编辑

aimisiyou 发表于 2018-2-10 07:46

大师，能不能给提供的代码，你算法造诣很深。

我试了 6 楼的老外的TSP的，500个点的时候，他的时间差不多是我这个的7倍多，点更多，差别更大。
但他的路径比我的短，我的距离是7834，他的是7468。他着重的是距离，我这个着重的是连线和时间。
他那个不能指定起始点，我这个可以指定。

命令: tt
选择最短距离连线的点<退出>:
选择对象: 指定对角点: 找到 500 个
选择对象:
路径起始点<原点最近>:
正在收集顶点...完毕.
正在计算最短路径...完毕.
正在计算无交叉通路...完毕.
[b][color=#ff0000]Use Time :6610ms.[/color][/b]

复制代码

命令: TEST
选择对象: 指定对角点: 找到 500 个
选择对象:
TSP Length :7468.
[color=#ff0000][b]Use Time :47953ms.[/b][/color]

复制代码

下面图片，左边的是我的，右边的是他的。

搜狗截图20180210140504.gif

我把他的代码贴上

(defun c:test (/ foo f2 ptl lst l n i d0 l0 l1 d1)
;;by GSLS(SS)
;;refer ElpanovEvgeniy's method from http://www.theswamp.org/index.php?topic=30434.75
;;2012-8-10
(defun foo (l / D D0 D1)
(setq l0 (mapcar (function list) (cons (last l) l) l)) ;_ setq
;_ defun
(setq d0 (get-closedpolygon-length l))
(while
(> d0
(progn
(foreach a l0
(setq d (get-closedpolygon-length l))
(setq l1 (vl-remove (car a) (vl-remove (cadr a) l)))
(setq l1 (f1 (car a) l1))
(setq l1 (f1 (cadr a) l1))
(if (> d
(setq d1 (get-closedpolygon-length l1))
)
(setq d d1
l l1
) ;_ setq
) ;_ if
(setq l1 (vl-remove (car a) (vl-remove (cadr a) l)))
(setq l1 (f1 (cadr a) l1))
(setq l1 (f1 (car a) l1))
(if (> d
(setq d1 (get-closedpolygon-length l1))
)
(setq d d1
l l1
)
)
)
d
) ;_ progn
) ;_ <
(setq d0 d)
) ;_ while
(setq d (get-closedpolygon-length l))
l
)
(defun f1 (a l)
(ins-lst a (get-closest-i l a) l)
)
(defun f2 (lst)
(mapcar (function (lambda (p0 p p1 / a)
(setq a (- (angle p p0) (angle p p1)))
(if (< a (- pi))
(abs (+ a pi pi))
(if (> a pi)
(abs (- a pi pi))
(abs a)
)
)
)
)
(cons (last lst) lst)
lst
(reverse (cons (car lst) (reverse (cdr lst))))
)
)
(setq ptl (my-getpt)
ptl (mapcar (function (lambda (p) (list (car p) (cadr p)))) ptl)
)
(setq t1 (getvar "MilliSecs"))
(setq lst (Graham-scan ptl))
(foreach a lst
(setq ptl (vl-remove a ptl))
)
(while (and (> (length ptl) 2) (setq l (Graham-scan ptl)))
(foreach p l
(setq ptl (vl-remove p ptl))
(setq n (get-minadddist-i lst p))
(setq lst (ins-lst p n lst))
)
)
(if ptl
(foreach p ptl
(setq n (get-minadddist-i lst p))
(setq lst (ins-lst p n lst))
)
)
(setq lst (foo lst))
(setq l (f2 lst))
(setq i 0
l0 lst
n (length lst)
d0 (get-closedpolygon-length lst)
)
(foreach a l
(if (and (< a _pi3) (= (setq p (nth i lst)) (nth i l0)))
(progn
(if (= i 0)
(setq p0 (last lst))
(setq p0 (nth (1- i) lst))
)
(if (= i (1- n))
(setq p1 (car lst))
(setq p1 (nth (1+ i) lst))
)
(setq m (list (list p0 p1 p)
(list p1 p p0)
(list p1 p0 p)
(list p p0 p1)
(list p p1 p0)
)
)
(setq l1
(car (vl-sort (mapcar (function (lambda (x)
(ch-para-lst x i lst)
)
)
m
)
(function (lambda (e1 e2)
(< (get-closedpolygon-length e1)
(get-closedpolygon-length e2)
)
)
)
)
)
)
(setq d1 (get-closedpolygon-length l1))
(if (< d1 d0)
(setq d0 d1
lst l1
)
)
)
)
(setq i (1+ i))
)
(setq l (f2 lst))
(setq i 0
l0 lst
d0 (get-closedpolygon-length lst)
)
(foreach a l
(if (and (< a _pi2) (setq p (nth i l0)))
(progn
(setq l1 (f1 p (vl-remove p lst)))
(setq d1 (get-closedpolygon-length l1))
(if (< d1 d0)
(setq d0 d1
lst l1
)
)
)
)
(setq i (1+ i))
)
(entmake
(append (list '(0 . "LWPOLYLINE")
'(100 . "AcDbEntity")
'(8 . "temp")
'(62 . 1)
'(100 . "AcDbPolyline")
(cons 90 (length lst))
'(70 . 1)
)
(mapcar (function (lambda (p) (cons 10 p))) lst)
)
)
(setq t2 (getvar "MilliSecs"))
(princ (strcat "\nTSP Length :" (rtos d0 2 0) "."))
(princ (strcat "\nUse Time :" (rtos (- t2 t1) 2 0) "ms."))
(princ)
)
;;;Use Funtions
;;;--------------------------------------------------------------
;; Convex hull of pts , Graham scan method
;; by Highflybird
(defun Graham-scan (ptl / hPs rPs PsY Pt0 sPs P Q)
(if (< (length ptl) 4) ;3点以下
ptl ;是本集合
(progn
(setq rPs (mapcar (function (lambda (x)
(if (= (length x) 3)
(cdr x) x)))
(mapcar 'reverse ptl));_点表的X和Y交换
PsY (mapcar 'cadr ptl) ;_点表的Y值的表
Pt0 (reverse (assoc (apply 'min PsY) rPs)) ;_最下面的点
sPs (sort-ad ptl Pt0) ;_按角度距离排序点集
hPs (list (caddr sPs) (cadr sPs) Pt0) ;_开始的三点
)
(foreach n (cdddr sPs) ;从第4点开始
(setq hPs (cons n hPs) ;把Pi加入到凸集
P (cadr hPs) ;Pi-1
Q (caddr hPs) ;Pi-2
)
(while (and q (> (det n P Q) -1e-6)) ;如果左转
(setq hPs (cons n (cddr hPs)) ;删除Pi-1点
P (cadr hPs) ;得到新的Pi-1点
Q (caddr hPs) ;得到新的Pi-2点
)))
hPs ;返回凸集
))
)
;;;以最下面的点为基点，按照角度和距离分类点集
(defun sort-ad (pl pt)
(vl-sort pl
(function (lambda (e1 e2 / an1 an2)
(setq an1 (angle pt e1)
an2 (angle pt e2))
(if (equal an1 an2 1e-6);_这里降低误差，以适应工程需求
(< (distance pt e1) (distance pt e2))
(< an1 an2)
))))
)
;;定义三点的行列式,即三点之倍面积
(defun det (p1 p2 p3)
(- (* (- (car p2) (car p1)) (- (cadr p3) (cadr p1)))
(* (- (car p3) (car p1)) (- (cadr p2) (cadr p1)))
))
;;;
;;;------------------------
(defun my-getpt (/ ss i en l)
(setq ss (ssget '((0 . "point"))))
(setq i -1)
(while (setq en (ssname ss (setq i (1+ i))))
(setq l (cons (cdr (assoc 10 (entget en))) l))
)
)
;;;------------------------
;;;
;;(ins-lst 10 5 '(1 2 3 4 5))
;; i 为新插入元素的位置
(defun ins-lst (new i lst / len fst)
(cond
((minusp i)
lst
)
((> i (setq len (length lst)))
lst
)
((> i (/ len 2))
(reverse (ins-lst new (- len i) (reverse lst)))
)
(t
(append
(progn
(setq fst nil)
(repeat (rem i 4)
(setq fst (cons (car lst) fst)
lst (cdr lst)
)
)
(repeat (/ i 4)
(setq fst (cons (cadddr lst)
(cons (caddr lst)
(cons
(cadr lst)
(cons
(car lst)
fst
)
)
)
)
lst (cddddr lst)
)
)
(reverse fst)
)
(list new)
lst
)
)
)
)
;;;------------------------
;;
;;(ch-para-lst '(7 8 9) 3 '(1 2 3 4 5))
(defun ch-para-lst (para i lst / len fst)
(setq len (length lst))
(cond
((minusp i)
lst
)
((> i (1- len))
lst
)
((= i 0)
(cons (cadr para)
(cons (caddr para)
(reverse (cons (car para) (cdr (reverse (cddr lst)))))
)
)
)
((= i (1- len))
(reverse
(append (cdr (reverse para))
(cddr (reverse (cons (last para) (cdr lst))))
)
)
)
((> i (/ len 2))
(reverse
(ch-para-lst (reverse para) (- len i 1) (reverse lst))
)
)
(t
(append
(progn
(setq fst nil)
(repeat (rem i 4)
(setq fst (cons (car lst) fst)
lst (cdr lst)
)
)
(repeat (/ i 4)
(setq fst (cons (cadddr lst)
(cons (caddr lst)
(cons
(cadr lst)
(cons
(car lst)
fst
)
)
)
)
lst (cddddr lst)
)
)
(reverse
(cons (caddr para)
(cons (cadr para) (cons (car para) (cdr fst)))
)
)
)
(cdr lst)
)
)
)
)
;;;------------------------
;;
(defun get-minadddist-i (lst p)
(car
(vl-sort-i
(mapcar (function (lambda (p1 p2)
(- (+ (distance p p1) (distance p p2))
(distance p1 p2)
)
)
)
(cons (last lst) lst)
lst
)
'<
)
)
)
;;;------------------------
(defun get-closest-i (lst p)
(car
(vl-sort-i
(mapcar
(function
(lambda (p1 p2 / pt d d1 d2)
(setq pt (inters p
(polar p (+ (/ pi 2.) (angle p1 p2)) 1.)
p1
p2
nil
)
d (distance p1 p2)
d1 (distance p p1)
d2 (distance p p2)
)
(if pt
(if (equal (+ (distance pt p1) (distance pt p2)) d 1e-8)
(distance p pt)
d2
)
1e99
)
)
)
(cons (last lst) lst)
lst
)
'<
)
)
)
;;;------------------------
;;
(defun get-closedpolygon-length (l)
(apply (function +)
(mapcar (function (lambda (p1 p2)
(distance p1 p2)
)
)
(cons (last l) l)
l
)
)
)

(defun c:test (/ foo f2 ptl lst l n i d0 l0 l1 d1) 
  ;;by GSLS(SS) 
  ;;refer ElpanovEvgeniy's method from  <a href=\"http://www.theswamp.org/index.php?topic=30434.75\" target=\"_blank\">http://www.theswamp.org/index.php?topic=30434.75</a> 
  ;;2012-8-10 
  (defun foo (l / D D0 D1) 
    (setq l0 (mapcar (function list) (cons (last l) l) l)) ;_  setq 
 ;_  defun 
    (setq d0 (get-closedpolygon-length l)) 
    (while 
      (> d0 
         (progn 
           (foreach a l0 
             (setq d (get-closedpolygon-length l)) 
             (setq l1 (vl-remove (car a) (vl-remove (cadr a) l))) 
             (setq l1 (f1 (car a) l1)) 
             (setq l1 (f1 (cadr a) l1)) 
             (if (> d 
                    (setq d1 (get-closedpolygon-length l1)) 
                 ) 
               (setq d d1 
                     l l1 
               ) ;_  setq 
             ) ;_  if 
             (setq l1 (vl-remove (car a) (vl-remove (cadr a) l))) 
             (setq l1 (f1 (cadr a) l1)) 
             (setq l1 (f1 (car a) l1)) 
             (if (> d 
                    (setq d1 (get-closedpolygon-length l1)) 
                 ) 
               (setq d d1 
                     l l1 
               ) 
             ) 
           ) 
           d 
         ) ;_  progn 
      ) ;_  < 
       (setq d0 d) 
    ) ;_  while    
    (setq d (get-closedpolygon-length l))    
    l 
  ) 
  (defun f1 (a l) 
    (ins-lst a (get-closest-i l a) l) 
  ) 
  (defun f2 (lst) 
    (mapcar (function (lambda (p0 p p1 / a) 
                        (setq a (- (angle p p0) (angle p p1))) 
                        (if (< a (- pi)) 
                          (abs (+ a pi pi)) 
                          (if (> a pi) 
                            (abs (- a pi pi)) 
                            (abs a) 
                          ) 
                        ) 
                      ) 
            ) 
            (cons (last lst) lst) 
            lst 
            (reverse (cons (car lst) (reverse (cdr lst)))) 
    ) 
  ) 
  (setq        ptl (my-getpt) 
        ptl (mapcar (function (lambda (p) (list (car p) (cadr p)))) ptl) 
  ) 
  (setq t1 (getvar "MilliSecs")) 
  (setq lst (Graham-scan ptl)) 
  (foreach a lst 
    (setq ptl (vl-remove a ptl)) 
  ) 
  (while (and (> (length ptl) 2) (setq l (Graham-scan ptl))) 
    (foreach p l 
      (setq ptl (vl-remove p ptl)) 
      (setq n (get-minadddist-i lst p)) 
      (setq lst (ins-lst p n lst)) 
    ) 
  ) 
  (if ptl 
    (foreach p ptl 
      (setq n (get-minadddist-i lst p)) 
      (setq lst (ins-lst p n lst)) 
    ) 
  ) 
  (setq lst (foo lst)) 
  (setq l (f2 lst)) 
  (setq        i  0 
        l0 lst 
        n  (length lst) 
        d0 (get-closedpolygon-length lst) 
  ) 
  (foreach a l 
    (if        (and (< a _pi3) (= (setq p (nth i lst)) (nth i l0))) 
      (progn 
        (if (= i 0) 
          (setq p0 (last lst)) 
          (setq p0 (nth (1- i) lst)) 
        ) 
        (if (= i (1- n)) 
          (setq p1 (car lst)) 
          (setq p1 (nth (1+ i) lst)) 
        ) 
        (setq m        (list (list p0 p1 p) 
                      (list p1 p p0) 
                      (list p1 p0 p) 
                      (list p p0 p1) 
                      (list p p1 p0) 
                ) 
        ) 
        (setq l1 
               (car (vl-sort (mapcar (function (lambda (x) 
                                                 (ch-para-lst x i lst) 
                                               ) 
                                     ) 
                                     m 
                             ) 
                             (function (lambda (e1 e2) 
                                         (< (get-closedpolygon-length e1) 
                                            (get-closedpolygon-length e2) 
                                         ) 
                                       ) 
                             ) 
                    ) 
               ) 
        ) 
        (setq d1 (get-closedpolygon-length l1)) 
        (if (< d1 d0) 
          (setq        d0  d1 
                lst l1 
          ) 
        ) 
      ) 
    ) 
    (setq i (1+ i)) 
  ) 
  (setq l (f2 lst)) 
  (setq        i  0 
        l0 lst 
        d0 (get-closedpolygon-length lst) 
  ) 
  (foreach a l 
    (if        (and (< a _pi2) (setq p (nth i l0))) 
      (progn 
        (setq l1 (f1 p (vl-remove p lst))) 
        (setq d1 (get-closedpolygon-length l1)) 
        (if (< d1 d0) 
          (setq        d0  d1 
                lst l1 
          ) 
        ) 
      ) 
    ) 
    (setq i (1+ i)) 
  ) 
  (entmake 
    (append (list '(0 . "LWPOLYLINE") 
                  '(100 . "AcDbEntity") 
                  '(8 . "temp") 
                  '(62 . 1) 
                  '(100 . "AcDbPolyline") 
                  (cons 90 (length lst)) 
                  '(70 . 1) 
            ) 
            (mapcar (function (lambda (p) (cons 10 p))) lst) 
    ) 
  ) 
  (setq t2 (getvar "MilliSecs")) 
  (princ (strcat "\nTSP Length :" (rtos d0 2 0) ".")) 
  (princ (strcat "\nUse Time :" (rtos (- t2 t1) 2 0) "ms.")) 
  (princ) 
) 
;;;Use Funtions 
;;;-------------------------------------------------------------- 
;; Convex hull of pts , Graham scan method 
;; by Highflybird 
  (defun Graham-scan (ptl / hPs rPs PsY Pt0 sPs P Q) 
    (if        (< (length ptl) 4)                ;3点以下 
      ptl                                ;是本集合 
      (progn 
        (setq rPs (mapcar (function (lambda (x) 
                                      (if (= (length x) 3) 
                                        (cdr x)        x))) 
                          (mapcar 'reverse ptl));_点表的X和Y交换 
              PsY (mapcar 'cadr ptl) ;_点表的Y值的表 
              Pt0 (reverse (assoc (apply 'min PsY) rPs)) ;_最下面的点       
              sPs (sort-ad ptl Pt0) ;_按角度距离排序点集 
              hPs (list (caddr sPs) (cadr sPs) Pt0) ;_开始的三点 
        ) 
        (foreach n (cdddr sPs)                ;从第4点开始 
          (setq        hPs (cons n hPs)        ;把Pi加入到凸集 
                P   (cadr hPs)                ;Pi-1 
                Q   (caddr hPs)                ;Pi-2 
          ) 
          (while (and q (> (det n P Q) -1e-6)) ;如果左转 
            (setq hPs (cons n (cddr hPs)) ;删除Pi-1点 
                  P   (cadr hPs)        ;得到新的Pi-1点 
                  Q   (caddr hPs)        ;得到新的Pi-2点 
            ))) 
        hPs                                ;返回凸集 
      )) 
  ) 
;;;以最下面的点为基点，按照角度和距离分类点集 
(defun sort-ad (pl pt) 
  (vl-sort pl 
           (function (lambda (e1 e2 / an1 an2) 
               (setq an1 (angle pt e1) 
                     an2 (angle pt e2)) 
               (if (equal an1 an2 1e-6);_这里降低误差，以适应工程需求 
                 (< (distance pt e1) (distance pt e2)) 
                 (< an1 an2) 
               )))) 
) 
;;定义三点的行列式,即三点之倍面积 
(defun det (p1 p2 p3) 
  (- (* (- (car p2) (car p1)) (- (cadr p3) (cadr p1))) 
     (* (- (car p3) (car p1)) (- (cadr p2) (cadr p1))) 
  )) 
;;; 
;;;------------------------ 
(defun my-getpt        (/ ss i en l) 
  (setq ss (ssget '((0 . "point")))) 
  (setq i -1) 
  (while (setq en (ssname ss (setq i (1+ i)))) 
    (setq l (cons (cdr (assoc 10 (entget en))) l)) 
  ) 
) 
;;;------------------------ 
;;; 
;;(ins-lst 10 5 '(1 2 3 4 5)) 
;; i 为新插入元素的位置 
(defun ins-lst (new i lst / len fst) 
  (cond 
    ((minusp i) 
     lst 
    ) 
    ((> i (setq len (length lst))) 
     lst 
    ) 
    ((> i (/ len 2)) 
     (reverse (ins-lst new (- len i) (reverse lst))) 
    ) 
    (t 
     (append 
       (progn 
         (setq fst nil) 
         (repeat (rem i 4) 
           (setq fst (cons (car lst) fst) 
                 lst (cdr lst) 
           ) 
         ) 
         (repeat (/ i 4) 
           (setq fst (cons (cadddr lst) 
                           (cons (caddr lst) 
                                 (cons 
                                   (cadr lst) 
                                   (cons 
                                     (car lst) 
                                     fst 
                                   ) 
                                 ) 
                           ) 
                     ) 
                 lst (cddddr lst) 
           ) 
         ) 
         (reverse fst) 
       ) 
       (list new) 
       lst 
     ) 
    ) 
  ) 
) 
;;;------------------------ 
;; 
;;(ch-para-lst '(7 8 9) 3 '(1 2 3 4 5)) 
(defun ch-para-lst (para i lst / len fst) 
  (setq len (length lst)) 
  (cond 
    ((minusp i) 
     lst 
    ) 
    ((> i (1- len)) 
     lst 
    ) 
    ((= i 0) 
     (cons (cadr para) 
           (cons (caddr para) 
                 (reverse (cons (car para) (cdr (reverse (cddr lst))))) 
           ) 
     ) 
    ) 
    ((= i (1- len)) 
     (reverse 
       (append (cdr (reverse para)) 
               (cddr (reverse (cons (last para) (cdr lst)))) 
       ) 
     ) 
    ) 
    ((> i (/ len 2)) 
     (reverse 
       (ch-para-lst (reverse para) (- len i 1) (reverse lst)) 
     ) 
    ) 
    (t 
     (append 
       (progn 
         (setq fst nil) 
         (repeat (rem i 4) 
           (setq fst (cons (car lst) fst) 
                 lst (cdr lst) 
           ) 
         ) 
         (repeat (/ i 4) 
           (setq fst (cons (cadddr lst) 
                           (cons (caddr lst) 
                                 (cons 
                                   (cadr lst) 
                                   (cons 
                                     (car lst) 
                                     fst 
                                   ) 
                                 ) 
                           ) 
                     ) 
                 lst (cddddr lst) 
           ) 
         ) 
         (reverse 
           (cons (caddr para) 
                 (cons (cadr para) (cons (car para) (cdr fst))) 
           ) 
         ) 
       ) 
       (cdr lst) 
     ) 
    ) 
  ) 
) 
;;;------------------------ 
;; 
(defun get-minadddist-i        (lst p) 
  (car 
    (vl-sort-i 
      (mapcar (function        (lambda        (p1 p2) 
                          (- (+ (distance p p1) (distance p p2)) 
                             (distance p1 p2) 
                          ) 
                        ) 
              ) 
              (cons (last lst) lst) 
              lst 
      ) 
      '< 
    ) 
  ) 
) 
;;;------------------------ 
(defun get-closest-i (lst p) 
  (car 
    (vl-sort-i 
      (mapcar 
        (function 
          (lambda (p1 p2 / pt d d1 d2) 
            (setq pt (inters p 
                             (polar p (+ (/ pi 2.) (angle p1 p2)) 1.) 
                             p1 
                             p2 
                             nil 
                     ) 
                  d  (distance p1 p2) 
                  d1 (distance p p1) 
                  d2 (distance p p2) 
            ) 
            (if        pt 
              (if (equal (+ (distance pt p1) (distance pt p2)) d 1e-8) 
                (distance p pt) 
                d2 
              ) 
              1e99 
            ) 
          ) 
        ) 
        (cons (last lst) lst) 
        lst 
      ) 
      '< 
    ) 
  ) 
) 
;;;------------------------ 
;; 
(defun get-closedpolygon-length        (l) 
  (apply (function +) 
         (mapcar (function (lambda (p1 p2) 
                             (distance p1 p2) 
                           ) 
                 ) 
                 (cons (last l) l) 
                 l 
         ) 
  ) 
)

aimisiyou · 发表于 2018-2-10 14:57:02

有测试图吗？我有空用遗传算法测试下。500个点运行时间估计够呛。

Lisphk · 发表于 2018-2-10 15:18:29

aimisiyou 发表于 2018-2-10 14:57

谢谢， 500和1000随机点的DWG

请点击此处下载

查看状态：需购买或无权限

您的用户组是：游客

文件名称:500-1000随机点.rar
下载次数:12 文件大小:58.1 KB
下载权限: 不限以上 [免费赚D豆]

HLCAD · 发表于 2018-2-11 10:51:53

向大师们学习

xinrstar · 发表于 2018-2-11 19:35:44

真不错，学习了

dnbcgrass · 发表于 2018-2-12 08:00:38

回复学习学习！

sicky111 · 发表于 2018-2-16 00:01:57

学习一下。

lj524917100 · 发表于 2018-2-22 10:33:54

学习一下大作

laiz3000 · 发表于 2018-2-28 14:48:11

厉害

flowerson · 发表于 2018-5-23 09:26:08

有没有通用函数？

newer · 发表于 2018-5-23 13:15:49

flowerson 发表于 2018-5-23 09:26
有没有通用函数？

(xdrx_points_connect pts)

连线gif.gif

(defun c:tt ()
(if (setq ss (ssget '((0 . "POINT"))))
(progn (setq pts (xdrx_entity_getproperty ss "position")
pts (xdrx_points_connect pts)
)
(xdrx_polyline_make pts)
(xdrx_setpropertyvalue (entlast) "color" 1)
)
)
(princ)
)

小菜 · 发表于 2018-5-23 13:32:48

谢谢分享，，。。

向嘟嘟 · 发表于 2018-5-23 20:43:52

看不懂呀！！！！

账号		自动登录	找回密码
密码			立即注册

[已解决] 【已解决】（指定起始点的相对最短路径连线）自交的多段线变成顶点不变的不自交的...

点评