急需一个命令（或lisp)将字段批量转换成文字（已解决）

wewehua

希望有个lisp程序可以将字段批量转换成文字，感谢各位神！

wewehua

;; Delete fields from selected text and mtext objects.
;; Requires 2005 or later.
;; Joe Burke - 12/7/2007
(defun c:FITOTXT (/ *error* doc i ss obj str)
  (defun *error* (msg)
    (cond
      ((not msg))
      ((wcmatch (strcase msg) "*QUIT*,*CANCEL*"))
      (T
        (princ (strcat "\nError: " msg))
      )
    )
    (vla-EndUndoMark doc)
    (princ)
  )                                       ; end error
  (if (not (>= (atof (getvar "AcadVer")) 15.0))
    (progn
      (princ "\nRequires 2005 or later. Exiting... ")
      (exit)
    )
  )
  (vl-load-com)
  (setq doc (vla-get-ActiveDocument (vlax-get-acad-object)))
  (vla-StartUndoMark doc)
  (setq i 0)
  (if (setq ss (ssget ":L" '((0 . "TEXT,MTEXT"))))
    (repeat (sslength ss)
      (setq obj (vlax-ename->vla-object (ssname ss i))
            str (vlax-get obj 'TextString)
      )
      (if (not (eq str (vla-FieldCode obj)))
        (progn
          (vlax-put obj 'TextString " ")
          (vlax-put obj 'TextString str)
        )
      )
      (setq i (1+ i))
    )
  )
  (*error* nil)
)
已解决了

marting

请压缩上传DWG

nijiea123

看看 有没有用 我也需要