获得SPLINE的包围范围

lisp_beginner

总获帮助，把自己收集的代码分享给大家

(defun getSplineBoundingBox (e / p1 p2 d ax bb)
  (vla-getboundingbox (vlax-ename->vla-object e) 'p1 'p2)
  (setq        p1 (vlax-safearray->list p1)
        p2 (vlax-safearray->list p2)
        d  (distance p1 p2)
        p1 (mapcar '- p1 (list d d d))
        p2 (mapcar '+ p2 (list d d d))
        ax (mapcar '(lambda (n) (sp e n))
                   '((t nil nil) (nil t nil) (nil nil t))
           )
        bb (mapcar
             (function
               (lambda (p)
                 (mapcar
                   (function
                     (lambda (f a n)
                       ((eval f) (vlax-curve-getclosestpointto a (pp p n)))
                     )
                   )
                   '(car cadr caddr)
                   ax
                   '((t nil nil) (nil t nil) (nil nil t))
                 )
               )
             )
             (list p1 p2)
           )
  )
  (mapcar 'entdel ax)
  bb
)
;spline projection on axis line
(defun sp (e n)
  (entmakex
    (mapcar (function (lambda (x)
                        (if (eq (car x) 10)
                          (cons (car x) (pp (cdr x) n))
                          x
                        )
                      )
            )
            (vl-remove-if
              '(lambda (x)
                 (vl-position (car x) '(-1 5 330 67 410 8 210 62 11))
               )
              (entget e)
            )
    )
  )
)
;point projection on axis line
(defun pp (p n) (mapcar 'if n p '(0.0 0.0 0.0)))

7325pink

谢谢楼主！拜读了！

sicky111

谢谢分享。