十进制转十六进制，十六进制转十进制函数

Lisphk · 发表于 2018-11-1 13:25:29

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

;; int2hex.lsp
;; Base-10 Integer to Hexadecimal converter.
;; Accepts positive or negative integer argument, including 0.
;; Rejects non-integer argument with Alert.
;; Kent Cooper, January 2011
(defun int2hex (int / power neg int result div remain posval)
(if (/= (type int) 'INT)
(progn (alert "Requires integer argument.") (quit))
)
(setq power 1
neg (minusp int)
int (abs int)
result ""
)
(while (> int 0)
(setq div (expt 16 power)
remain (rem int div)
posval (/ remain (expt 16 (1- power)))
int (- int remain)
result (strcat (if (< posval 10)
(itoa posval)
(chr (+ 55 posval))
)
result
)
power (1+ power)
) ; end setq
) ; end while
(strcat (if neg
"-"
""
)
(if (= result "")
"0"
result
)
)
) ; end defun - int2hex
;; hex2int.lsp
;; Hexadecimal to base-10 Integer converter [e.g. for entity handles]
;; Modified/simplified from Frank Oquendo's (basetodecimal) function.
;; Added negative-argument capability and argument validity controls.
;; Kent Cooper, January 2011
(defun hex2int (hndl / result neg power tmp)
(if (/= (type hndl) 'STR)
(progn (alert "Requires string argument.") (quit))
)
(setq hndl (strcase hndl)
result 0
)
(if (= (substr hndl 1 1) "-")
(setq neg T
hndl (substr hndl 2)
)
)
(if (/= (vl-string-trim "0123456789ABCDEF" hndl) "")
(progn (alert "Invalid hexadecimal string.") (quit))
) ; end if
(repeat (setq power (strlen hndl))
(setq result (+ result
(* (- (setq tmp (ascii (substr hndl 1 1)))
(if (> tmp 64)
55
48
)
)
(expt 16 (setq power (1- power)))
)
)
hndl (substr hndl 2)
) ; end setq
) ; end while
(if neg
(- result)
result
)
) ; end defun - hex2int

;; int2hex.lsp 
;; Base-10 Integer to Hexadecimal converter. 
;; Accepts positive or negative integer argument, including 0. 
;; Rejects non-integer argument with Alert. 
;; Kent Cooper, January 2011 
(defun int2hex (int / power neg int result div remain posval) 
  (if (/= (type int) 'INT) 
    (progn (alert "Requires integer argument.") (quit)) 
  ) 
  (setq power  1 
        neg    (minusp int) 
        int    (abs int) 
        result "" 
  ) 
  (while (> int 0) 
    (setq div    (expt 16 power) 
          remain (rem int div) 
          posval (/ remain (expt 16 (1- power))) 
          int    (- int remain) 
          result (strcat (if (< posval 10) 
                           (itoa posval) 
                           (chr (+ 55 posval)) 
                         ) 
                         result 
                 ) 
          power  (1+ power) 
    )                                   ; end setq 
  )                                     ; end while 
  (strcat (if neg 
            "-" 
            "" 
          ) 
          (if (= result "") 
            "0" 
            result 
          ) 
  ) 
)                                       ; end defun - int2hex 
 
 
;; hex2int.lsp 
;; Hexadecimal to base-10 Integer converter [e.g. for entity handles] 
;; Modified/simplified from Frank Oquendo's (basetodecimal) function. 
;; Added negative-argument capability and argument validity controls. 
;; Kent Cooper, January 2011 
(defun hex2int (hndl / result neg power tmp) 
  (if (/= (type hndl) 'STR) 
    (progn (alert "Requires string argument.") (quit)) 
  ) 
  (setq hndl   (strcase hndl) 
        result 0 
  ) 
  (if (= (substr hndl 1 1) "-") 
    (setq neg  T 
          hndl (substr hndl 2) 
    ) 
  ) 
  (if (/= (vl-string-trim "0123456789ABCDEF" hndl) "") 
    (progn (alert "Invalid hexadecimal string.") (quit)) 
  )                                     ; end if 
  (repeat (setq power (strlen hndl)) 
    (setq result (+ result 
                    (* (- (setq tmp (ascii (substr hndl 1 1))) 
                          (if (> tmp 64) 
                            55 
                            48 
                          ) 
                       ) 
                       (expt 16 (setq power (1- power))) 
                    ) 
                 ) 
          hndl   (substr hndl 2) 
    )                                   ; end setq 
  )                                     ; end while 
  (if neg 
    (- result) 
    result 
  ) 
)                                       ; end defun - hex2int

marting · 发表于 2018-11-1 13:49:57

我这也有俩

;;;;;;
;; Hex to Decimal - Lee Mac
;; Converts a hexadecimal string to an integer
;; n - [str] string representing number to convert
;; Returns: [int] Decimal representation of supplied number
(defun LM:hex->dec (n)
((lambda (f)
(f (mapcar '(lambda (x)
(- x
(if (< x 65)
48
55
)
)
)
(reverse (vl-string->list n))
)
)
)
(lambda (c)
(if c
(+ (* 16 (f (cdr c))) (car c))
0
)
)
)
)
;++++++++++++ HEX2DECimal +++++++++++++++++++++++++
(defun h2d (s / sl c p x)
(setq c 1
p 0
)
(repeat (strlen s)
(setq sl (cons (ascii (substr (strcase s) c 1)) sl)
c (1+ c)
)
)
(foreach a sl
(setq p (max 1 (* p 16))
x (cons (* (if (< a 58)
(- a 48)
(- a 55)
)
p
)
x
)
)
)
(apply '+ x)
)

;;;;;; 
;; Hex to Decimal  -  Lee Mac 
;; Converts a hexadecimal string to an integer 
;; n - [str] string representing number to convert 
;; Returns: [int] Decimal representation of supplied number 
 
(defun LM:hex->dec (n) 
  ((lambda (f) 
     (f (mapcar '(lambda (x) 
                   (- x 
                      (if (< x 65) 
                        48 
                        55 
                      ) 
                   ) 
                 ) 
                (reverse (vl-string->list n)) 
        ) 
     ) 
   ) 
    (lambda (c) 
      (if c 
        (+ (* 16 (f (cdr c))) (car c)) 
        0 
      ) 
    ) 
  ) 
) 
 
                                        ;++++++++++++ HEX2DECimal +++++++++++++++++++++++++ 
(defun h2d (s / sl c p x) 
  (setq c 1 
        p 0 
  ) 
  (repeat (strlen s) 
    (setq sl (cons (ascii (substr (strcase s) c 1)) sl) 
          c  (1+ c) 
    ) 
  ) 
  (foreach a sl 
    (setq p (max 1 (* p 16)) 
          x (cons (* (if (< a 58) 
                       (- a 48) 
                       (- a 55) 
                     ) 
                     p 
                  ) 
                  x 
            ) 
    ) 
  ) 
  (apply '+ x) 
)

ll_j · 发表于 2018-11-2 11:04:40

以前也借明经通道函数整合过一个
http://bbs.xdcad.net/thread-468989-1-1.html

cabinsummer · 发表于 2020-7-21 16:18:00

我也来一个16进制转10进制

(defun hex2dec(hex / map lst len p)
(setq map '(48 49 50 51 52 53 54 55 56 57 65 66 67 68 69 70))
(setq lst (mapcar '(lambda(x)(vl-position x map)) (vl-string->list (strcase hex))))
(setq len (length lst))
(setq p 0)
(if (< len 8)
(apply '+ (mapcar '(lambda(x)(lsh x (* 4 (- len (setq p (1+ p)))))) lst))
"最多转7位16进制字符串"
)
)

账号		自动登录	找回密码
密码			立即注册

[每日一码] 十进制转十六进制，十六进制转十进制 函数

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

[每日一码] 十进制转十六进制，十六进制转十进制函数