多条同方向的线生成一条线

twtysoi

多条同方向如图生成一条线

王鹏_pBZlo

(defun c:jl( / ss osm i ent par p10 p101 p102 p103 p104 p11 p111 p112 p113 p114 ss1 ss2)
        (setq ss (ssget "x" (list (cons 0 "LINE"))))
        (if (not ss) (setq ss (ssadd)))
        (command "undo" "be")
        (setq osm (getvar "osmode"))
        (setvar "osmode" 0)
        (command "zoom" "O" ss "")
        (setq i -1)
        (while (setq ent (ssname ss (setq i (1+ i))))
           (if (setq par (entget ent))
              (progn        (setq p10 (trans (cdr (assoc 10 par)) 0 1))
                (setq p11 (trans (cdr (assoc 11 par)) 0 1))
                (setq p101 (list (- (car p10) 0.1) (- (cadr p10) 0.1)))
                (setq p102 (list (+ (car p10) 0.1) (- (cadr p10) 0.1)))
                (setq p103 (list (+ (car p10) 0.1) (+ (cadr p10) 0.1)))
                (setq p104 (list (- (car p10) 0.1) (+ (cadr p10) 0.1)))
                (setq p111 (list (- (car p11) 0.1) (- (cadr p11) 0.1)))
                (setq p112 (list (+ (car p11) 0.1) (- (cadr p11) 0.1)))
                (setq p113 (list (+ (car p11) 0.1) (+ (cadr p11) 0.1)))
                (setq p114 (list (- (car p11) 0.1) (+ (cadr p11) 0.1)))
                (setq ss1 (ssget "cp" (list p101 p102 p103 p104 p101) (list (cons 0 "LINE"))))
                (setq ss2 (ssget "cp" (list p111 p112 p113 p114 p111) (list (cons 0 "LINE"))))
                (command "join" ent ss1 ss2 "")
              )
           )
        )
        (command "zoom" "P")
        (setvar "osmode" osm)
        (command "undo" "e")
        (princ)
)

pxr201419

(defun c:j1()
    (setvar "cmdecho" 0)
    (defun xpi (j)
        (if (>= j pi)(setq j (- j pi)) j))
    (setq ss (ssget "x" '((0 . "LINE")))
          lst nil  i 0)
    (if (> (sslength ss) 1)
        (progn
            (if (= wc nil)(setq wc 1.0))
            (if (null (setq wc (getreal (strcat "输入相邻两点坐标允许误差<" (rtos wc 2 1) ">:"))))(setq wc 1.0))
            (while (setq e (ssname ss i))
                (setq lst (append lst (list e))
                      i (1+ i)))
            (while (nth 1 lst)
                (setq e1 (car lst))
                (setq lst (cdr lst))
                (setq i 0 lst1 nil)
                (while (nth i lst)
                    (setq e2 (nth i lst))
                    (setq jd1 (xpi (vlax-get-property (vlax-ename->vla-object e1) 'angle))
                          jd2 (xpi (vlax-get-property (vlax-ename->vla-object e2) 'angle)))
                    (cond ((equal jd1 jd2 1e-10)
                           (setq jd (xpi (angle (cdr (assoc 10 (entget e1))) (cdr (assoc 10 (entget e2))))))
                           (if (equal jd jd1 1e-10)
                               (setq tx t)
                               (setq tx nil)))
                          (t (setq tx nil)))
                    (cond (tx
                           (setq p11 (cdr (assoc 10 (entget e1)))
                                 p12 (cdr (assoc 11 (entget e1)))
                                 p21 (cdr (assoc 10 (entget e2)))
                                 p22 (cdr (assoc 11 (entget e2))))
                           (cond ((or (equal p11 p21 wc)(equal p11 p22 wc)(equal p12 p21 wc)(equal p12 p22 wc))
                                  (command "join" e1 e2 "")
                                  (setq lst1 (append lst1 (list e2)))))))
                    (setq i (1+ i))
                    )
                (setq lst (vl-remove nil (mapcar '(lambda (x) (if (member x lst1) nil  x)) lst))))
            ))
    (princ)
    )

tzfcn

这是个课题，值得研究一下。

nbxhy

哪位大神赶紧出手！！！

pxr201419

试试这个，只针对LINE
(defun c:j1 ( / ss e1 e2 i)
    (setvar "cmdecho" 0)
    (setq ss (ssget ":s" '((0 . "LINE")))
          e1 (ssname ss 0)
          i  1)
    (while (setq e2 (ssname ss i)) (vl-cmdf "join" e1 e2 "") (setq i (1+ i)))
    (princ)
)

twtysoi

多谢
，

twtysoi

pxr201419 发表于 2019-11-21 17:08
试试这个，只针对LINE
(defun c:j1 ( / ss e1 e2 i)
    (setvar "cmdecho" 0)

你好刚才我测试了下，好像只能合接最近绘的线，但是从前的不行，能不能在优化下

pxr201419

标注一下不能合接的线，上传dwg文件

twtysoi

pxr201419 发表于 2019-11-21 17:08
试试这个，只针对LINE
(defun c:j1 ( / ss e1 e2 i)
    (setvar "cmdecho" 0)

最下面哪红色线，

王鹏_pBZlo

twtysoi 发表于 2019-11-22 09:34
最下面哪红色线，

可以接上啊

twtysoi

王鹏_pBZlo 发表于 2019-11-22 16:15
可以接上啊

我是选的所有图，不是只选的哪2个，

twtysoi

我也试了只选这2个可以，但是全部选择就不行了

pxr201419

一懒到底
(defun c:j1()
    (setvar "cmdecho" 0)
    (defun xpi (j)
        (if (>= j pi)(setq j (- j pi)) j))
    (setq ss (ssget "x" '((0 . "LINE")))
          lst nil  i 0)
    (while (setq e (ssname ss i))
        (setq lst (append lst (list e))
              i (1+ i)))
    (while (nth 1 lst)
        (setq e1 (car lst))
        (setq lst (cdr lst))
        (setq i 0 lst1 nil)
        (while (nth i lst)
            (setq e2 (nth i lst))
            (setq jd1 (xpi (vlax-get-property (vlax-ename->vla-object e1) 'angle))
                  jd2 (xpi (vlax-get-property (vlax-ename->vla-object e2) 'angle)))
            (cond ((equal jd1 jd2 1e-10)
                   (setq jd (xpi (angle (cdr (assoc 10 (entget e1))) (cdr (assoc 10 (entget e2))))))
                   (if (equal jd jd1 1e-10)
                       (setq tx t)
                       (setq tx nil)))
                  (t (setq tx nil)))
            (cond (tx (command "join" e1 e2 "")
                   (setq lst1 (append lst1 (list e2)))))
            (setq i (1+ i))
            )
        (setq lst (vl-remove nil (mapcar '(lambda (x) (if (member x lst1) nil  x)) lst))))
    (princ)
    )
如果要自己选择范围，把(setq ss (ssget "x" '((0 . "LINE")))改为(setq ss (ssget  '((0 . "LINE")))

twtysoi

pxr201419 发表于 2019-11-23 12:04
一懒到底
(defun c:j1()
    (setvar "cmdecho" 0)

就是哪些没有，相连的直线地方就不改成一样线了，多谢，

twtysoi

pxr201419 发表于 2019-11-23 12:04
一懒到底
(defun c:j1()
    (setvar "cmdecho" 0)