新人求助

杨疯子 · 发表于 2018-5-28 22:44:33

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

求哪位大神能够编出能够统计矩形边长乘边长并且生成面积制表的lisp 例如矩形的边长乘边长=面积最好有源码 QQ截图20180528224253.png

marting · 发表于 2018-5-28 22:50:56

上传你的DWG，并且手工做出结果标注在图上。

杨疯子 · 发表于 2018-5-29 18:46:30

marting 发表于 2018-5-28 22:50
上传你的DWG，并且手工做出结果标注在图上。

希望你能够帮助我感谢了！！！我想要lisp源码

newer · 发表于 2018-5-29 18:51:22

本帖最后由 newer 于 2018-5-29 18:52 编辑

你那个弧线也算矩形里面的？DWG图在哪呢？

杨疯子 · 发表于 2018-5-29 19:15:06

newer 发表于 2018-5-29 18:51
你那个弧线也算矩形里面的？DWG图在哪呢？

圆弧也算

杨疯子 · 发表于 2018-5-29 19:16:46

本帖最后由杨疯子于 2018-5-29 19:21 编辑

杨疯子发表于 2018-5-29 19:15
圆弧也算

貌似不能上传dwg文件

杨疯子 · 发表于 2018-5-29 19:19:47

原文件我是做门窗的主要是一个个尺寸输入到excel里面太麻烦了

newer · 发表于 2018-5-29 20:00:30

杨疯子发表于 2018-5-29 19:19
原文件我是做门窗的主要是一个个尺寸输入到excel里面太麻烦了

把那个统计矩形的插件加行代码就行了
搜狗截图20180529200026.png

(defun c:XDTB_TJRec (/ ar ar1 data e i key l l1 l2 len len1 lst num nums p1 p2 p3 pt pts scl ss tb
tlen txth val w x y
)
(defun _process (e)
(if (or (and (XD::Polyline:IsRectang e)
(setq pts (xdrx_getpropertyvalue e "vertices"))
)
(setq pts (xdrx_entity_box e))
)
(progn (setq p1 (car pts)
p2 (cadr pts)
p3 (caddr pts)
l1 (distance p1 p2)
l2 (distance p2 p3)
l (list l1 l2)
l (vl-sort l '(lambda (x y) (> x y)))
)
(list (rtos (car l) 2 #xd_var_rectang_tol)
(rtos (cadr l) 2 #xd_var_rectang_tol)
)
)
)
)
(defun _keyword (key)
(cond ((= key "D")
(if (setq val (getint
(xdrx_prompt "\n保留小数位数<" #xd_var_rectang_tol ">:" t)
)
)
(setq #xd_var_rectang_tol val)
)
)
((= key "E")
(if (setq val (getreal
(xdrx_prompt "\n表格字高<" #xd_var_rectang_txtheight ">:" t)
)
)
(setq #xd_var_rectang_txtheight val)
)
)
)
(_prompt)
)
(defun _prompt ()
(xdrx_prompt
"\n当前设置: 字高(" #xd_var_rectang_txtheight ") / 小数位数(" #xd_var_rectang_tol ")"
)
)
(xdrx_begin)
(xdrx_sysvar_push '("dimzin" 0))
(if (not #xd_var_rectang_tol)
(setq #xd_var_rectang_tol 1)
)
(if (not #xd_var_rectang_txtheight)
(setq #xd_var_rectang_txtheight 3.5)
)
(_prompt)
(if (and (xdrx_initget "D E")
(xdrx_initssget
"\n选取要统计的矩形(非矩形按包围框)[字高(E)/小数位(D)]<退出>:"
"D E"
""
"_keyword"
)
(setq ss (xdrx_ssget '((0 . "*POLYLINE") (-4 . "&=") (70 . 1))))
)
(progn (setq data nil
i 0
)
(mapcar '(lambda (x)
(if (setq lst (_process x))
(setq lst (cons (apply 'strcat lst) lst)
data (cons lst data)
)
)
)
(xdrx_pickset->ents ss)
)
(setq data (xd::list:groupbyindex data 0.1)
data (vl-sort data '(lambda (x y) (< (car x) (car y))))
i 0
tlen 0.0
nums 0
ar 0.0
data (mapcar '(lambda (x)
(setq val (list (itoa (setq i (1+ i)))
(setq l (caadr x))
(setq w (cadadr x))
(setq num (itoa (length (cdr x))))
(setq len (* (atoi num) (* 2 (+ (atof l) (atof w))))
ar1 (* (atoi num) (* (atof l) (atof w)))
nums (+ nums (atoi num))
len1 (rtos len 2 #xd_var_rectang_tol)
)
(rtos ar1 2 #xd_var_rectang_tol)
)
)
(setq tlen (+ len tlen)
ar (+ ar1 ar)
)
val
)
data
)
data (cons (list "编号" "长度" "高度" "数量" "总长" "面积")
data
)
data (cons (list "矩形统计表" nil nil nil nil nil) data)
data (append data
(list (list "合计"
nil
""
(itoa nums)
(rtos tlen 2 #xd_var_rectang_tol)
(rtos ar 2 #xd_var_rectang_tol)
)
)
)
)
(if (setq pt (getpoint "\n表格插入点<退出>:"))
(progn (xd::text:init 1)
(setq scl (* (xd::var:getratio) (XD::Var:GetScaleRatio))
txth (* scl #xd_var_rectang_txtheight)
)
(setq tb (xd::table:makefromlist data pt txth (/ txth 3.0)))
)
)
)
)
(xdrx_sysvar_pop)
(xdrx_end)
(princ)
)

(defun c:XDTB_TJRec (/ ar ar1 data e i key l l1 l2 len len1 lst num nums p1 p2 p3 pt pts scl ss tb 
                     tlen txth val w x y 
                    ) 
  (defun _process (e) 
    (if (or (and (XD::Polyline:IsRectang e) 
                 (setq pts (xdrx_getpropertyvalue e "vertices")) 
            ) 
            (setq pts (xdrx_entity_box e)) 
        ) 
      (progn (setq p1  (car pts) 
                   p2  (cadr pts) 
                   p3  (caddr pts) 
                   l1  (distance p1 p2) 
                   l2  (distance p2 p3) 
                   l   (list l1 l2) 
                   l   (vl-sort l '(lambda (x y) (> x y))) 
             ) 
             (list (rtos (car l) 2 #xd_var_rectang_tol) 
                   (rtos (cadr l) 2 #xd_var_rectang_tol) 
             ) 
      ) 
    ) 
  ) 
  (defun _keyword (key) 
    (cond ((= key "D") 
           (if (setq val (getint 
                           (xdrx_prompt "\n保留小数位数<" #xd_var_rectang_tol ">:" t) 
                         ) 
               ) 
             (setq #xd_var_rectang_tol val) 
           ) 
          ) 
          ((= key "E") 
           (if (setq val (getreal 
                           (xdrx_prompt "\n表格字高<" #xd_var_rectang_txtheight ">:" t) 
                         ) 
               ) 
             (setq #xd_var_rectang_txtheight val) 
           ) 
          ) 
    ) 
    (_prompt) 
  ) 
  (defun _prompt () 
    (xdrx_prompt 
      "\n当前设置: 字高(" #xd_var_rectang_txtheight ") / 小数位数(" #xd_var_rectang_tol ")" 
     ) 
  ) 
  (xdrx_begin) 
  (xdrx_sysvar_push '("dimzin" 0)) 
  (if (not #xd_var_rectang_tol) 
    (setq #xd_var_rectang_tol 1) 
  ) 
  (if (not #xd_var_rectang_txtheight) 
    (setq #xd_var_rectang_txtheight 3.5) 
  ) 
  (_prompt) 
  (if (and (xdrx_initget "D E") 
           (xdrx_initssget 
             "\n选取要统计的矩形(非矩形按包围框)[字高(E)/小数位(D)]<退出>:" 
             "D E" 
             "" 
             "_keyword" 
           ) 
           (setq ss (xdrx_ssget '((0 . "*POLYLINE") (-4 . "&=") (70 . 1)))) 
      ) 
    (progn (setq data nil 
                 i    0 
           ) 
           (mapcar '(lambda (x) 
                      (if (setq lst (_process x)) 
                        (setq lst  (cons (apply 'strcat lst) lst) 
                              data (cons lst data) 
                        ) 
                      ) 
                    ) 
                   (xdrx_pickset->ents ss) 
           ) 
           (setq data (xd::list:groupbyindex data 0.1) 
                 data (vl-sort data '(lambda (x y) (< (car x) (car y)))) 
                 i    0 
                 tlen 0.0 
                 nums 0 
                 ar   0.0 
                 data (mapcar '(lambda (x) 
                                 (setq val (list (itoa (setq i (1+ i))) 
                                                 (setq l (caadr x)) 
                                                 (setq w (cadadr x)) 
                                                 (setq num (itoa (length (cdr x)))) 
                                                 (setq len  (* (atoi num) (* 2 (+ (atof l) (atof w)))) 
                                                       ar1  (* (atoi num) (* (atof l) (atof w))) 
                                                       nums (+ nums (atoi num)) 
                                                       len1 (rtos len 2 #xd_var_rectang_tol) 
                                                 ) 
                                                 (rtos ar1 2 #xd_var_rectang_tol) 
                                           ) 
                                 ) 
                                 (setq tlen (+ len tlen) 
                                       ar   (+ ar1 ar) 
                                 ) 
                                 val 
                               ) 
                              data 
                      ) 
                 data (cons (list "编 号" "长 度" "高 度" "数 量" "总 长" "面 积") 
                            data 
                      ) 
                 data (cons (list "矩形统计表" nil nil nil nil nil) data) 
                 data (append data 
                              (list (list "合 计" 
                                          nil 
                                          "" 
                                          (itoa nums) 
                                          (rtos tlen 2 #xd_var_rectang_tol) 
                                          (rtos ar 2 #xd_var_rectang_tol) 
                                    ) 
                              ) 
                      ) 
           ) 
           (if (setq pt (getpoint "\n表格插入点<退出>:")) 
             (progn (xd::text:init 1) 
                    (setq scl  (* (xd::var:getratio) (XD::Var:GetScaleRatio)) 
                          txth (* scl #xd_var_rectang_txtheight) 
                    ) 
                    (setq tb (xd::table:makefromlist data pt txth (/ txth 3.0))) 
             ) 
           ) 
    ) 
  ) 
  (xdrx_sysvar_pop) 
  (xdrx_end) 
  (princ) 
)

杨疯子 · 发表于 2018-5-29 21:29:39

newer 发表于 2018-5-29 20:00
把那个统计矩形的插件加行代码就行了

很感谢能否上传一个压缩包啊我不想用晓东工具箱安装到CAD里面插件太多了担心会不兼容

marting · 发表于 2018-5-29 21:30:48

杨疯子发表于 2018-5-29 21:29
很感谢能否上传一个压缩包啊我不想用晓东工具箱安装到CAD里面插件太多了担心会不兼容

那就只下载 XDRX API安装，然后把代码拷贝回去保存LISP用。

杨疯子 · 发表于 2018-5-29 21:59:52

marting 发表于 2018-5-29 21:30
那就只下载 XDRX API安装，然后把代码拷贝回去保存LISP用。

好的。。。。。。。。。。。。

账号		自动登录	找回密码
密码			立即注册

[求助] 新人求助

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

点评

点评