使用函数(xdrx_curve->polyline ss)出现的问题

dyjwyqz5221 · 发表于 2018-5-11 14:36:53

line线变复线时，出现了奇怪的连接，望高手给予解答。我用的api是2018.4.25的版本。 A4V7~XG42$YVU4JH(8V[6YJ.png

dyjwyqz5221 · 发表于 2018-5-24 13:13:51

用内部选择集进行直线长度的过滤，成功解决了此问题，变复线都没问题了。还是谢谢大家。

dyjwyqz5221 · 发表于 2018-5-24 13:32:46

(defun c:bfx ( / e e1 ss ss1 ss2 oldlay )
 (xdrx_setvar "CMDECHO" 0)
 (xdrx_setvar "osmode" 0)
 (setq oldlay(getvar "clayer"));;;获取当前的图层
 (_CreateLayer "0-详图闭合线框")
 (if (progn
 (prompt "\r选取要变复线的LINE或非封闭复线<退出>:")
 (setq ss (ssget '((-4 . "<OR")
 (0 . "LINE")
 (-4 . "<and")
 (0 . "*POLYLINE")
 (39 . 0.0)
 (70 . 0)
 (-4 . "and>")
 (-4 . "OR>")
 )
 )
 );;;setq
 );;;progn
 (progn
 (xdrx_begin)
 (setq ss1(ssadd))
 (setq ss2(ssadd))
 ;;;以下用内部选择集进行过滤，解决了图元顺序的问题，变复线很成功。
 (xdrx_setsstodb ss 0)
 (while (setq e (xdrx_getentdata 0))
 (if (>= (xdrx_getpropertyvalue e "length") 250.0)
 (ssadd e ss1)
 );;;if
 );;;while
 (if (> (sslength ss1) 0)
 (progn
 (xdrx_curve->polyline ss1)
 (xdrx_setsstodb ss1 0)
 (while (setq e1 (xdrx_getentdata 0))
 (if (xdrx_getpropertyvalue e1 "isclosed")
 (ssadd e1 ss2)
 );;;if
 );;;while
 (xdrx_entity_setLayer ss2 "0-详图闭合线框");;;;改变选择集ss1到"0-详图闭合线框"上。
 (xdrx_entity_setColor ss2 6);;;;改变选择集实体颜色。6---颜色号，紫色；
 (prompt (strcat "\n选择了 " (itoa (sslength ss1)) " 个实体，转换成了 "
 (itoa (sslength ss2)) " 个封闭复线.\n")
 );;;prompt
 );;progn
 (prompt "\n未选择到长度>=375.0的直线或非封闭复线！\n")
 );;;if
 );;;progn
 (prompt "\n未选择到直线或非封闭复线！\n")
 );;;if
 (setvar "clayer" oldlay) ;;;;;图层回到原先的图层
 (xdrx_end)
 (xdrx_setvar "CMDECHO" 1)
 (xdrx_setvar "osmode" 1)
 (princ)
);;;defun

newer · 发表于 2018-5-11 14:36:54

本帖最后由 newer 于 2018-5-24 14:53 编辑

dyjwyqz5221 发表于 2018-5-24 13:32
(defun c:bfx ( / e e1 ss ss1 ss2  oldlay )
      (xdrx_setvar "CMDECHO" 0)
      (xdrx_setva ...

帮你修改下
1、不用创建层，xdrx_setpropertyvalue 或者 xdrx_entity_setlayer 层不存在，自动创建。
2、设置层和设置颜色，可以放到 xdrx_setpropertyvalue 一起，速度更快。

(defun c:bfx (/ e e1 ss ss1 ss2 oldlay)
(if (and (xdrx_initssget "\r选取要变复线的LINE或非封闭复线<退出>:")
(setq ss (xdrx_ssget
'((-4 . "<OR")
(0 . "LINE")
(-4 . "<and")
(0 . "*POLYLINE")
(39 . 0.0)
(70 . 0)
(-4 . "and>")
(-4 . "OR>")
)
)
)
)
(progn (xdrx_begin)
(xdrx_sysvar_push '("osmode" 0 "cmdecho" 0))
(setq ss1 (ssadd))
(setq ss2 (ssadd))
(xdrx_setsstodb ss 0)
(while (setq e (xdrx_getentdata 0))
(if (>= (xdrx_getpropertyvalue e "length") 250.0)
(ssadd e ss1)
)
)
(if (> (sslength ss1) 0)
(progn (xdrx_curve->polyline ss1)
(xdrx_setsstodb ss1 0)
(while (setq e1 (xdrx_getentdata 0))
(if (xdrx_getpropertyvalue e1 "isclosed")
(ssadd e1 ss2)
)
)
(xdrx_entity_setproperty ss2 "layer" "0-详图闭合线框" "color" 6)
(xdrx_prompt "\n选择了 " (sslength ss1) " 个实体，转换成了 "(sslength ss2) " 个封闭复线.\n")
)
(xdrx_prompt "\n未选择到长度>=375.0的直线或非封闭复线！\n")
)
(xdrx_sysvar_pop)
(xdrx_end)
)
(xdrx_prompt "\n未选择到直线或非封闭复线！\n")
)
(princ)
)

(defun c:bfx (/ e e1 ss ss1 ss2 oldlay) 
  (if (and (xdrx_initssget "\r选取要变复线的LINE或非封闭复线<退出>:") 
           (setq ss (xdrx_ssget 
                      '((-4 . "<OR") 
                        (0 . "LINE") 
                        (-4 . "<and") 
                        (0 . "*POLYLINE") 
                        (39 . 0.0) 
                        (70 . 0) 
                        (-4 . "and>") 
                        (-4 . "OR>") 
                       ) 
                    ) 
           ) 
      ) 
    (progn (xdrx_begin) 
           (xdrx_sysvar_push '("osmode" 0 "cmdecho" 0)) 
           (setq ss1 (ssadd)) 
           (setq ss2 (ssadd)) 
           (xdrx_setsstodb ss 0) 
           (while (setq e (xdrx_getentdata 0)) 
             (if (>= (xdrx_getpropertyvalue e "length") 250.0) 
               (ssadd e ss1) 
             ) 
           ) 
           (if (> (sslength ss1) 0) 
             (progn (xdrx_curve->polyline ss1) 
                    (xdrx_setsstodb ss1 0) 
                    (while (setq e1 (xdrx_getentdata 0)) 
                      (if (xdrx_getpropertyvalue e1 "isclosed") 
                        (ssadd e1 ss2) 
                      ) 
                    ) 
                    (xdrx_entity_setproperty ss2 "layer" "0-详图闭合线框" "color" 6) 
                    (xdrx_prompt "\n选择了 " (sslength ss1) " 个实体，转换成了 "(sslength ss2) " 个封闭复线.\n") 
             ) 
             (xdrx_prompt "\n未选择到长度>=375.0的直线或非封闭复线！\n") 
           ) 
           (xdrx_sysvar_pop) 
           (xdrx_end) 
    ) 
    (xdrx_prompt "\n未选择到直线或非封闭复线！\n") 
  ) 
  (princ) 
)

newer · 发表于 2018-5-11 14:41:22

本帖最后由 newer 于 2018-5-11 14:43 编辑

1、所有的讨论基于最新版本的API，所以，你先升级到API到目前的2018.0508版本。2、请把 DWG图压缩传上来。

Lispboy · 发表于 2018-5-11 15:02:05

XDRX API 有个精度控制，确定那些点是挨着的，如果精度控制过大，就有可能造成距离很远的也被认为是一个点

精度控制的函数是

(xdrx_document_setprec 点精度向量精度)

你可以用xdrx_curve->polyline前，设置下
(xdrx_document_setprec 1e-4 0.01)

dyjwyqz5221 · 发表于 2018-5-11 15:14:38

使用2018.5.8的api结果一样。顺便将我编制的变复线lsp命令拷贝进去了，帮忙测试下，看看问题出在哪里了，多谢！！！

dyjwyqz5221 · 发表于 2018-5-11 15:19:41

精度修改了，结果一样。测试中感觉与选择集里图元的顺序有关系，我的变复线命令里，对直线的长度做了过滤。

Lispboy · 发表于 2018-5-11 15:32:25

dyjwyqz5221 发表于 2018-5-11 15:19
精度修改了，结果一样。测试中感觉与选择集里图元的顺序有关系，我的变复线命令里，对直线的长度做了过滤。

确实跟选择集顺序有关，xdrx_curve->polyline最可靠的是给实体名，你明确告诉函数哪两个是相挨着的。
你图中这种，建议你换个函数

(xdrx_setvar "boundaryextendlength" 10.0) ;; 10.0你根据线间隙，自己设置。
(xdrx_geom_searchoutline (ssget '((0 . "*LINE,ARC,ELLIPSE,CIRCLE"))))

dyjwyqz5221 · 发表于 2018-5-11 15:52:11

应该不是精度的问题，是我将直线选择集对长度小于500的进行了过滤（去掉长度小于500的图元），重新形成选择集的问题。其他图变复线都没问题，只有这个图有问题。

小陶 · 发表于 2018-5-11 15:53:34

这个用ET的flatten 执行过就不会出玩这种情况了！

dyjwyqz5221 · 发表于 2018-5-11 15:53:48

如对选择集未进行过滤，虽然得不到自己想要的结果，但是却不出现线段连接错误的问题。

Lispboy · 发表于 2018-5-11 16:14:45

dyjwyqz5221 发表于 2018-5-11 15:53
如对选择集未进行过滤，虽然得不到自己想要的结果，但是却不出现线段连接错误的问题。

关键是你中间有个竖短线，多上它，会有很多组合，你选择集去掉它，在生成试试。给选择集做参数，有很多未知可能，哪些在一起，哪些不在一起，所以，你给的选择集要处理到确实能连到一起的。
最准确的是 (xdrx_curve->polyline e1 e2 .....en)

你这样的图，最好用 (xdrx_geom_searchregions (ssget)) 和 (xdrx_geom_searchoutline (ssget))

dyjwyqz5221 · 发表于 2018-5-11 16:42:31

好的，我试试，谢谢大家的帮助。我们是审图中心的，图纸是其他设计单位出的，情况很多，所以难免会出现异常的情况，很难做到全覆盖。

newer · 发表于 2018-5-24 13:38:21

dyjwyqz5221 发表于 2018-5-24 13:32
(defun c:bfx ( / e e1 ss ss1 ss2  oldlay )
      (xdrx_setvar "CMDECHO" 0)
      (xdrx_setva ...

这个代码做什么的，楼主？最好配上个动图。

账号		自动登录	找回密码
密码			立即注册

[已解决] 使用函数(xdrx_curve->polyline ss)出现的问题

最佳答案

点评

评分

评分